modules/private/websites/tools/cloud/default.nix

   1 { lib, pkgs, config, myconfig,  ... }:
   2 let
   3   nextcloud = pkgs.webapps.nextcloud.withApps (builtins.attrValues pkgs.webapps.nextcloud-apps);
   4   env = myconfig.env.tools.nextcloud;
   5   varDir = "/var/lib/nextcloud";
   6   webappName = "tools_nextcloud";
   7   apacheRoot = "/run/current-system/webapps/${webappName}";
   8   cfg = config.myServices.websites.tools.cloud;
   9   phpFpm = rec {
  10     basedir = builtins.concatStringsSep ":" (
  11       [ nextcloud varDir ]
  12       ++ builtins.attrValues pkgs.webapps.nextcloud-apps);
  13     socket = "/var/run/phpfpm/nextcloud.sock";
  14     phpConfig = ''
  15       extension=${pkgs.phpPackages.redis}/lib/php/extensions/redis.so
  16       extension=${pkgs.phpPackages.apcu}/lib/php/extensions/apcu.so
  17       zend_extension=${pkgs.php}/lib/php/extensions/opcache.so
  18       '';
  19     pool = ''
  20       user = wwwrun
  21       group = wwwrun
  22       listen.owner = wwwrun
  23       listen.group = wwwrun
  24       pm = ondemand
  25       pm.max_children = 60
  26       pm.process_idle_timeout = 60
  27
  28       php_admin_value[output_buffering] = 0
  29       php_admin_value[max_execution_time] = 1800
  30       php_admin_value[zend_extension] = "opcache"
  31       ;already enabled by default?
  32       ;php_value[opcache.enable] = 1
  33       php_value[opcache.enable_cli] = 1
  34       php_value[opcache.interned_strings_buffer] = 8
  35       php_value[opcache.max_accelerated_files] = 10000
  36       php_value[opcache.memory_consumption] = 128
  37       php_value[opcache.save_comments] = 1
  38       php_value[opcache.revalidate_freq] = 1
  39       php_admin_value[memory_limit] = 512M
  40
  41       php_admin_value[open_basedir] = "/run/wrappers/bin/sendmail:${basedir}:/proc/meminfo:/dev/urandom:/proc/self/fd:/tmp"
  42       php_admin_value[session.save_path] = "${varDir}/phpSessions"
  43       '';
  44   };
  45 in {
  46   options.myServices.websites.tools.cloud = {
  47     enable = lib.mkEnableOption "enable cloud website";
  48   };
  49
  50   config = lib.mkIf cfg.enable {
  51     services.websites.env.tools.modules = [ "proxy_fcgi" ];
  52
  53     services.websites.env.tools.vhostConfs.cloud = {
  54       certName    = "eldiron";
  55       addToCerts  = true;
  56       hosts       = ["cloud.immae.eu" ];
  57       root        = apacheRoot;
  58       extraConfig = [
  59         ''
  60           SetEnvIf Authorization "(.*)" HTTP_AUTHORIZATION=$1
  61           <Directory ${apacheRoot}>
  62             AcceptPathInfo On
  63             DirectoryIndex index.php
  64             Options FollowSymlinks
  65             Require all granted
  66             AllowOverride all
  67
  68             <IfModule mod_headers.c>
  69               Header always set Strict-Transport-Security "max-age=15552000; includeSubDomains; preload"
  70             </IfModule>
  71             <FilesMatch "\.php$">
  72               CGIPassAuth on
  73               SetHandler "proxy:unix:${phpFpm.socket}|fcgi://localhost"
  74             </FilesMatch>
  75
  76           </Directory>
  77         ''
  78       ];
  79     };
  80
  81     secrets.keys = [{
  82       dest = "webapps/tools-nextcloud";
  83       user = "wwwrun";
  84       group = "wwwrun";
  85       permissions = "0600";
  86       text = ''
  87         <?php
  88         $CONFIG = array (
  89           // FIXME: change this value when nextcloud starts getting slow
  90           'instanceid' => '${env.instance_id}1',
  91           'datadirectory' => '/var/lib/nextcloud/',
  92           'passwordsalt' => '${env.password_salt}',
  93           'debug' => false,
  94           'dbtype' => 'pgsql',
  95           'version' => '16.0.0.9',
  96           'dbname' => '${env.postgresql.database}',
  97           'dbhost' => '${env.postgresql.socket}',
  98           'dbtableprefix' => 'oc_',
  99           'dbuser' => '${env.postgresql.user}',
 100           'dbpassword' => '${env.postgresql.password}',
 101           'installed' => true,
 102           'maxZipInputSize' => 0,
 103           'allowZipDownload' => true,
 104           'forcessl' => true,
 105           'theme' => ${"''"},
 106           'maintenance' => false,
 107           'trusted_domains' =>
 108           array (
 109             0 => 'cloud.immae.eu',
 110           ),
 111           'secret' => '${env.secret}',
 112           'appstoreenabled' => false,
 113           'appstore.experimental.enabled' => true,
 114           'loglevel' => 2,
 115           'trashbin_retention_obligation' => 'auto',
 116           'htaccess.RewriteBase' => '/',
 117           'mail_smtpmode' => 'sendmail',
 118           'mail_smtphost' => '127.0.0.1',
 119           'mail_smtpname' => ''',
 120           'mail_smtppassword' => ''',
 121           'mail_from_address' => 'nextcloud',
 122           'mail_smtpauth' => false,
 123           'mail_domain' => 'tools.immae.eu',
 124           'memcache.local' => '\\OC\\Memcache\\APCu',
 125           'memcache.locking' => '\\OC\\Memcache\\Redis',
 126           'filelocking.enabled' => true,
 127           'redis' =>
 128           array (
 129             'host' => '${env.redis.socket}',
 130             'port' => 0,
 131             'dbindex' => ${env.redis.db_index},
 132           ),
 133           'overwrite.cli.url' => 'https://cloud.immae.eu',
 134           'ldapIgnoreNamingRules' => false,
 135           'ldapProviderFactory' => '\\OCA\\User_LDAP\\LDAPProviderFactory',
 136           'has_rebuilt_cache' => true,
 137         );
 138       '';
 139     }];
 140     users.users.root.packages = let
 141       occ = pkgs.writeScriptBin "nextcloud-occ" ''
 142         #! ${pkgs.stdenv.shell}
 143         cd ${nextcloud}
 144         NEXTCLOUD_CONFIG_DIR="${nextcloud}/config" \
 145           exec \
 146           sudo -u wwwrun ${pkgs.php}/bin/php \
 147           -c ${pkgs.php}/etc/php.ini \
 148           occ $*
 149         '';
 150     in [ occ ];
 151
 152     system.activationScripts.nextcloud = {
 153       deps = [ "secrets" ];
 154       text = let
 155         confs = lib.attrsets.mapAttrs (n: v: pkgs.writeText "${n}.json" (builtins.toJSON v)) nextcloud.otherConfig;
 156       in
 157         ''
 158         install -m 0755 -o wwwrun -g wwwrun -d ${varDir}
 159         install -m 0750 -o wwwrun -g wwwrun -d ${varDir}/phpSessions
 160         ${builtins.concatStringsSep "\n" (lib.attrsets.mapAttrsToList (n: v:
 161           "install -D -m 0644 -o wwwrun -g wwwrun -T ${v} ${varDir}/config/${n}.json"
 162           ) confs)}
 163         install -D -m 0600 -o wwwrun -g wwwrun -T /var/secrets/webapps/tools-nextcloud ${varDir}/config/config.php
 164       '';
 165     };
 166     # FIXME: add a warning when config.php changes
 167     system.extraSystemBuilderCmds = ''
 168       mkdir -p $out/webapps
 169       ln -s ${nextcloud} $out/webapps/${webappName}
 170       '';
 171
 172     services.phpfpm.pools.nextcloud = {
 173       listen = phpFpm.socket;
 174       extraConfig = phpFpm.pool;
 175       phpOptions = config.services.phpfpm.phpOptions + phpFpm.phpConfig;
 176     };
 177
 178     services.cron = {
 179       enable = true;
 180       systemCronJobs = let
 181         script = pkgs.writeScriptBin "nextcloud-cron" ''
 182           #! ${pkgs.stdenv.shell}
 183           export LOCALE_ARCHIVE=/run/current-system/sw/lib/locale/locale-archive
 184           export PATH=/run/wrappers/bin:$PATH
 185           ${pkgs.php}/bin/php -f ${nextcloud}/cron.php
 186           '';
 187       in [
 188         ''
 189           */15 * * * * wwwrun ${script}/bin/nextcloud-cron
 190         ''
 191       ];
 192     };
 193   };
 194 }