nixops/modules/websites/tools/mastodon/mastodon.nix

   1 { env, ruby_2_5, bundlerEnv, defaultGemConfig, fetchedGithub, stdenv, writeText, pkgs }:
   2 let
   3   varDir = "/var/lib/mastodon_immae";
   4   socketsDir = "/run/mastodon";
   5   gems = bundlerEnv {
   6     name = "mastodon-env";
   7     # https://git.immae.eu/mantisbt/view.php?id=131
   8     ruby = ruby_2_5.overrideAttrs(old: {
   9       postInstall = builtins.replaceStrings [" --destdir $GEM_HOME"] [""] old.postInstall;
  10     });
  11     gemset = ./gemset.nix;
  12     gemdir = (fetchedGithub ./mastodon.json).src;
  13     groups = [ "default" "production" "test" "development" ];
  14     gemConfig = defaultGemConfig // {
  15       cld3 = attrs: {
  16         buildInputs = with pkgs; [ protobuf protobufc pkgconfig ];
  17       };
  18       idn-ruby = attrs: {
  19         buildInputs = with pkgs; [ libidn ];
  20       };
  21       rpam2 = attrs: {
  22         buildInputs = with pkgs; [ pam ];
  23       };
  24     };
  25   };
  26   yarnModules = let
  27       info = fetchedGithub ./mastodon.json;
  28     in
  29       pkgs.yarn2nix.mkYarnModules {
  30         name = "mastodon-yarn-modules";
  31         packageJSON = "${info.src}/package.json";
  32         yarnLock = "${info.src}/yarn.lock";
  33         yarnNix = ./yarn-packages.nix;
  34         pkgConfig = {
  35           uws = {
  36             postInstall = ''
  37               npx node-gyp rebuild > build_log.txt 2>&1 || true
  38               '';
  39           };
  40           node-zopfli = {
  41             postInstall = ''
  42               npx node-pre-gyp install --fallback-to-build
  43               '';
  44           };
  45           node-sass = {
  46             buildInputs = with pkgs; [ libsass python ];
  47             postInstall = let
  48               nodeHeaders = pkgs.fetchurl {
  49                 url = "https://nodejs.org/download/release/v${pkgs.nodejs.version}/node-v${pkgs.nodejs.version}-headers.tar.gz";
  50                 sha256 = "16f20ya3ys6w5w6y6l4536f7jrgk4gz46bf71w1r1xxb26a54m32";
  51               };
  52             in
  53               ''
  54                 node scripts/build.js --tarball=${nodeHeaders}
  55               '';
  56           };
  57         };
  58       };
  59   mastodon = stdenv.mkDerivation (fetchedGithub ./mastodon.json // rec {
  60     installPhase = ''
  61       cp -a . $out
  62       cp -a ${yarnModules}/node_modules $out
  63     '';
  64     buildInputs = [ yarnModules gems ];
  65   });
  66   config = writeText "mastodon_environment" ''
  67     REDIS_HOST=${env.redis.host}
  68     REDIS_PORT=${env.redis.port}
  69     REDIS_DB=${env.redis.db}
  70     DB_HOST=${env.postgresql.socket}
  71     DB_USER=${env.postgresql.user}
  72     DB_NAME=${env.postgresql.database}
  73     DB_PASS=${env.postgresql.password}
  74     DB_PORT=${env.postgresql.port}
  75
  76     LOCAL_DOMAIN=mastodon.immae.eu
  77     LOCAL_HTTPS=true
  78     ALTERNATE_DOMAINS=immae.eu
  79
  80     PAPERCLIP_SECRET=${env.paperclip_secret}
  81     SECRET_KEY_BASE=${env.secret_key_base}
  82     OTP_SECRET=${env.otp_secret}
  83
  84     VAPID_PRIVATE_KEY=${env.vapid.private}
  85     VAPID_PUBLIC_KEY=${env.vapid.public}
  86
  87     SMTP_DELIVERY_METHOD=sendmail
  88     SMTP_FROM_ADDRESS=notifications@mastodon.immae.eu
  89     SENDMAIL_LOCATION="/run/wrappers/bin/sendmail"
  90     PAPERCLIP_ROOT_PATH=${varDir}
  91
  92     STREAMING_CLUSTER_NUM=1
  93
  94     RAILS_LOG_LEVEL=warn
  95
  96     # LDAP authentication (optional)
  97     LDAP_ENABLED=true
  98     LDAP_HOST=ldap.immae.eu
  99     LDAP_PORT=636
 100     LDAP_METHOD=simple_tls
 101     LDAP_BASE="dc=immae,dc=eu"
 102     LDAP_BIND_DN="cn=mastodon,ou=services,dc=immae,dc=eu"
 103     LDAP_PASSWORD="${env.ldap.password}"
 104     LDAP_UID="uid"
 105     LDAP_SEARCH_FILTER="(&(%{uid}=%{email})(memberOf=cn=users,cn=mastodon,ou=services,dc=immae,dc=eu))"
 106     '';
 107
 108     railsRoot = stdenv.mkDerivation {
 109       name = "mastodon_immae";
 110       inherit config mastodon;
 111       builder = writeText "build_mastodon_immae" ''
 112         source $stdenv/setup
 113         set -a
 114         source $config
 115         set +a
 116         cp -a $mastodon $out
 117         cd $out
 118         chmod u+rwX . public
 119         chmod -R u+rwX config/
 120         sed -i -e 's@^end$@  config.action_mailer.sendmail_settings = { location: ENV.fetch("SENDMAIL_LOCATION", "/usr/sbin/sendmail") }\nend@' config/environments/production.rb
 121         RAILS_ENV=production ${gems}/bin/rails assets:precompile
 122         rm -rf tmp/cache
 123         ln -sf ${varDir}/tmp/cache tmp
 124         '';
 125       buildInputs = [ gems gems.ruby pkgs.nodejs pkgs.yarn ];
 126     };
 127 in
 128   {
 129     inherit railsRoot config varDir socketsDir gems;
 130     nodeSocket = "${socketsDir}/live_immae_node.sock";
 131     railsSocket = "${socketsDir}/live_immae_puma.sock";
 132   }