nixops/modules/gitolite/default.nix

   1 { lib, pkgs, config, myconfig, mylibs, ... }:
   2 let
   3     cfg = config.services.myGitolite;
   4 in {
   5   options.services.myGitolite = {
   6     enable = lib.mkEnableOption "my gitolite service";
   7     gitoliteDir = lib.mkOption {
   8       type = lib.types.string;
   9       default = "/var/lib/gitolite";
  10     };
  11   };
  12
  13   config = lib.mkIf cfg.enable {
  14     nixpkgs.config.packageOverrides = oldpkgs: rec {
  15       gitolite = oldpkgs.gitolite.overrideAttrs(old: rec {
  16         name = "gitolite-${version}";
  17         version = "3.6.10";
  18         src = pkgs.fetchFromGitHub {
  19           owner = "sitaramc";
  20           repo = "gitolite";
  21           rev = "v${version}";
  22           sha256 = "0p2697mn6rwm03ndlv7q137zczai82n41aplq1g006ii7f12xy8h";
  23         };
  24       });
  25     };
  26
  27     networking.firewall.allowedTCPPorts = [ 9418 ];
  28
  29     services.gitDaemon = {
  30       enable = true;
  31       user = "gitolite";
  32       group = "gitolite";
  33       basePath = "${cfg.gitoliteDir}/repositories";
  34     };
  35
  36     system.activationScripts.gitolite = let
  37       gitolite_ldap_groups = mylibs.wrap {
  38         name = "gitolite_ldap_groups.sh";
  39         file = ./gitolite_ldap_groups.sh;
  40         vars = {
  41           LDAP_PASS = myconfig.env.tools.gitolite.ldap.password;
  42         };
  43         paths = [ pkgs.openldap pkgs.stdenv.shellPackage pkgs.gnugrep pkgs.coreutils ];
  44       };
  45     in {
  46       deps = [ "users" ];
  47       text = ''
  48         if [ -d ${cfg.gitoliteDir} ]; then
  49           ln -sf ${gitolite_ldap_groups} ${cfg.gitoliteDir}/gitolite_ldap_groups.sh
  50           chmod g+rx ${cfg.gitoliteDir}
  51         fi
  52         if [ -f ${cfg.gitoliteDir}/projects.list ]; then
  53           chmod g+r ${cfg.gitoliteDir}/projects.list
  54         fi
  55       '';
  56     };
  57
  58     users.users.wwwrun.extraGroups = [ "gitolite" ];
  59
  60     users.users.gitolite.packages = let
  61       python-packages = python-packages: with python-packages; [
  62         simplejson
  63         urllib3
  64       ];
  65     in
  66       [
  67         (pkgs.python3.withPackages python-packages)
  68       ];
  69     # Installation: https://git.immae.eu/mantisbt/view.php?id=93
  70     services.gitolite = {
  71       enable = true;
  72       adminPubkey = "ssh-rsa AAAAB3NzaC1yc2EAAAADAQABAAABAQDXqRbiHw7QoHADNIEuo4nUT9fSOIEBMdJZH0bkQAxXyJFyCM1IMz0pxsHV0wu9tdkkr36bPEUj2aV5bkYLBN6nxcV2Y49X8bjOSCPfx3n6Own1h+NeZVBj4ZByrFmqCbTxUJIZ2bZKcWOFncML39VmWdsVhNjg0X4NBBehqXRIKr2gt3E/ESAxTYJFm0BnU0baciw9cN0bsRGqvFgf5h2P48CIAfwhVcGmPQnnAwabnosYQzRWxR0OygH5Kd8mePh6FheIRIigfXsDO8f/jdxwut8buvNIf3m5EBr3tUbTsvM+eV3M5vKGt7sk8T64DVtepTSdOOWtp+47ktsnHOMh immae@immae.eu";
  73     };
  74   };
  75 }