modules/private/websites/tools/git/default.nix

   1 { lib, pkgs, config, ... }:
   2 let
   3     mantisbt = pkgs.callPackage ./mantisbt.nix {
   4       inherit (pkgs.webapps) mantisbt_2 mantisbt_2-plugins;
   5       env = config.myEnv.tools.mantisbt;
   6       inherit config;
   7     };
   8     gitweb = pkgs.callPackage ./gitweb.nix {
   9       gitoliteDir = config.myServices.gitolite.gitoliteDir;
  10     };
  11
  12     cfg = config.myServices.websites.tools.git;
  13 in {
  14   options.myServices.websites.tools.git = {
  15     enable = lib.mkEnableOption "enable git's website";
  16   };
  17
  18   config = lib.mkIf cfg.enable {
  19     secrets.keys = mantisbt.keys;
  20     services.websites.env.tools.modules =
  21       gitweb.apache.modules ++
  22       mantisbt.apache.modules;
  23     services.websites.webappDirs."${gitweb.apache.webappName}" = gitweb.webRoot;
  24     services.websites.webappDirs."${mantisbt.apache.webappName}" = mantisbt.webRoot;
  25
  26     system.activationScripts.mantisbt = mantisbt.activationScript;
  27     services.websites.env.tools.vhostConfs.git = {
  28       certName    = "eldiron";
  29       addToCerts  = true;
  30       hosts       = ["git.immae.eu" ];
  31       root        = gitweb.apache.root;
  32       extraConfig = [
  33         gitweb.apache.vhostConf
  34         (mantisbt.apache.vhostConf config.services.phpfpm.pools.mantisbt.socket)
  35         ''
  36           RewriteEngine on
  37           RewriteCond %{REQUEST_URI}       ^/releases
  38           RewriteRule /releases(.*)        https://release.immae.eu$1 [P,L]
  39           ''
  40       ];
  41     };
  42     services.phpfpm.pools = {
  43       mantisbt = {
  44         user = config.services.httpd.Tools.user;
  45         group = config.services.httpd.Tools.group;
  46         settings = mantisbt.phpFpm.pool;
  47         phpPackage = pkgs.php72;
  48       };
  49     };
  50   };
  51 }