virtual/eldiron.nix

   1 {
   2   network = {
   3     description = "Immae's network";
   4     enableRollback = true;
   5   };
   6
   7   eldiron = { config, pkgs, ... }:
   8     let mypkgs = import ./packages.nix;
   9         mylibs = import ../libs.nix;
  10     in
  11   {
  12     networking = {
  13       firewall = {
  14         enable = true;
  15         allowedTCPPorts = [ 22 80 443 3306 5432 ];
  16       };
  17     };
  18
  19     deployment = {
  20       targetEnv = "hetzner";
  21       hetzner = {
  22         #robotUser = "defined in HETZNER_ROBOT_USER";
  23         #robotPass = "defined in HETZNER_ROBOT_PASS";
  24         mainIPv4 = "176.9.151.89";
  25         partitions = ''
  26           clearpart --all --initlabel --drives=sda,sdb
  27
  28           part swap1 --recommended --label=swap1 --fstype=swap --ondisk=sda
  29           part swap2 --recommended --label=swap2 --fstype=swap --ondisk=sdb
  30
  31           part raid.1 --grow --ondisk=sda
  32           part raid.2 --grow --ondisk=sdb
  33
  34           raid / --level=1 --device=md0 --fstype=ext4 --label=root raid.1 raid.2
  35         '';
  36       };
  37     };
  38
  39     environment.systemPackages = let
  40       # FIXME: move it to nextcloud
  41       occ = pkgs.writeScriptBin "nextcloud-occ" ''
  42         #! ${pkgs.stdenv.shell}
  43         cd ${mypkgs.nextcloud.webRoot}
  44         NEXTCLOUD_CONFIG_DIR="${mypkgs.nextcloud.webRoot}/config" \
  45           exec \
  46           ${config.services.phpfpm.phpPackage}/bin/php \
  47           -c ${config.services.phpfpm.phpPackage}/etc/php.ini \
  48           occ $*
  49         '';
  50     in [
  51       pkgs.telnet
  52       pkgs.vim
  53       occ
  54     ];
  55
  56     security.acme.certs = {
  57       "eldiron" = {
  58         webroot = "/var/lib/acme/acme-challenge";
  59         email = "ismael@bouya.org";
  60         domain = "eldiron.immae.eu";
  61         plugins = [ "cert.pem" "chain.pem" "fullchain.pem" "full.pem" "key.pem" "account_key.json" ];
  62         postRun = ''
  63           systemctl reload httpd.service
  64         '';
  65         extraDomains = {
  66           "db-1.immae.eu" = null;
  67           "tools.immae.eu" = null;
  68           "connexionswing.immae.eu" = null;
  69           "sandetludo.immae.eu" = null;
  70           "cloud.immae.eu" = null;
  71         };
  72       };
  73       # "connexionswing" = {
  74       #   webroot = "/var/lib/acme/acme-challenge";
  75       #   email = "ismael@bouya.org";
  76       #   domain = "connexionswing.com";
  77       #   plugins = [ "cert.pem" "chain.pem" "fullchain.pem" "full.pem" "key.pem" "account_key.json" ];
  78       #   postRun = ''
  79       #     systemctl reload httpd.service
  80       #   '';
  81       #   extraDomains = {
  82       #     "www.connexionswing.com" = null;
  83       #     "sandetludo.com" = null;
  84       #     "www.sandetludo.com" = null;
  85       #   };
  86       # };
  87     };
  88
  89     services.openssh.extraConfig = ''
  90       AuthorizedKeysCommand     /etc/ssh/ldap_authorized_keys
  91       AuthorizedKeysCommandUser nobody
  92       '';
  93
  94     users.users.wwwrun.extraGroups = [ "gitolite" ];
  95
  96     # FIXME: after initial install, need to
  97     # (1) copy rc file (adjust gitolite_ldap_groups.sh)
  98     # (2) (mark old readonly and) sync repos except gitolite-admin
  99     #     rsync -av --exclude=gitolite-admin.git old:/var/lib/gitolite/repositories /var/lib/gitolite/
 100     #     chown -R gitolite:gitolite /var/lib/gitolite
 101     # (3) push force the gitolite-admin to new location (from external point)
 102     #     Don't use an existing key, it will take precedence over
 103     #     gitolite-admin
 104     # (4) su -u gitolite gitolite setup
 105     services.gitolite = {
 106       enable = true;
 107       # FIXME: key from ./ssh
 108       adminPubkey = "ssh-rsa AAAAB3NzaC1yc2EAAAADAQABAAABAQDXqRbiHw7QoHADNIEuo4nUT9fSOIEBMdJZH0bkQAxXyJFyCM1IMz0pxsHV0wu9tdkkr36bPEUj2aV5bkYLBN6nxcV2Y49X8bjOSCPfx3n6Own1h+NeZVBj4ZByrFmqCbTxUJIZ2bZKcWOFncML39VmWdsVhNjg0X4NBBehqXRIKr2gt3E/ESAxTYJFm0BnU0baciw9cN0bsRGqvFgf5h2P48CIAfwhVcGmPQnnAwabnosYQzRWxR0OygH5Kd8mePh6FheIRIigfXsDO8f/jdxwut8buvNIf3m5EBr3tUbTsvM+eV3M5vKGt7sk8T64DVtepTSdOOWtp+47ktsnHOMh immae@immae.eu";
 109     };
 110
 111     services.ympd = mypkgs.ympd.config // { enable = true; };
 112
 113     services.phpfpm = {
 114       # /!\ phppackage is used in nextcloud configuation
 115       phpOptions = ''
 116         ; For nextcloud
 117         extension=${pkgs.phpPackages.redis}/lib/php/extensions/redis.so
 118         ; For nextcloud
 119         extension=${pkgs.phpPackages.apcu}/lib/php/extensions/apcu.so
 120         '';
 121       extraConfig = ''
 122         log_level = notice
 123         '';
 124       poolConfigs = {
 125         adminer = mypkgs.adminer.phpFpm.pool;
 126         connexionswing_dev = mypkgs.connexionswing_dev.phpFpm.pool;
 127         connexionswing_prod = mypkgs.connexionswing_prod.phpFpm.pool;
 128         nextcloud = mypkgs.nextcloud.phpFpm.pool;
 129       };
 130     };
 131
 132     system.activationScripts = {
 133       connexionswing_dev  = mypkgs.connexionswing_dev.activationScript;
 134       connexionswing_prod = mypkgs.connexionswing_prod.activationScript;
 135       nextcloud = mypkgs.nextcloud.activationScript;
 136       httpd = ''
 137         install -d -m 0755 /var/lib/acme/acme-challenge
 138         '';
 139       redis = ''
 140         mkdir -p /run/redis
 141         chown redis /run/redis
 142         '';
 143       gitolite =
 144         assert mylibs.checkEnv "NIXOPS_GITOLITE_LDAP_PASSWORD";
 145         let
 146         gitolite_ldap_groups = mylibs.wrap {
 147           name = "gitolite_ldap_groups.sh";
 148           file = ./packages/gitolite_ldap_groups.sh;
 149           vars = {
 150             LDAP_PASS = builtins.getEnv "NIXOPS_GITOLITE_LDAP_PASSWORD";
 151           };
 152           paths = [ pkgs.openldap pkgs.stdenv.shellPackage pkgs.gnugrep pkgs.coreutils ];
 153         };
 154       in {
 155         deps = [ "users" ];
 156         text = ''
 157           if [ -d /var/lib/gitolite ]; then
 158             ln -sf ${gitolite_ldap_groups} /var/lib/gitolite/gitolite_ldap_groups.sh
 159             chmod g+rx /var/lib/gitolite
 160           fi
 161           if [ -f /var/lib/gitolite/projects.list ]; then
 162             chmod g+r /var/lib/gitolite/projects.list
 163           fi
 164         '';
 165       };
 166     };
 167
 168     environment.etc."ssh/ldap_authorized_keys" = let
 169       ldap_authorized_keys =
 170         assert mylibs.checkEnv "NIXOPS_SSHD_LDAP_PASSWORD";
 171         mylibs.wrap {
 172           name = "ldap_authorized_keys";
 173           file = ./ldap_authorized_keys.sh;
 174           vars = {
 175             LDAP_PASS = builtins.getEnv "NIXOPS_SSHD_LDAP_PASSWORD";
 176             GITOLITE_SHELL = "${pkgs.gitolite}/bin/gitolite-shell";
 177             ECHO = "${pkgs.coreutils}/bin/echo";
 178           };
 179           paths = [ pkgs.openldap pkgs.stdenv.shellPackage pkgs.gnugrep pkgs.gnused pkgs.coreutils ];
 180         };
 181     in {
 182       enable = true;
 183       mode = "0755";
 184       user = "root";
 185       source = ldap_authorized_keys;
 186     };
 187
 188     services.httpd = let
 189       withSSL = domain: {
 190         enableSSL = true;
 191         sslServerCert = "/var/lib/acme/${domain}/cert.pem";
 192         sslServerKey = "/var/lib/acme/${domain}/key.pem";
 193         sslServerChain = "/var/lib/acme/${domain}/fullchain.pem";
 194       };
 195       apacheConfig = {
 196         gzip = {
 197           modules = [ "deflate" "filter" ];
 198           extraConfig = ''
 199             AddOutputFilterByType DEFLATE text/html text/plain text/xml text/css text/javascript application/javascript
 200           '';
 201         };
 202         ldap = {
 203           modules = [ "ldap" "authnz_ldap" ];
 204           extraConfig = assert mylibs.checkEnv "NIXOPS_HTTP_LDAP_PASSWORD"; ''
 205             <IfModule ldap_module>
 206               LDAPSharedCacheSize 500000
 207               LDAPCacheEntries 1024
 208               LDAPCacheTTL 600
 209               LDAPOpCacheEntries 1024
 210               LDAPOpCacheTTL 600
 211             </IfModule>
 212
 213             <Macro LDAPConnect>
 214               <IfModule authnz_ldap_module>
 215                 AuthLDAPURL          ldap://ldap.immae.eu:389/dc=immae,dc=eu
 216                 AuthLDAPBindDN       cn=httpd,ou=services,dc=immae,dc=eu
 217                 AuthLDAPBindPassword "${builtins.getEnv "NIXOPS_HTTP_LDAP_PASSWORD"}"
 218                 AuthType             Basic
 219                 AuthName             "Authentification requise (Acces LDAP)"
 220                 AuthBasicProvider    ldap
 221               </IfModule>
 222             </Macro>
 223           '';
 224         };
 225       };
 226     in rec {
 227       enable = true;
 228       logPerVirtualHost = true;
 229       multiProcessingModule = "worker";
 230       adminAddr = "httpd@immae.eu";
 231       # FIXME: http2
 232       # FIXME: voir les autres modules:
 233       #    authz_core_module
 234       #    reqtimeout_module
 235       #    http2_module
 236       #    version_module
 237       #    proxy_connect_module
 238       #    proxy_ftp_module
 239       #    proxy_scgi_module
 240       #    proxy_ajp_module
 241       #    proxy_balancer_module
 242       #    proxy_express_module
 243       #    lbmethod_byrequests_module
 244       #    lbmethod_bytraffic_module
 245       #    lbmethod_bybusyness_module
 246       #    lbmethod_heartbeat_module
 247
 248       extraModules = pkgs.lib.lists.unique (
 249         mypkgs.adminer.apache.modules ++
 250         mypkgs.nextcloud.apache.modules ++
 251         mypkgs.connexionswing_dev.apache.modules ++
 252         mypkgs.connexionswing_prod.apache.modules ++
 253         mypkgs.ympd.apache.modules ++
 254         mypkgs.git.web.apache.modules ++
 255         pkgs.lib.lists.flatten (pkgs.lib.attrsets.mapAttrsToList (n: v: v.modules) apacheConfig) ++
 256         [ "macro" ]);
 257       extraConfig = builtins.concatStringsSep "\n"
 258         (pkgs.lib.attrsets.mapAttrsToList (n: v: v.extraConfig) apacheConfig);
 259       virtualHosts = [
 260         (withSSL "eldiron" // {
 261           listen = [ { ip = "*"; port = 443; } ];
 262           hostName = "eldiron.immae.eu";
 263           documentRoot = ./www;
 264           extraConfig = ''
 265             DirectoryIndex index.htm
 266             '';
 267         })
 268         (withSSL "eldiron" // {
 269           listen = [ { ip = "*"; port = 443; } ];
 270           hostName = "db-1.immae.eu";
 271           documentRoot = null;
 272           extraConfig = builtins.concatStringsSep "\n" [
 273             mypkgs.adminer.apache.vhostConf
 274           ];
 275         })
 276         (withSSL "eldiron" // {
 277           listen = [ { ip = "*"; port = 443; } ];
 278           hostName = "tools.immae.eu";
 279           documentRoot = null;
 280           extraConfig = builtins.concatStringsSep "\n" [
 281             mypkgs.adminer.apache.vhostConf
 282             mypkgs.ympd.apache.vhostConf
 283           ];
 284         })
 285         (withSSL "eldiron" // {
 286           listen = [ { ip = "*"; port = 443; } ];
 287           hostName = "connexionswing.immae.eu";
 288           serverAliases = [ "sandetludo.immae.eu" ];
 289           documentRoot = mypkgs.connexionswing_dev.webRoot;
 290           extraConfig = builtins.concatStringsSep "\n" [
 291             mypkgs.connexionswing_dev.apache.vhostConf
 292           ];
 293         })
 294         (withSSL "eldiron" // {
 295           listen = [ { ip = "*"; port = 443; } ];
 296           hostName = "cloud.immae.eu";
 297           documentRoot = mypkgs.nextcloud.webRoot;
 298           extraConfig = builtins.concatStringsSep "\n" [
 299             mypkgs.nextcloud.apache.vhostConf
 300           ];
 301         })
 302         (withSSL "eldiron" // {
 303           listen = [ { ip = "*"; port = 443; } ];
 304           hostName = "git.immae.eu";
 305           documentRoot = mypkgs.git.web.webRoot;
 306           extraConfig = builtins.concatStringsSep "\n" [
 307             mypkgs.git.web.apache.vhostConf
 308           ] + ''
 309             RewriteEngine on
 310             RewriteCond %{REQUEST_URI}       ^/releases
 311             RewriteRule /releases(.*)        https://release.immae.eu$1 [P,L]
 312             '';
 313         })
 314         { # Should go last, default fallback
 315           listen = [ { ip = "*"; port = 80; } ];
 316           hostName = "redirectSSL";
 317           serverAliases = [ "*" ];
 318           enableSSL = false;
 319           documentRoot = "/var/lib/acme/acme-challenge";
 320           extraConfig = ''
 321             RewriteEngine on
 322             RewriteCond "%{REQUEST_URI}"   "!^/\.well-known"
 323             RewriteRule ^(.+)              https://%{HTTP_HOST}$1  [R=301]
 324             # To redirect in specific "VirtualHost *:80", do
 325             #   RedirectMatch 301 ^/((?!\.well-known.*$).*)$ https://host/$1
 326             # rather than rewrite
 327             '';
 328         }
 329         ];
 330     };
 331
 332     security.pam.services = let
 333       pam_ldap = pkgs.pam_ldap;
 334       pam_ldap_mysql = assert mylibs.checkEnv "NIXOPS_MYSQL_PAM_PASSWORD";
 335               pkgs.writeText "mysql.conf" ''
 336         host ldap.immae.eu
 337         base dc=immae,dc=eu
 338         binddn cn=mysql,cn=pam,ou=services,dc=immae,dc=eu
 339         bindpw ${builtins.getEnv "NIXOPS_MYSQL_PAM_PASSWORD"}
 340         pam_filter memberOf=cn=users,cn=mysql,cn=pam,ou=services,dc=immae,dc=eu
 341         '';
 342     in [
 343       {
 344         name = "mysql";
 345         text = ''
 346           # https://mariadb.com/kb/en/mariadb/pam-authentication-plugin/
 347           auth    required ${pam_ldap}/lib/security/pam_ldap.so config=${pam_ldap_mysql}
 348           account required ${pam_ldap}/lib/security/pam_ldap.so config=${pam_ldap_mysql}
 349           '';
 350       }
 351     ];
 352
 353     # FIXME: backup
 354     services.redis = rec {
 355       enable = true;
 356       bind = "127.0.0.1";
 357       unixSocket = "/run/redis/redis.sock";
 358       extraConfig = ''
 359         unixsocketperm 777
 360         maxclients 1024
 361         '';
 362     };
 363
 364     # FIXME: initial sync
 365     # FIXME: backup
 366     # FIXME: restart after pam
 367     # FIXME: pam access doesn’t work (because of php module)
 368     # FIXME: ssl
 369     services.mysql = rec {
 370       enable = true;
 371       package = pkgs.mariadb.overrideAttrs(old: rec {
 372         cmakeFlags = old.cmakeFlags ++ [ "-DWITH_AUTHENTICATION_PAM=ON" ];
 373         buildInputs = old.buildInputs ++ [ pkgs.pam ];
 374       });
 375     };
 376
 377     # FIXME: initial sync
 378     # FIXME: backup
 379     # FIXME: ssl
 380     services.postgresql = rec {
 381       enable = true;
 382       package = pkgs.postgresql100.overrideAttrs(old: rec {
 383         passthru = old.passthru // { psqlSchema = "11.0"; };
 384         name = "postgresql-11.1";
 385         src = pkgs.fetchurl {
 386           url = "mirror://postgresql/source/v11.1/${name}.tar.bz2";
 387           sha256 = "026v0sicsh7avzi45waf8shcbhivyxmi7qgn9fd1x0vl520mx0ch";
 388         };
 389       });
 390       enableTCPIP = true;
 391       extraConfig = ''
 392         max_connections = 100
 393         wal_level = logical
 394         shared_buffers = 128MB
 395         max_wal_size = 1GB
 396         min_wal_size = 80MB
 397         log_timezone = 'Europe/Paris'
 398         datestyle = 'iso, mdy'
 399         timezone = 'Europe/Paris'
 400         lc_messages = 'en_US.UTF-8'
 401         lc_monetary = 'en_US.UTF-8'
 402         lc_numeric = 'en_US.UTF-8'
 403         lc_time = 'en_US.UTF-8'
 404         default_text_search_config = 'pg_catalog.english'
 405         # ssl = on
 406         # ssl_cert_file = '/var/lib/acme/eldiron/fullchain.pem'
 407         # ssl_key_file = '/var/lib/acme/eldiron/key.pem'
 408         '';
 409       authentication = ''
 410         local   all     postgres                                ident
 411         local   all     all                                     md5
 412         host    all     all             178.33.252.96/32        md5
 413         host    all     all             188.165.209.148/32      md5
 414         #host   all     all             all                     pam
 415       '';
 416     };
 417   };
 418 }