nixops/modules/websites/connexionswing/default.nix

   1 { lib, pkgs, config, mylibs, myconfig, ... }:
   2 let
   3     connexionswing = pkgs.callPackage ./connexionswing.nix { inherit (mylibs) fetchedGitPrivate; };
   4     connexionswing_dev  = connexionswing {
   5       config = myconfig.env.websites.connexionswing.integration;
   6     };
   7     connexionswing_prod = connexionswing {
   8       config = myconfig.env.websites.connexionswing.production;
   9     };
  10
  11     cfg = config.services.myWebsites.Connexionswing;
  12 in {
  13   options.services.myWebsites.Connexionswing = {
  14     production = {
  15       enable = lib.mkEnableOption "enable Connexionswing's website in production";
  16     };
  17     integration = {
  18       enable = lib.mkEnableOption "enable Connexionswing's website in integration";
  19     };
  20   };
  21
  22   imports = [
  23     ../commons/stats.nix
  24   ];
  25
  26   config = lib.mkMerge [
  27     (lib.mkIf cfg.production.enable {
  28       services.myWebsites.commons.stats.enable = true;
  29       services.myWebsites.commons.stats.sites = [
  30         {
  31           name = "connexionswing.com";
  32           conf = ./goaccess.conf;
  33         }
  34       ];
  35
  36       security.acme.certs."connexionswing" = config.services.myCertificates.certConfig // {
  37         domain = "connexionswing.com";
  38         extraDomains = {
  39           "www.connexionswing.com" = null;
  40           "sandetludo.com" = null;
  41           "www.sandetludo.com" = null;
  42         };
  43       };
  44
  45       services.myPhpfpm.poolConfigs.connexionswing_prod = connexionswing_prod.phpFpm.pool;
  46       services.myPhpfpm.poolPhpConfigs.connexionswing_prod = connexionswing_prod.phpFpm.phpConfig;
  47       system.activationScripts.connexionswing_prod = connexionswing_prod.activationScript;
  48       services.myWebsites.production.modules = connexionswing_prod.apache.modules;
  49       services.myWebsites.production.vhostConfs.connexionswing = {
  50         certName    = "connexionswing";
  51         hosts       = ["connexionswing.com" "sandetludo.com" "www.connexionswing.com" "www.sandetludo.com" ];
  52         root        = connexionswing_prod.webRoot;
  53         extraConfig = [ connexionswing_prod.apache.vhostConf ];
  54       };
  55     })
  56     (lib.mkIf cfg.integration.enable {
  57       security.acme.certs."eldiron".extraDomains."sandetludo.immae.eu" = null;
  58       security.acme.certs."eldiron".extraDomains."connexionswing.immae.eu" = null;
  59       services.myPhpfpm.poolConfigs.connexionswing_dev = connexionswing_dev.phpFpm.pool;
  60       services.myPhpfpm.poolPhpConfigs.connexionswing_dev = connexionswing_dev.phpFpm.phpConfig;
  61       system.activationScripts.connexionswing_dev = connexionswing_dev.activationScript;
  62       services.myWebsites.integration.modules = connexionswing_dev.apache.modules;
  63       services.myWebsites.integration.vhostConfs.connexionswing = {
  64         certName    = "eldiron";
  65         hosts       = ["connexionswing.immae.eu" "sandetludo.immae.eu" ];
  66         root        = connexionswing_dev.webRoot;
  67         extraConfig = [ connexionswing_dev.apache.vhostConf ];
  68       };
  69     })
  70   ];
  71 }
  72