modules/webapps/webstats/default.nix

   1 { lib, pkgs, config, ... }:
   2 let
   3   name = "goaccess";
   4   cfg = config.services.webstats;
   5 in {
   6   options.services.webstats = {
   7     dataDir = lib.mkOption {
   8       type = lib.types.path;
   9       default = "/var/lib/${name}";
  10       description = ''
  11         The directory where Goaccess stores its data.
  12       '';
  13     };
  14     sites = lib.mkOption {
  15       type = lib.types.listOf (lib.types.submodule {
  16         options = {
  17           conf = lib.mkOption {
  18             type = lib.types.nullOr lib.types.path;
  19             default = null;
  20             description = ''
  21               use custom goaccess configuration file instead of the
  22               default one.
  23               '';
  24           };
  25           name = lib.mkOption {
  26             type = lib.types.str;
  27             description  = ''
  28               Domain name. Corresponds to the Apache file name and the
  29               folder name in which the state will be saved.
  30               '';
  31           };
  32         };
  33       });
  34       default = [];
  35       description = "Sites to generate stats";
  36     };
  37   };
  38
  39   config = lib.mkIf (builtins.length cfg.sites > 0) {
  40     services.duplyBackup.profiles.goaccess = {
  41       rootDir = cfg.dataDir;
  42     };
  43     users.users.root.packages = [
  44       pkgs.goaccess
  45     ];
  46
  47     services.cron = {
  48       enable = true;
  49       systemCronJobs = let
  50         stats = domain: conf: let
  51           config = if builtins.isNull conf
  52             then pkgs.runCommand "goaccess.conf" {
  53                 dbPath = "${cfg.dataDir}/${domain}";
  54               } "substituteAll ${./goaccess.conf} $out"
  55             else conf;
  56           d = pkgs.writeScriptBin "stats-${domain}" ''
  57             #!${pkgs.stdenv.shell}
  58             set -e
  59             shopt -s nullglob
  60             TMPFILE=$(mktemp)
  61             trap "rm -f $TMPFILE" EXIT
  62
  63             mkdir -p ${cfg.dataDir}/${domain}
  64             for i in /var/log/httpd/access-${domain}*.gz; do
  65               zcat "$i" >> $TMPFILE
  66             done
  67             cat /var/log/httpd/access-${domain}.log > $TMPFILE
  68             ${pkgs.goaccess}/bin/goaccess $TMPFILE --no-progress -o ${cfg.dataDir}/${domain}/index.html -p ${config}
  69             '';
  70           in "${d}/bin/stats-${domain}";
  71         allStats = sites: pkgs.writeScript "stats" ''
  72           #!${pkgs.stdenv.shell}
  73
  74           mkdir -p ${cfg.dataDir}
  75           ${builtins.concatStringsSep "\n" (map (v: stats v.name v.conf) sites)}
  76           '';
  77       in
  78         [
  79           "5 0 * * * root ${allStats cfg.sites}"
  80         ];
  81     };
  82   };
  83 }