modules/private/websites/tools/tools/default.nix

   1 { lib, pkgs, config, ... }:
   2 let
   3   adminer = pkgs.callPackage ./adminer.nix {
   4     inherit (pkgs.webapps) adminer;
   5   };
   6   ympd = pkgs.callPackage ./ympd.nix {
   7     env = config.myEnv.tools.ympd;
   8   };
   9   ttrss = pkgs.callPackage ./ttrss.nix {
  10     inherit (pkgs.webapps) ttrss ttrss-plugins;
  11     env = config.myEnv.tools.ttrss;
  12   };
  13   kanboard = pkgs.callPackage ./kanboard.nix  {
  14     env = config.myEnv.tools.kanboard;
  15   };
  16   wallabag = pkgs.callPackage ./wallabag.nix {
  17     inherit (pkgs.webapps) wallabag;
  18     env = config.myEnv.tools.wallabag;
  19   };
  20   yourls = pkgs.callPackage ./yourls.nix {
  21     inherit (pkgs.webapps) yourls yourls-plugins;
  22     env = config.myEnv.tools.yourls;
  23   };
  24   rompr = pkgs.callPackage ./rompr.nix {
  25     inherit (pkgs.webapps) rompr;
  26     env = config.myEnv.tools.rompr;
  27   };
  28   shaarli = pkgs.callPackage ./shaarli.nix {
  29     env = config.myEnv.tools.shaarli;
  30   };
  31   dokuwiki = pkgs.callPackage ./dokuwiki.nix {
  32     inherit (pkgs.webapps) dokuwiki dokuwiki-plugins;
  33   };
  34   ldap = pkgs.callPackage ./ldap.nix {
  35     inherit (pkgs.webapps) phpldapadmin;
  36     env = config.myEnv.tools.phpldapadmin;
  37   };
  38
  39   cfg = config.myServices.websites.tools.tools;
  40 in {
  41   options.myServices.websites.tools.tools = {
  42     enable = lib.mkEnableOption "enable tools website";
  43   };
  44
  45   config = lib.mkIf cfg.enable {
  46     secrets.keys =
  47       kanboard.keys
  48       ++ ldap.keys
  49       ++ shaarli.keys
  50       ++ ttrss.keys
  51       ++ wallabag.keys
  52       ++ yourls.keys;
  53
  54     services.duplyBackup.profiles = {
  55       dokuwiki = dokuwiki.backups;
  56       kanboard = kanboard.backups;
  57       rompr = rompr.backups;
  58       shaarli = shaarli.backups;
  59       ttrss = ttrss.backups;
  60       wallabag = wallabag.backups;
  61     };
  62
  63     services.websites.env.tools.modules =
  64       [ "proxy_fcgi" ]
  65       ++ adminer.apache.modules
  66       ++ ympd.apache.modules
  67       ++ ttrss.apache.modules
  68       ++ wallabag.apache.modules
  69       ++ yourls.apache.modules
  70       ++ rompr.apache.modules
  71       ++ shaarli.apache.modules
  72       ++ dokuwiki.apache.modules
  73       ++ ldap.apache.modules
  74       ++ kanboard.apache.modules;
  75
  76     services.websites.env.integration.vhostConfs.devtools = {
  77       certName    = "eldiron";
  78       addToCerts  = true;
  79       hosts       = ["devtools.immae.eu" ];
  80       root        = "/var/lib/ftp/devtools.immae.eu";
  81       extraConfig = [
  82         ''
  83           <Directory "/var/lib/ftp/devtools.immae.eu">
  84             DirectoryIndex index.php index.htm index.html
  85             AllowOverride all
  86             Require all granted
  87             <FilesMatch "\.php$">
  88               SetHandler "proxy:unix:/var/run/phpfpm/devtools.sock|fcgi://localhost"
  89             </FilesMatch>
  90           </Directory>
  91           ''
  92       ];
  93     };
  94
  95     services.websites.env.tools.vhostConfs.tools = {
  96       certName    = "eldiron";
  97       addToCerts  = true;
  98       hosts       = ["tools.immae.eu" ];
  99       root        = "/var/lib/ftp/tools.immae.eu";
 100       extraConfig = [
 101         ''
 102           RedirectMatch 301 ^/roundcube(.*)$   https://mail.immae.eu/roundcube$1
 103           RedirectMatch 301 ^/jappix(.*)$      https://im.immae.fr/converse
 104
 105           <Directory "/var/lib/ftp/tools.immae.eu">
 106             DirectoryIndex index.php index.htm index.html
 107             AllowOverride all
 108             Require all granted
 109             <FilesMatch "\.php$">
 110               SetHandler "proxy:unix:/var/run/phpfpm/tools.sock|fcgi://localhost"
 111             </FilesMatch>
 112           </Directory>
 113           ''
 114         adminer.apache.vhostConf
 115         ympd.apache.vhostConf
 116         ttrss.apache.vhostConf
 117         wallabag.apache.vhostConf
 118         yourls.apache.vhostConf
 119         rompr.apache.vhostConf
 120         shaarli.apache.vhostConf
 121         dokuwiki.apache.vhostConf
 122         ldap.apache.vhostConf
 123         kanboard.apache.vhostConf
 124       ];
 125     };
 126
 127     services.websites.env.tools.vhostConfs.outils = {
 128       certName   = "eldiron";
 129       addToCerts = true;
 130       hosts      = [ "outils.immae.eu" "outils.immae.fr" ];
 131       root       = null;
 132       extraConfig = [
 133         ''
 134         RedirectMatch 301 ^/mediagoblin(.*)$ https://mgoblin.immae.eu$1
 135
 136         RedirectMatch 301 ^/ether(.*)$       https://ether.immae.eu$1
 137
 138         RedirectMatch 301 ^/nextcloud(.*)$   https://cloud.immae.eu$1
 139         RedirectMatch 301 ^/owncloud(.*)$    https://cloud.immae.eu$1
 140
 141         RedirectMatch 301 ^/carddavmate(.*)$ https://dav.immae.eu/infcloud$1
 142         RedirectMatch 301 ^/caldavzap(.*)$   https://dav.immae.eu/infcloud$1
 143         RedirectMatch 301 ^/caldav.php(.*)$  https://dav.immae.eu/caldav.php$1
 144         RedirectMatch 301 ^/davical(.*)$     https://dav.immae.eu/davical$1
 145
 146         RedirectMatch 301 ^/taskweb(.*)$     https://task.immae.eu/taskweb$1
 147
 148         RedirectMatch 301 ^/roundcube(.*)$   https://mail.immae.eu/roundcube$1
 149
 150         RedirectMatch 301 ^/jappix(.*)$      https://im.immae.fr/converse
 151
 152         RedirectMatch 301 ^/(.*)$            https://tools.immae.eu/$1
 153         ''
 154       ];
 155     };
 156
 157     systemd.services = {
 158       phpfpm-dokuwiki = {
 159         after = lib.mkAfter dokuwiki.phpFpm.serviceDeps;
 160         wants = dokuwiki.phpFpm.serviceDeps;
 161       };
 162       phpfpm-kanboard = {
 163         after = lib.mkAfter kanboard.phpFpm.serviceDeps;
 164         wants = kanboard.phpFpm.serviceDeps;
 165       };
 166       phpfpm-ldap = {
 167         after = lib.mkAfter ldap.phpFpm.serviceDeps;
 168         wants = ldap.phpFpm.serviceDeps;
 169       };
 170       phpfpm-shaarli = {
 171         after = lib.mkAfter shaarli.phpFpm.serviceDeps;
 172         wants = shaarli.phpFpm.serviceDeps;
 173       };
 174       phpfpm-ttrss = {
 175         after = lib.mkAfter ttrss.phpFpm.serviceDeps;
 176         wants = ttrss.phpFpm.serviceDeps;
 177       };
 178       phpfpm-wallabag = {
 179         after = lib.mkAfter wallabag.phpFpm.serviceDeps;
 180         wants = wallabag.phpFpm.serviceDeps;
 181         preStart = lib.mkAfter wallabag.phpFpm.preStart;
 182       };
 183       phpfpm-yourls = {
 184         after = lib.mkAfter yourls.phpFpm.serviceDeps;
 185         wants = yourls.phpFpm.serviceDeps;
 186       };
 187       ympd = {
 188         description = "Standalone MPD Web GUI written in C";
 189         wantedBy = [ "multi-user.target" ];
 190         script = ''
 191           export MPD_PASSWORD=$(cat /var/secrets/mpd)
 192           ${pkgs.ympd}/bin/ympd --host ${ympd.config.host} --port ${toString ympd.config.port} --webport ${ympd.config.webPort} --user nobody
 193           '';
 194       };
 195       tt-rss = {
 196         description = "Tiny Tiny RSS feeds update daemon";
 197         serviceConfig = {
 198           User = "wwwrun";
 199           ExecStart = "${pkgs.php}/bin/php ${ttrss.webRoot}/update.php --daemon";
 200           StandardOutput = "syslog";
 201           StandardError = "syslog";
 202           PermissionsStartOnly = true;
 203         };
 204
 205         wantedBy = [ "multi-user.target" ];
 206         requires = ["postgresql.service"];
 207         after = ["network.target" "postgresql.service"];
 208       };
 209     };
 210
 211     services.filesWatcher.ympd = {
 212       restart = true;
 213       paths = [ "/var/secrets/mpd" ];
 214     };
 215
 216     services.phpfpm.pools.devtools = {
 217       listen = "/var/run/phpfpm/devtools.sock";
 218       extraConfig = ''
 219         user = wwwrun
 220         group = wwwrun
 221         listen.owner = wwwrun
 222         listen.group = wwwrun
 223         pm = dynamic
 224         pm.max_children = 60
 225         pm.start_servers = 2
 226         pm.min_spare_servers = 1
 227         pm.max_spare_servers = 10
 228
 229         php_admin_value[open_basedir] = "/run/wrappers/bin/sendmail:/var/lib/ftp/devtools.immae.eu:/tmp"
 230         '';
 231       phpOptions = config.services.phpfpm.phpOptions + ''
 232         extension=${pkgs.php}/lib/php/extensions/mysqli.so
 233         extension=${pkgs.phpPackages.redis}/lib/php/extensions/redis.so
 234         extension=${pkgs.phpPackages.apcu}/lib/php/extensions/apcu.so
 235         zend_extension=${pkgs.php}/lib/php/extensions/opcache.so
 236         '';
 237     };
 238
 239     services.phpfpm.poolConfigs = {
 240       adminer = adminer.phpFpm.pool;
 241       ttrss = ttrss.phpFpm.pool;
 242       wallabag = wallabag.phpFpm.pool;
 243       yourls = yourls.phpFpm.pool;
 244       rompr = rompr.phpFpm.pool;
 245       shaarli = shaarli.phpFpm.pool;
 246       dokuwiki = dokuwiki.phpFpm.pool;
 247       ldap = ldap.phpFpm.pool;
 248       kanboard = kanboard.phpFpm.pool;
 249       tools = ''
 250         listen = /var/run/phpfpm/tools.sock
 251         user = wwwrun
 252         group = wwwrun
 253         listen.owner = wwwrun
 254         listen.group = wwwrun
 255         pm = dynamic
 256         pm.max_children = 60
 257         pm.start_servers = 2
 258         pm.min_spare_servers = 1
 259         pm.max_spare_servers = 10
 260
 261         ; Needed to avoid clashes in browser cookies (same domain)
 262         php_value[session.name] = ToolsPHPSESSID
 263         php_admin_value[open_basedir] = "/run/wrappers/bin/sendmail:/var/lib/ftp/tools.immae.eu:/tmp"
 264         '';
 265     };
 266
 267     system.activationScripts = {
 268       adminer = adminer.activationScript;
 269       ttrss = ttrss.activationScript;
 270       wallabag = wallabag.activationScript;
 271       yourls = yourls.activationScript;
 272       rompr = rompr.activationScript;
 273       shaarli = shaarli.activationScript;
 274       dokuwiki = dokuwiki.activationScript;
 275       kanboard = kanboard.activationScript;
 276       ldap = ldap.activationScript;
 277     };
 278
 279     myServices.websites.webappDirs = {
 280       _adminer = adminer.webRoot;
 281       "${dokuwiki.apache.webappName}" = dokuwiki.webRoot;
 282       "${ldap.apache.webappName}" = "${ldap.webRoot}/htdocs";
 283       "${rompr.apache.webappName}" = rompr.webRoot;
 284       "${shaarli.apache.webappName}" = shaarli.webRoot;
 285       "${ttrss.apache.webappName}" = ttrss.webRoot;
 286       "${wallabag.apache.webappName}" = wallabag.webRoot;
 287       "${yourls.apache.webappName}" = yourls.webRoot;
 288       "${kanboard.apache.webappName}" = kanboard.webRoot;
 289     };
 290
 291     services.websites.env.tools.watchPaths = [
 292       "/var/secrets/webapps/tools-shaarli"
 293     ];
 294     services.filesWatcher.phpfpm-wallabag = {
 295       restart = true;
 296       paths = [ "/var/secrets/webapps/tools-wallabag" ];
 297     };
 298   };
 299 }
 300