virtual/eldiron.nix

   1 {
   2   network = {
   3     description = "Immae's network";
   4     enableRollback = true;
   5   };
   6
   7   eldiron = { config, pkgs, ... }:
   8     let mypkgs = import ./packages.nix;
   9     in
  10   {
  11     networking = {
  12       firewall = {
  13         enable = true;
  14         allowedTCPPorts = [ 22 80 443 3306 5432 ];
  15       };
  16     };
  17
  18     deployment = {
  19       targetEnv = "hetzner";
  20       hetzner = {
  21         #robotUser = "defined in HETZNER_ROBOT_USER";
  22         #robotPass = "defined in HETZNER_ROBOT_PASS";
  23         mainIPv4 = "176.9.151.89";
  24         partitions = ''
  25           clearpart --all --initlabel --drives=sda,sdb
  26
  27           part swap1 --recommended --label=swap1 --fstype=swap --ondisk=sda
  28           part swap2 --recommended --label=swap2 --fstype=swap --ondisk=sdb
  29
  30           part raid.1 --grow --ondisk=sda
  31           part raid.2 --grow --ondisk=sdb
  32
  33           raid / --level=1 --device=md0 --fstype=ext4 --label=root raid.1 raid.2
  34         '';
  35       };
  36     };
  37
  38     # FIXME: how to run it? currently set as timer
  39     security.acme.certs = {
  40       "eldiron" = {
  41         webroot = "/var/lib/acme/acme-challenge";
  42         email = "ismael@bouya.org";
  43         domain = "eldiron.immae.eu";
  44         plugins = [ "cert.pem" "chain.pem" "fullchain.pem" "full.pem" "key.pem" "account_key.json" ];
  45         postRun = ''
  46           "systemctl reload httpd.service"
  47         '';
  48         extraDomains = {
  49           "db-1.immae.eu" = null;
  50           "tools.immae.eu" = null;
  51         };
  52       };
  53     };
  54
  55     # FIXME: open_basedir
  56     services.phpfpm = {
  57       extraConfig = ''
  58         log_level = notice
  59         '';
  60       poolConfigs = {
  61         adminer = mypkgs.adminer.phpFpm.pool;
  62         www = ''
  63           listen = /var/run/phpfpm/www.sock
  64           user = wwwrun
  65           group = wwwrun
  66           listen.owner = wwwrun
  67           listen.group = wwwrun
  68           pm = ondemand
  69           pm.max_children = 5
  70           pm.process_idle_timeout = 60
  71           ;php_admin_flag[log_errors] = on
  72           php_admin_value[open_basedir] = "/var/www"
  73           '';
  74       };
  75     };
  76
  77     services.httpd = let
  78       withSSL = domain: {
  79         enableSSL = true;
  80         sslServerCert = "/var/lib/acme/${domain}/full.pem"; # FIXME: cert only?
  81         sslServerKey = "/var/lib/acme/${domain}/key.pem";
  82         sslServerChain = "/var/lib/acme/${domain}/fullchain.pem";
  83       };
  84     in rec {
  85       enable = true;
  86       logPerVirtualHost = true;
  87       multiProcessingModule = "worker";
  88       adminAddr = "httpd@immae.eu";
  89       extraModules = [
  90         "proxy_fcgi" # for PHP
  91       ];
  92       virtualHosts = [
  93         (withSSL "eldiron" // {
  94           listen = [ { ip = "*"; port = 443; } ];
  95           hostName = "eldiron.immae.eu";
  96           # FIXME: directory needs to exist
  97           documentRoot = "/var/www";
  98         })
  99         (withSSL "eldiron" // {
 100           listen = [ { ip = "*"; port = 443; } ];
 101           hostName = "db-1.immae.eu";
 102           documentRoot = null;
 103           extraConfig = builtins.concatStringsSep "\n" [
 104             mypkgs.adminer.apacheConf
 105           ];
 106         })
 107         (withSSL "eldiron" // {
 108           listen = [ { ip = "*"; port = 443; } ];
 109           hostName = "tools.immae.eu";
 110           documentRoot = null;
 111           extraConfig = builtins.concatStringsSep "\n" [
 112             mypkgs.adminer.apacheConf
 113           ];
 114         })
 115         { # Should go last, default fallback
 116           listen = [ { ip = "*"; port = 80; } ];
 117           hostName = "redirectSSL";
 118           serverAliases = [ "*" ];
 119           enableSSL = false;
 120           # FIXME: directory needs to exist
 121           documentRoot = "/var/lib/acme/acme-challenge";
 122           extraConfig = ''
 123             RewriteEngine on
 124             RewriteCond "%{REQUEST_URI}"   "!^/\.well-known"
 125             RewriteRule ^(.+)              https://%{HTTP_HOST}$1  [R=301]
 126             # To redirect in specific "VirtualHost *:80", do
 127             #   RedirectMatch 301 ^/((?!\.well-known.*$).*)$ https://host/$1
 128             # rather than rewrite
 129             '';
 130         }
 131         ];
 132     };
 133
 134     # FIXME: environment variables ?
 135     security.pam.services = let
 136       pam_ldap = pkgs.pam_ldap;
 137       pam_ldap_mysql = pkgs.writeText "mysql.conf" ''
 138         host ldap.immae.eu
 139         base dc=immae,dc=eu
 140         binddn cn=mysql,cn=pam,ou=services,dc=immae,dc=eu
 141         bindpw ${builtins.getEnv "NIXOPS_MYSQL_PAM_PASSWORD"}
 142         pam_filter memberOf=cn=users,cn=mysql,cn=pam,ou=services,dc=immae,dc=eu
 143         '';
 144     in [
 145       {
 146         name = "mysql";
 147         text = ''
 148           # https://mariadb.com/kb/en/mariadb/pam-authentication-plugin/
 149           auth    required ${pam_ldap}/lib/security/pam_ldap.so config=${pam_ldap_mysql}
 150           account required ${pam_ldap}/lib/security/pam_ldap.so config=${pam_ldap_mysql}
 151           '';
 152       }
 153     ];
 154
 155     # FIXME: initial sync
 156     # FIXME: backup
 157     # FIXME: restart after pam
 158     # FIXME: pam access doesn’t work (because of php module)
 159     # FIXME: ssl
 160     services.mysql = rec {
 161       enable = true;
 162       package = pkgs.mariadb.overrideAttrs(old: rec {
 163         cmakeFlags = old.cmakeFlags ++ [ "-DWITH_AUTHENTICATION_PAM=ON" ];
 164         buildInputs = old.buildInputs ++ [ pkgs.pam ];
 165       });
 166     };
 167
 168     # FIXME: initial sync
 169     # FIXME: backup
 170     # FIXME: ssl
 171     services.postgresql = rec {
 172       enable = true;
 173       package = pkgs.postgresql100.overrideAttrs(old: rec {
 174         passthru = old.passthru // { psqlSchema = "11.0"; };
 175         name = "postgresql-11.1";
 176         src = pkgs.fetchurl {
 177           url = "mirror://postgresql/source/v11.1/${name}.tar.bz2";
 178           sha256 = "026v0sicsh7avzi45waf8shcbhivyxmi7qgn9fd1x0vl520mx0ch";
 179         };
 180       });
 181       enableTCPIP = true;
 182       extraConfig = ''
 183         max_connections = 100
 184         wal_level = logical
 185         shared_buffers = 128MB
 186         max_wal_size = 1GB
 187         min_wal_size = 80MB
 188         log_timezone = 'Europe/Paris'
 189         datestyle = 'iso, mdy'
 190         timezone = 'Europe/Paris'
 191         lc_messages = 'en_US.UTF-8'
 192         lc_monetary = 'en_US.UTF-8'
 193         lc_numeric = 'en_US.UTF-8'
 194         lc_time = 'en_US.UTF-8'
 195         default_text_search_config = 'pg_catalog.english'
 196         # ssl = on
 197         # ssl_cert_file = '/var/lib/acme/eldiron/fullchain.pem'
 198         # ssl_key_file = '/var/lib/acme/eldiron/key.pem'
 199         '';
 200       authentication = ''
 201         local   all     postgres                                ident
 202         local   all     all                                     md5
 203         host    all     all             178.33.252.96/32        md5
 204         host    all     all             188.165.209.148/32      md5
 205         #host   all     all             all                     pam
 206       '';
 207     };
 208   };
 209 }