nixops/modules/websites/tools/diaspora/default.nix

   1 { lib, pkgs, config, myconfig, mylibs, ... }:
   2 let
   3   diaspora = pkgs.callPackage ./diaspora.nix {
   4     inherit (mylibs) fetchedGithub;
   5     env = myconfig.env.tools.diaspora;
   6   };
   7
   8   root = "/run/current-system/webapps/tools_diaspora";
   9   cfg = config.services.myWebsites.tools.diaspora;
  10 in {
  11   options.services.myWebsites.tools.diaspora = {
  12     enable = lib.mkEnableOption "enable diaspora's website";
  13   };
  14
  15   config = lib.mkIf cfg.enable {
  16     ids.uids.diaspora = myconfig.env.tools.diaspora.user.uid;
  17     ids.gids.diaspora = myconfig.env.tools.diaspora.user.gid;
  18
  19     users.users.diaspora = {
  20       name = "diaspora";
  21       uid = config.ids.uids.diaspora;
  22       group = "diaspora";
  23       description = "Diaspora user";
  24       home = diaspora.varDir;
  25       useDefaultShell = true;
  26       packages = [ diaspora.gems pkgs.nodejs diaspora.gems.ruby ];
  27       extraGroups = [ "keys" ];
  28     };
  29
  30     users.groups.diaspora.gid = config.ids.gids.diaspora;
  31
  32     deployment.keys = diaspora.keys;
  33     systemd.services.diaspora = {
  34       description = "Diaspora";
  35       wantedBy = [ "multi-user.target" ];
  36       after = [
  37         "network.target" "redis.service" "postgresql.service"
  38         "tools-diaspora-secret_token.service"
  39         "tools-diaspora-config.service"
  40         "tools-diaspora-database_config.service"
  41       ];
  42       wants = [
  43         "redis.service" "postgresql.service"
  44         "tools-diaspora-secret_token.service"
  45         "tools-diaspora-config.service"
  46         "tools-diaspora-database_config.service"
  47       ];
  48
  49       environment.RAILS_ENV = "production";
  50       environment.BUNDLE_PATH = "${diaspora.gems}/${diaspora.gems.ruby.gemPath}";
  51       environment.BUNDLE_GEMFILE = "${diaspora.gems.confFiles}/Gemfile";
  52       environment.EYE_SOCK = "${diaspora.socketsDir}/eye.sock";
  53       environment.EYE_PID = "${diaspora.socketsDir}/eye.pid";
  54
  55       path = [ diaspora.gems pkgs.nodejs diaspora.gems.ruby pkgs.curl pkgs.which pkgs.gawk ];
  56
  57       preStart = ''
  58         ./bin/bundle exec rails db:migrate
  59       '';
  60
  61       script = ''
  62         exec ${diaspora.railsRoot}/script/server
  63       '';
  64
  65       serviceConfig = {
  66         User = "diaspora";
  67         PrivateTmp = true;
  68         Restart = "always";
  69         Type = "simple";
  70         WorkingDirectory = diaspora.railsRoot;
  71         StandardInput = "null";
  72         KillMode = "control-group";
  73       };
  74
  75       unitConfig.RequiresMountsFor = diaspora.varDir;
  76     };
  77
  78     system.activationScripts.diaspora = {
  79       deps = [ "users" ];
  80       text = ''
  81       install -m 0755 -o diaspora -g diaspora -d ${diaspora.socketsDir}
  82       install -m 0755 -o diaspora -g diaspora -d ${diaspora.varDir} \
  83         ${diaspora.varDir}/uploads ${diaspora.varDir}/tmp \
  84         ${diaspora.varDir}/log
  85       install -m 0700 -o diaspora -g diaspora -d ${diaspora.varDir}/tmp/pids
  86       if [ ! -f ${diaspora.varDir}/schedule.yml ]; then
  87         echo "{}" | $wrapperDir/sudo -u diaspora tee ${diaspora.varDir}/schedule.yml
  88       fi
  89       '';
  90     };
  91
  92     services.myWebsites.tools.modules = [
  93       "headers" "proxy" "proxy_http"
  94     ];
  95     security.acme.certs."eldiron".extraDomains."diaspora.immae.eu" = null;
  96     system.extraSystemBuilderCmds = ''
  97       mkdir -p $out/webapps
  98       ln -s ${diaspora.railsRoot}/public/ $out/webapps/tools_diaspora
  99       '';
 100     services.myWebsites.tools.vhostConfs.diaspora = {
 101       certName    = "eldiron";
 102       hosts       = [ "diaspora.immae.eu" ];
 103       root        = root;
 104       extraConfig = [ ''
 105         RewriteEngine On
 106         RewriteCond %{DOCUMENT_ROOT}/%{REQUEST_FILENAME} !-f
 107         RewriteRule ^/(.*)$ unix://${diaspora.railsSocket}|http://diaspora.immae.eu/%{REQUEST_URI} [P,NE,QSA,L]
 108
 109         ProxyRequests Off
 110         ProxyVia On
 111         ProxyPreserveHost On
 112         RequestHeader set X_FORWARDED_PROTO https
 113
 114         <Proxy *>
 115             Require all granted
 116         </Proxy>
 117
 118         <Directory ${root}>
 119             Require all granted
 120             Options -MultiViews
 121         </Directory>
 122       '' ];
 123     };
 124   };
 125 }