pkgs/webapps/default.nix

   1 { callPackage, mylibs, lib }:
   2 rec {
   3   adminer = callPackage ./adminer {};
   4   awl = callPackage ./awl {};
   5   davical = callPackage ./davical {};
   6   diaspora = callPackage ./diaspora { inherit mylibs; };
   7
   8   dokuwiki = callPackage ./dokuwiki { inherit mylibs; };
   9   dokuwiki-with-plugins = dokuwiki.withPlugins (builtins.attrValues dokuwiki-plugins);
  10   dokuwiki-plugins = let
  11     names = [ "farmer" "todo" ];
  12   in
  13     lib.attrsets.genAttrs names
  14       (name: callPackage (./dokuwiki/plugins + "/${name}.nix") {});
  15
  16   infcloud = callPackage ./infcloud {};
  17
  18   mantisbt_2 = callPackage ./mantisbt_2 {};
  19   mantisbt_2-with-plugins = mantisbt_2.withPlugins (builtins.attrValues mantisbt_2-plugins);
  20   mantisbt_2-plugins = let
  21     names = [ "slack" "source-integration" ];
  22   in
  23     lib.attrsets.genAttrs names
  24       (name: callPackage (./mantisbt_2/plugins + "/${name}") {});
  25
  26   mastodon = callPackage ./mastodon { inherit mylibs; };
  27
  28   mediagoblin = callPackage ./mediagoblin { inherit mylibs; };
  29   mediagoblin-with-plugins = mediagoblin.withPlugins (builtins.attrValues mediagoblin-plugins);
  30   mediagoblin-plugins = let
  31     names = [ "basicsearch" ];
  32   in
  33     lib.attrsets.genAttrs names
  34       (name: callPackage (./mediagoblin/plugins + "/${name}") {});
  35
  36   nextcloud = callPackage ./nextcloud {};
  37   nextcloud-with-apps = nextcloud.withPlugins (builtins.attrValues nextcloud-apps);
  38   nextcloud-apps = let
  39       names = [
  40         "audioplayer" "bookmarks" "calendar" "contacts" "deck"
  41         "files_markdown" "gpxedit" "gpxpod" "keeweb" "music"
  42         "notes" "ocsms" "passman" "spreed" "tasks"
  43         "flowupload" "carnet"
  44         # FIXME: fix passman for NC 16
  45       ];
  46     in
  47     lib.attrsets.genAttrs names
  48       (name: callPackage (./nextcloud/apps + "/${name}.nix") { buildApp = nextcloud.buildApp; });
  49
  50   phpldapadmin = callPackage ./phpldapadmin {};
  51   rompr = callPackage ./rompr { inherit mylibs; };
  52
  53   roundcubemail = callPackage ./roundcubemail {};
  54   roundcubemail-with-plugins-skins = roundcubemail.withPlugins (builtins.attrValues roundcubemail-plugins) (builtins.attrValues roundcubemail-skins);
  55   roundcubemail-skins = let
  56     names = [];
  57   in
  58     lib.attrsets.genAttrs names
  59       (name: callPackage (./roundcubemail/skins + "/${name}") {});
  60   roundcubemail-plugins = let
  61     names = [
  62       "automatic_addressbook" "carddav" "contextmenu"
  63       "contextmenu_folder" "html5_notifier" "ident_switch"
  64       "message_highlight" "thunderbird_labels"
  65     ];
  66   in
  67     lib.attrsets.genAttrs names
  68       (name: callPackage (./roundcubemail/plugins + "/${name}") { buildPlugin = roundcubemail.buildPlugin; });
  69
  70   ttrss = callPackage ./ttrss { inherit mylibs; };
  71   ttrss-with-plugins = ttrss.withPlugins (builtins.attrValues ttrss-plugins);
  72   ttrss-plugins = let
  73     names = [ "auth_ldap" "af_feedmod" "feediron" "ff_instagram" "tumblr_gdpr_ua" ];
  74     patched = [ "af_feedmod" "feediron" ];
  75   in
  76     lib.attrsets.genAttrs names
  77       (name: callPackage (./ttrss/plugins + "/${name}") (
  78         { inherit mylibs; } //
  79         (if builtins.elem name patched then { patched = true; } else {})
  80         )
  81       );
  82
  83   yourls = callPackage ./yourls { inherit mylibs; };
  84   yourls-with-plugins = yourls.withPlugins (builtins.attrValues yourls-plugins);
  85   yourls-plugins = let
  86     names = [ "ldap" ];
  87   in
  88     lib.attrsets.genAttrs names
  89       (name: callPackage (./yourls/plugins + "/${name}") { inherit mylibs; });
  90 }