nixops/modules/websites/ludivine/default.nix

   1 { lib, pkgs, config, myconfig, mylibs, ... }:
   2 let
   3     ludivinecassal = pkgs.callPackage ./ludivinecassal.nix { inherit (mylibs) fetchedGitPrivate; };
   4     ludivinecassal_dev  = ludivinecassal {
   5       config = myconfig.env.websites.ludivinecassal.integration;
   6     };
   7     ludivinecassal_prod = ludivinecassal {
   8       config = myconfig.env.websites.ludivinecassal.production;
   9     };
  10
  11     cfg = config.services.myWebsites.Ludivine;
  12 in {
  13   options.services.myWebsites.Ludivine = {
  14     production = {
  15       enable = lib.mkEnableOption "enable Ludivine's website in production";
  16     };
  17     integration = {
  18       enable = lib.mkEnableOption "enable Ludivine's website in integration";
  19     };
  20   };
  21
  22   config = lib.mkMerge [
  23     (lib.mkIf cfg.production.enable {
  24       deployment.keys = ludivinecassal_prod.keys;
  25       services.myWebsites.commons.stats.enable = true;
  26       services.myWebsites.commons.stats.sites = [
  27         {
  28           name = "ludivinecassal.com";
  29           conf = ./goaccess.conf;
  30         }
  31       ];
  32
  33       security.acme.certs."ludivinecassal" = config.services.myCertificates.certConfig // {
  34         domain = "ludivinecassal.com";
  35         extraDomains = {
  36           "www.ludivinecassal.com" = null;
  37         };
  38       };
  39
  40       services.myPhpfpm.serviceDependencies.ludivinecassal_prod = ludivinecassal_prod.phpFpm.serviceDeps;
  41       services.myPhpfpm.poolConfigs.ludivinecassal_prod = ludivinecassal_prod.phpFpm.pool;
  42       system.activationScripts.ludivinecassal_prod = ludivinecassal_prod.activationScript;
  43       system.extraSystemBuilderCmds = ''
  44         mkdir -p $out/webapps
  45         ln -s ${ludivinecassal_prod.webRoot} $out/webapps/${ludivinecassal_prod.apache.webappName}
  46         '';
  47       services.myWebsites.production.modules = ludivinecassal_prod.apache.modules;
  48       services.myWebsites.production.vhostConfs.ludivine = {
  49         certName    = "ludivinecassal";
  50         hosts       = ["ludivinecassal.com" "www.ludivinecassal.com" ];
  51         root        = ludivinecassal_prod.apache.root;
  52         extraConfig = [ ludivinecassal_prod.apache.vhostConf ];
  53       };
  54     })
  55     (lib.mkIf cfg.integration.enable {
  56       deployment.keys = ludivinecassal_dev.keys;
  57       security.acme.certs."eldiron".extraDomains."ludivine.immae.eu" = null;
  58
  59       services.myPhpfpm.serviceDependencies.ludivinecassal_dev = ludivinecassal_dev.phpFpm.serviceDeps;
  60       services.myPhpfpm.poolConfigs.ludivinecassal_dev = ludivinecassal_dev.phpFpm.pool;
  61       system.activationScripts.ludivinecassal_dev = ludivinecassal_dev.activationScript;
  62       system.extraSystemBuilderCmds = ''
  63         mkdir -p $out/webapps
  64         ln -s ${ludivinecassal_dev.webRoot} $out/webapps/${ludivinecassal_dev.apache.webappName}
  65         '';
  66       services.myWebsites.apacheConfig.ludivinecassal_dev.modules = ludivinecassal_dev.apache.modules;
  67       services.myWebsites.integration.modules = ludivinecassal_dev.apache.modules;
  68       services.myWebsites.integration.vhostConfs.ludivine = {
  69         certName    = "eldiron";
  70         hosts       = [ "ludivine.immae.eu" ];
  71         root        = ludivinecassal_dev.apache.root;
  72         extraConfig = [ ludivinecassal_dev.apache.vhostConf ];
  73       };
  74     })
  75   ];
  76 }