modules/private/websites/tools/tools/shaarli.nix

   1 { lib, env, stdenv, fetchurl, shaarli, config }:
   2 let
   3   varDir = "/var/lib/shaarli";
   4 in rec {
   5   backups = {
   6     rootDir = varDir;
   7     remotes = [ "eriomem" "ovh" ];
   8   };
   9   activationScript = ''
  10     install -m 0755 -o ${apache.user} -g ${apache.group} -d ${varDir} \
  11       ${varDir}/cache ${varDir}/pagecache ${varDir}/tmp ${varDir}/data \
  12       ${varDir}/phpSessions
  13     '';
  14   webRoot = shaarli varDir;
  15   apache = rec {
  16     user = "wwwrun";
  17     group = "wwwrun";
  18     modules =  [ "proxy_fcgi" "rewrite" "env" ];
  19     root = webRoot;
  20     vhostConf = socket: ''
  21       Alias /Shaarli "${root}"
  22
  23       Include ${config.secrets.fullPaths."webapps/tools-shaarli"}
  24       <Location /Shaarli>
  25         Header set Access-Control-Allow-Origin "*"
  26         Header set Access-Control-Allow-Methods "GET, POST, PUT, DELETE, OPTIONS"
  27         Header set Access-Control-Allow-Headers "Origin, X-Requested-With, Content-Type, Accept, Authorization, Client-Security-Token, Accept-Encoding"
  28       </Location>
  29       <Directory "${root}">
  30         DirectoryIndex index.php index.htm index.html
  31         Options Indexes FollowSymLinks MultiViews Includes
  32         AllowOverride All
  33         Require all granted
  34         <FilesMatch "\.php$">
  35           SetHandler "proxy:unix:${socket}|fcgi://localhost"
  36         </FilesMatch>
  37       </Directory>
  38       '';
  39   };
  40   keys."webapps/tools-shaarli" = {
  41     user = apache.user;
  42     group = apache.group;
  43     permissions = "0400";
  44     text = ''
  45       SetEnv SHAARLI_LDAP_PASSWORD "${env.ldap.password}"
  46       SetEnv SHAARLI_LDAP_DN       "${env.ldap.dn}"
  47       SetEnv SHAARLI_LDAP_HOST     "ldaps://${env.ldap.host}"
  48       SetEnv SHAARLI_LDAP_BASE     "${env.ldap.base}"
  49       SetEnv SHAARLI_LDAP_FILTER   "${env.ldap.filter}"
  50       '';
  51   };
  52   phpFpm = rec {
  53     serviceDeps = [ "openldap.service" ];
  54     basedir = builtins.concatStringsSep ":" [ webRoot varDir ];
  55     pool = {
  56       "listen.owner" = apache.user;
  57       "listen.group" = apache.group;
  58       "pm" = "ondemand";
  59       "pm.max_children" = "60";
  60       "pm.process_idle_timeout" = "60";
  61
  62       # Needed to avoid clashes in browser cookies (same domain)
  63       "php_value[session.name]" = "ShaarliPHPSESSID";
  64       "php_admin_value[open_basedir]" = "${basedir}:/tmp";
  65       "php_admin_value[session.save_path]" = "${varDir}/phpSessions";
  66       "php_admin_value[upload_max_filesize]" = "200M";
  67       "php_admin_value[post_max_size]" = "200M";
  68     };
  69   };
  70 }