virtual/eldiron.nix

   1 {
   2   network = {
   3     description = "Immae's network";
   4     enableRollback = true;
   5   };
   6
   7   eldiron = { config, pkgs, ... }:
   8     let mypkgs = import ./packages.nix;
   9         mylibs = import ../libs.nix;
  10     in
  11   {
  12     networking = {
  13       firewall = {
  14         enable = true;
  15         allowedTCPPorts = [ 22 80 443 3306 5432 ];
  16       };
  17     };
  18
  19     deployment = {
  20       targetEnv = "hetzner";
  21       hetzner = {
  22         #robotUser = "defined in HETZNER_ROBOT_USER";
  23         #robotPass = "defined in HETZNER_ROBOT_PASS";
  24         mainIPv4 = "176.9.151.89";
  25         partitions = ''
  26           clearpart --all --initlabel --drives=sda,sdb
  27
  28           part swap1 --recommended --label=swap1 --fstype=swap --ondisk=sda
  29           part swap2 --recommended --label=swap2 --fstype=swap --ondisk=sdb
  30
  31           part raid.1 --grow --ondisk=sda
  32           part raid.2 --grow --ondisk=sdb
  33
  34           raid / --level=1 --device=md0 --fstype=ext4 --label=root raid.1 raid.2
  35         '';
  36       };
  37     };
  38
  39     environment.systemPackages = [
  40       pkgs.telnet
  41       pkgs.vim
  42     ];
  43
  44     security.acme.certs = {
  45       "eldiron" = {
  46         webroot = "/var/lib/acme/acme-challenge";
  47         email = "ismael@bouya.org";
  48         domain = "eldiron.immae.eu";
  49         plugins = [ "cert.pem" "chain.pem" "fullchain.pem" "full.pem" "key.pem" "account_key.json" ];
  50         postRun = ''
  51           systemctl reload httpd.service
  52         '';
  53         extraDomains = {
  54           "db-1.immae.eu" = null;
  55           "tools.immae.eu" = null;
  56           "connexionswing.immae.eu" = null;
  57           "sandetludo.immae.eu" = null;
  58         };
  59       };
  60       # "connexionswing" = {
  61       #   webroot = "/var/lib/acme/acme-challenge";
  62       #   email = "ismael@bouya.org";
  63       #   domain = "connexionswing.com";
  64       #   plugins = [ "cert.pem" "chain.pem" "fullchain.pem" "full.pem" "key.pem" "account_key.json" ];
  65       #   postRun = ''
  66       #     systemctl reload httpd.service
  67       #   '';
  68       #   extraDomains = {
  69       #     "www.connexionswing.com" = null;
  70       #     "sandetludo.com" = null;
  71       #     "www.sandetludo.com" = null;
  72       #   };
  73       # };
  74     };
  75
  76     services.ympd = mypkgs.ympd.config // { enable = true; };
  77
  78     services.phpfpm = {
  79       extraConfig = ''
  80         log_level = notice
  81         '';
  82       poolConfigs = {
  83         adminer = mypkgs.adminer.phpFpm.pool;
  84         connexionswing_dev = mypkgs.connexionswing_dev.phpFpm.pool;
  85         connexionswing_prod = mypkgs.connexionswing_prod.phpFpm.pool;
  86         www = ''
  87           listen = /var/run/phpfpm/www.sock
  88           user = wwwrun
  89           group = wwwrun
  90           listen.owner = wwwrun
  91           listen.group = wwwrun
  92           pm = ondemand
  93           pm.max_children = 5
  94           pm.process_idle_timeout = 60
  95           ;php_admin_flag[log_errors] = on
  96           php_admin_value[open_basedir] = "/var/www"
  97           '';
  98       };
  99     };
 100
 101     system.activationScripts = {
 102       connexionswing_dev  = mypkgs.connexionswing_dev.activationScript;
 103       connexionswing_prod = mypkgs.connexionswing_prod.activationScript;
 104       httpd = ''
 105         install -d -m 0755 /var/lib/acme/acme-challenge
 106         install -d -m 0755 /var/www
 107         '';
 108       redis = ''
 109         mkdir -p /run/redis
 110         chown redis /run/redis
 111         '';
 112     };
 113
 114     services.httpd = let
 115       withSSL = domain: {
 116         enableSSL = true;
 117         sslServerCert = "/var/lib/acme/${domain}/cert.pem";
 118         sslServerKey = "/var/lib/acme/${domain}/key.pem";
 119         sslServerChain = "/var/lib/acme/${domain}/fullchain.pem";
 120       };
 121       apacheConfig = {
 122         gzip = {
 123           modules = [ "deflate" "filter" ];
 124           extraConfig = ''
 125             AddOutputFilterByType DEFLATE text/html text/plain text/xml text/css text/javascript application/javascript
 126           '';
 127         };
 128         ldap = {
 129           modules = [ "ldap" "authnz_ldap" ];
 130           extraConfig = assert mylibs.checkEnv "NIXOPS_HTTP_LDAP_PASSWORD"; ''
 131             <IfModule ldap_module>
 132               LDAPSharedCacheSize 500000
 133               LDAPCacheEntries 1024
 134               LDAPCacheTTL 600
 135               LDAPOpCacheEntries 1024
 136               LDAPOpCacheTTL 600
 137             </IfModule>
 138
 139             <Macro LDAPConnect>
 140               <IfModule authnz_ldap_module>
 141                 AuthLDAPURL          ldap://ldap.immae.eu:389/dc=immae,dc=eu
 142                 AuthLDAPBindDN       cn=httpd,ou=services,dc=immae,dc=eu
 143                 AuthLDAPBindPassword "${builtins.getEnv "NIXOPS_HTTP_LDAP_PASSWORD"}"
 144                 AuthType             Basic
 145                 AuthName             "Authentification requise (Acces LDAP)"
 146                 AuthBasicProvider    ldap
 147               </IfModule>
 148             </Macro>
 149           '';
 150         };
 151       };
 152     in rec {
 153       enable = true;
 154       logPerVirtualHost = true;
 155       multiProcessingModule = "worker";
 156       adminAddr = "httpd@immae.eu";
 157       # FIXME: http2
 158       # FIXME: voir les autres modules:
 159       #    authz_core_module
 160       #    reqtimeout_module
 161       #    http2_module
 162       #    version_module
 163       #    proxy_connect_module
 164       #    proxy_ftp_module
 165       #    proxy_scgi_module
 166       #    proxy_ajp_module
 167       #    proxy_balancer_module
 168       #    proxy_express_module
 169       #    lbmethod_byrequests_module
 170       #    lbmethod_bytraffic_module
 171       #    lbmethod_bybusyness_module
 172       #    lbmethod_heartbeat_module
 173
 174       extraModules = pkgs.lib.lists.unique (
 175         mypkgs.adminer.apache.modules ++
 176         mypkgs.connexionswing_dev.apache.modules ++
 177         mypkgs.connexionswing_prod.apache.modules ++
 178         pkgs.lib.lists.flatten (pkgs.lib.attrsets.mapAttrsToList (n: v: v.modules) apacheConfig) ++
 179         [ "macro" ]);
 180       extraConfig = builtins.concatStringsSep "\n"
 181         (pkgs.lib.attrsets.mapAttrsToList (n: v: v.extraConfig) apacheConfig);
 182       virtualHosts = [
 183         (withSSL "eldiron" // {
 184           listen = [ { ip = "*"; port = 443; } ];
 185           hostName = "eldiron.immae.eu";
 186           # FIXME: directory needs to exist
 187           documentRoot = "/var/www";
 188         })
 189         (withSSL "eldiron" // {
 190           listen = [ { ip = "*"; port = 443; } ];
 191           hostName = "db-1.immae.eu";
 192           documentRoot = null;
 193           extraConfig = builtins.concatStringsSep "\n" [
 194             mypkgs.adminer.apache.vhostConf
 195           ];
 196         })
 197         (withSSL "eldiron" // {
 198           listen = [ { ip = "*"; port = 443; } ];
 199           hostName = "tools.immae.eu";
 200           documentRoot = null;
 201           extraConfig = builtins.concatStringsSep "\n" [
 202             mypkgs.adminer.apache.vhostConf
 203             mypkgs.ympd.apache.vhostConf
 204           ];
 205         })
 206         (withSSL "eldiron" // {
 207           listen = [ { ip = "*"; port = 443; } ];
 208           hostName = "connexionswing.immae.eu";
 209           serverAliases = [ "sandetludo.immae.eu" ];
 210           documentRoot = mypkgs.connexionswing_dev.webRoot;
 211           extraConfig = builtins.concatStringsSep "\n" [
 212             mypkgs.connexionswing_dev.apache.vhostConf
 213           ];
 214         })
 215         { # Should go last, default fallback
 216           listen = [ { ip = "*"; port = 80; } ];
 217           hostName = "redirectSSL";
 218           serverAliases = [ "*" ];
 219           enableSSL = false;
 220           documentRoot = "/var/lib/acme/acme-challenge";
 221           extraConfig = ''
 222             RewriteEngine on
 223             RewriteCond "%{REQUEST_URI}"   "!^/\.well-known"
 224             RewriteRule ^(.+)              https://%{HTTP_HOST}$1  [R=301]
 225             # To redirect in specific "VirtualHost *:80", do
 226             #   RedirectMatch 301 ^/((?!\.well-known.*$).*)$ https://host/$1
 227             # rather than rewrite
 228             '';
 229         }
 230         ];
 231     };
 232
 233     security.pam.services = let
 234       pam_ldap = pkgs.pam_ldap;
 235       pam_ldap_mysql = assert mylibs.checkEnv "NIXOPS_MYSQL_PAM_PASSWORD";
 236               pkgs.writeText "mysql.conf" ''
 237         host ldap.immae.eu
 238         base dc=immae,dc=eu
 239         binddn cn=mysql,cn=pam,ou=services,dc=immae,dc=eu
 240         bindpw ${builtins.getEnv "NIXOPS_MYSQL_PAM_PASSWORD"}
 241         pam_filter memberOf=cn=users,cn=mysql,cn=pam,ou=services,dc=immae,dc=eu
 242         '';
 243     in [
 244       {
 245         name = "mysql";
 246         text = ''
 247           # https://mariadb.com/kb/en/mariadb/pam-authentication-plugin/
 248           auth    required ${pam_ldap}/lib/security/pam_ldap.so config=${pam_ldap_mysql}
 249           account required ${pam_ldap}/lib/security/pam_ldap.so config=${pam_ldap_mysql}
 250           '';
 251       }
 252     ];
 253
 254     # FIXME: backup
 255     services.redis = rec {
 256       enable = true;
 257       bind = "127.0.0.1";
 258       unixSocket = "/run/redis/redis.sock";
 259       extraConfig = ''
 260         unixsocketperm 777
 261         maxclients 1024
 262         '';
 263     };
 264
 265     # FIXME: initial sync
 266     # FIXME: backup
 267     # FIXME: restart after pam
 268     # FIXME: pam access doesn’t work (because of php module)
 269     # FIXME: ssl
 270     services.mysql = rec {
 271       enable = true;
 272       package = pkgs.mariadb.overrideAttrs(old: rec {
 273         cmakeFlags = old.cmakeFlags ++ [ "-DWITH_AUTHENTICATION_PAM=ON" ];
 274         buildInputs = old.buildInputs ++ [ pkgs.pam ];
 275       });
 276     };
 277
 278     # FIXME: initial sync
 279     # FIXME: backup
 280     # FIXME: ssl
 281     services.postgresql = rec {
 282       enable = true;
 283       package = pkgs.postgresql100.overrideAttrs(old: rec {
 284         passthru = old.passthru // { psqlSchema = "11.0"; };
 285         name = "postgresql-11.1";
 286         src = pkgs.fetchurl {
 287           url = "mirror://postgresql/source/v11.1/${name}.tar.bz2";
 288           sha256 = "026v0sicsh7avzi45waf8shcbhivyxmi7qgn9fd1x0vl520mx0ch";
 289         };
 290       });
 291       enableTCPIP = true;
 292       extraConfig = ''
 293         max_connections = 100
 294         wal_level = logical
 295         shared_buffers = 128MB
 296         max_wal_size = 1GB
 297         min_wal_size = 80MB
 298         log_timezone = 'Europe/Paris'
 299         datestyle = 'iso, mdy'
 300         timezone = 'Europe/Paris'
 301         lc_messages = 'en_US.UTF-8'
 302         lc_monetary = 'en_US.UTF-8'
 303         lc_numeric = 'en_US.UTF-8'
 304         lc_time = 'en_US.UTF-8'
 305         default_text_search_config = 'pg_catalog.english'
 306         # ssl = on
 307         # ssl_cert_file = '/var/lib/acme/eldiron/fullchain.pem'
 308         # ssl_key_file = '/var/lib/acme/eldiron/key.pem'
 309         '';
 310       authentication = ''
 311         local   all     postgres                                ident
 312         local   all     all                                     md5
 313         host    all     all             178.33.252.96/32        md5
 314         host    all     all             188.165.209.148/32      md5
 315         #host   all     all             all                     pam
 316       '';
 317     };
 318   };
 319 }