modules/role/manifests/backup.pp

   1 class role::backup (
   2   String            $user,
   3   String            $group,
   4   String            $mailto,
   5   Optional[Array]   $backups = [],
   6   Optional[String]  $mountpoint = "/backup1",
   7   Optional[String]  $backup_script = "/usr/local/bin/backup.sh",
   8 ) {
   9   include "base_installation"
  10
  11   include "profile::mail"
  12   include "profile::tools"
  13   include "profile::xmr_stak"
  14   include "profile::known_hosts"
  15
  16   ssh_keygen { $user:
  17     notify => Notify_refresh["notify-backup-sshkey-change"]
  18   }
  19
  20   $hosts = $backups.map |$backup| { $backup["host"] }
  21
  22   notify_refresh { "notify-backup-sshkey-change":
  23     message     => template("role/backup/ssh_key_changed.info.erb"),
  24     refreshonly => true
  25   }
  26
  27   $hosts.each |$host| {
  28     notify_refresh { "notify-backup-sshhost-$host-changed":
  29       message     => template("role/backup/ssh_host_changed.info.erb"),
  30       refreshonly => true,
  31       subscribe   => Sshkey[$host],
  32     }
  33   }
  34
  35   concat { $backup_script:
  36     ensure         => "present",
  37     ensure_newline => true,
  38     mode           => "0755",
  39   }
  40
  41   cron { "backup":
  42     ensure  => present,
  43     command => $backup_script,
  44     user    => $user,
  45     minute  => 25,
  46     hour    => 3,
  47     require => Concat[$backup_script],
  48   }
  49
  50   concat::fragment { "backup_head":
  51     target  => $backup_script,
  52     content => template("role/backup/backup_head.sh.erb"),
  53     order   => "01-50",
  54   }
  55
  56   concat::fragment { "backup_tail":
  57     target  => $backup_script,
  58     content => template("role/backup/backup_tail.sh.erb"),
  59     order   => "99-50",
  60   }
  61
  62   $backups.each |$infos| {
  63     $dirname = $infos["name"]
  64     $login = $infos["login"]
  65     $host = $infos["host"]
  66     $dest = "$login@$host"
  67     $base = "$mountpoint/$dirname"
  68     $nbr  = $infos["nbr"]
  69     $order_dirname = $infos["order"]
  70
  71     file { $base:
  72       ensure  => "directory",
  73       owner   => $user,
  74       group   => $group,
  75       require => Mount[$mountpoint],
  76     } ->
  77     file { "$base/older":
  78       ensure  => "directory",
  79       owner   => $user,
  80       group   => $group,
  81     } ->
  82     file { "$base/rsync_output":
  83       ensure  => "directory",
  84       owner   => $user,
  85       group   => $group,
  86     }
  87
  88     concat::fragment { "backup_${dirname}_head":
  89       target  => $backup_script,
  90       content => template("role/backup/backup_dirname_head.sh.erb"),
  91       order   => "$order_dirname-01",
  92     }
  93
  94     concat::fragment { "backup_${dirname}_tail":
  95       target  => $backup_script,
  96       content => template("role/backup/backup_dirname_tail.sh.erb"),
  97       order   => "$order_dirname-99",
  98     }
  99
 100     $infos["parts"].each |$part| {
 101       $local_folder = $part["local_folder"]
 102       $remote_folder = $part["remote_folder"]
 103       $exclude_from = $part["exclude_from"]
 104       $files_from = $part["files_from"]
 105       $args = $part["args"]
 106       $order_part = $part["order"]
 107
 108       file { "$base/$local_folder":
 109         ensure  => "directory",
 110         owner   => $user,
 111         group   => $group,
 112         require => File[$base],
 113       }
 114
 115       concat::fragment { "backup_${dirname}_${local_folder}":
 116         target  => $backup_script,
 117         content => template("role/backup/backup_dirname_part.sh.erb"),
 118         order   => "$order_dirname-$order_part",
 119       }
 120     }
 121   }
 122 }