nixops/modules/websites/aten/default.nix

   1 { lib, pkgs, config, myconfig, mylibs, ... }:
   2 let
   3   aten_dev = pkgs.callPackage ./aten.nix {
   4     inherit (pkgs.private.webapps) aten;
   5     config = myconfig.env.websites.aten.integration;
   6   };
   7   aten_prod = pkgs.callPackage ./aten.nix {
   8     inherit (pkgs.private.webapps) aten;
   9     config = myconfig.env.websites.aten.production;
  10   };
  11
  12   cfg = config.services.myWebsites.Aten;
  13 in {
  14   options.services.myWebsites.Aten = {
  15     production = {
  16       enable = lib.mkEnableOption "enable Aten's website in production";
  17     };
  18     integration = {
  19       enable = lib.mkEnableOption "enable Aten's website in integration";
  20     };
  21   };
  22
  23   config = lib.mkMerge [
  24     (lib.mkIf cfg.production.enable {
  25       secrets.keys = aten_prod.keys;
  26       services.webstats.sites = [ { name = "aten.pro"; } ];
  27
  28       security.acme.certs."aten" = config.services.myCertificates.certConfig // {
  29         domain = "aten.pro";
  30         extraDomains = {
  31           "www.aten.pro" = null;
  32         };
  33       };
  34
  35       services.myPhpfpm.preStart.aten_prod = aten_prod.phpFpm.preStart;
  36       services.myPhpfpm.serviceDependencies.aten_prod = aten_prod.phpFpm.serviceDeps;
  37       services.myPhpfpm.poolConfigs.aten_prod = aten_prod.phpFpm.pool;
  38       system.activationScripts.aten_prod = aten_prod.activationScript;
  39       system.extraSystemBuilderCmds = ''
  40         mkdir -p $out/webapps
  41         ln -s ${aten_prod.app.webRoot} $out/webapps/${aten_prod.apache.webappName}
  42         '';
  43       services.myWebsites.apacheConfig.aten_prod.modules = aten_prod.apache.modules;
  44       services.myWebsites.production.modules = aten_prod.apache.modules;
  45       services.myWebsites.production.vhostConfs.aten = {
  46         certName    = "aten";
  47         hosts       = [ "aten.pro" "www.aten.pro" ];
  48         root        = aten_prod.apache.root;
  49         extraConfig = [ aten_prod.apache.vhostConf ];
  50       };
  51     })
  52     (lib.mkIf cfg.integration.enable {
  53       secrets.keys = aten_dev.keys;
  54       security.acme.certs."eldiron".extraDomains."dev.aten.pro" = null;
  55       services.myPhpfpm.preStart.aten_dev = aten_dev.phpFpm.preStart;
  56       services.myPhpfpm.serviceDependencies.aten_dev = aten_dev.phpFpm.serviceDeps;
  57       services.myPhpfpm.poolConfigs.aten_dev = aten_dev.phpFpm.pool;
  58       system.activationScripts.aten_dev = aten_dev.activationScript;
  59       system.extraSystemBuilderCmds = ''
  60         mkdir -p $out/webapps
  61         ln -s ${aten_dev.app.webRoot} $out/webapps/${aten_dev.apache.webappName}
  62         '';
  63       services.myWebsites.integration.modules = aten_dev.apache.modules;
  64       services.myWebsites.integration.vhostConfs.aten = {
  65         certName    = "eldiron";
  66         hosts       = [ "dev.aten.pro" ];
  67         root        = aten_dev.apache.root;
  68         extraConfig = [ aten_dev.apache.vhostConf ];
  69       };
  70     })
  71   ];
  72 }
  73