nixops/modules/websites/connexionswing/default.nix

   1 { lib, pkgs, config, mylibs, myconfig, ... }:
   2 let
   3     connexionswing = pkgs.callPackage ./connexionswing.nix { inherit (mylibs) fetchedGitPrivate; };
   4     connexionswing_dev  = connexionswing {
   5       config = myconfig.env.websites.connexionswing.integration;
   6     };
   7     connexionswing_prod = connexionswing {
   8       config = myconfig.env.websites.connexionswing.production;
   9     };
  10
  11     cfg = config.services.myWebsites.Connexionswing;
  12 in {
  13   options.services.myWebsites.Connexionswing = {
  14     production = {
  15       enable = lib.mkEnableOption "enable Connexionswing's website in production";
  16     };
  17     integration = {
  18       enable = lib.mkEnableOption "enable Connexionswing's website in integration";
  19     };
  20   };
  21
  22   imports = [
  23     ../commons/stats.nix
  24   ];
  25
  26   config = lib.mkMerge [
  27     (lib.mkIf cfg.production.enable {
  28       deployment.keys = connexionswing_prod.keys;
  29       services.myWebsites.commons.stats.enable = true;
  30       services.myWebsites.commons.stats.sites = [
  31         {
  32           name = "connexionswing.com";
  33           conf = ./goaccess.conf;
  34         }
  35       ];
  36
  37       security.acme.certs."connexionswing" = config.services.myCertificates.certConfig // {
  38         domain = "connexionswing.com";
  39         extraDomains = {
  40           "www.connexionswing.com" = null;
  41           "sandetludo.com" = null;
  42           "www.sandetludo.com" = null;
  43         };
  44       };
  45
  46       services.myPhpfpm.poolConfigs.connexionswing_prod = connexionswing_prod.phpFpm.pool;
  47       services.myPhpfpm.poolPhpConfigs.connexionswing_prod = connexionswing_prod.phpFpm.phpConfig;
  48       system.activationScripts.connexionswing_prod = connexionswing_prod.activationScript;
  49       system.extraSystemBuilderCmds = ''
  50         mkdir -p $out/webapps
  51         ln -s ${connexionswing_prod.webRoot} $out/webapps/${connexionswing_prod.apache.webappName}
  52         '';
  53       services.myWebsites.production.modules = connexionswing_prod.apache.modules;
  54       services.myWebsites.production.vhostConfs.connexionswing = {
  55         certName    = "connexionswing";
  56         hosts       = ["connexionswing.com" "sandetludo.com" "www.connexionswing.com" "www.sandetludo.com" ];
  57         root        = connexionswing_prod.apache.root;
  58         extraConfig = [ connexionswing_prod.apache.vhostConf ];
  59       };
  60     })
  61     (lib.mkIf cfg.integration.enable {
  62       deployment.keys = connexionswing_dev.keys;
  63       security.acme.certs."eldiron".extraDomains."sandetludo.immae.eu" = null;
  64       security.acme.certs."eldiron".extraDomains."connexionswing.immae.eu" = null;
  65       services.myPhpfpm.poolConfigs.connexionswing_dev = connexionswing_dev.phpFpm.pool;
  66       services.myPhpfpm.poolPhpConfigs.connexionswing_dev = connexionswing_dev.phpFpm.phpConfig;
  67       system.activationScripts.connexionswing_dev = connexionswing_dev.activationScript;
  68       system.extraSystemBuilderCmds = ''
  69         mkdir -p $out/webapps
  70         ln -s ${connexionswing_dev.webRoot} $out/webapps/${connexionswing_dev.apache.webappName}
  71         '';
  72       services.myWebsites.integration.modules = connexionswing_dev.apache.modules;
  73       services.myWebsites.integration.vhostConfs.connexionswing = {
  74         certName    = "eldiron";
  75         hosts       = ["connexionswing.immae.eu" "sandetludo.immae.eu" ];
  76         root        = connexionswing_dev.apache.root;
  77         extraConfig = [ connexionswing_dev.apache.vhostConf ];
  78       };
  79     })
  80   ];
  81 }
  82