modules/private/websites/isabelle/aten_app/default.nix

   1 { environment ? "prod"
   2 , varDir ? "/var/lib/aten_${environment}"
   3 , composerEnv, fetchgit, runCommand, nodejs, jq, libsass, python, fetchurl, yarn2nix-moretea, sources }:
   4 let
   5   packagesource = sources.websites-isabelle-aten;
   6   packagejson = runCommand "package.json" { buildInputs = [ jq ]; } ''
   7     cat ${packagesource}/package.json | jq -r '.version = "v1.0.0"|.name="aten"' > $out
   8     '';
   9   yarnModules = yarn2nix-moretea.mkYarnModules rec {
  10     name = "aten-yarn";
  11     pname = name;
  12     version = "v1.0.0";
  13     packageJSON = packagejson;
  14     yarnLock = "${packagesource}/yarn.lock";
  15     yarnNix = ./yarn-packages.nix;
  16     pkgConfig = {
  17       node-sass = {
  18         buildInputs = [ libsass python ];
  19         postInstall = let
  20           nodeHeaders = fetchurl {
  21             url = "https://nodejs.org/download/release/v${nodejs.version}/node-v${nodejs.version}-headers.tar.gz";
  22             sha256 = "1prvrcvbyal39k9axfwjixs4wfgs1m8xy4prsl0kq0s0n7r7nxzj";
  23           };
  24         in
  25           ''
  26             node scripts/build.js --tarball=${nodeHeaders}
  27           '';
  28       };
  29     };
  30   };
  31   app = composerEnv.buildPackage (
  32     import ./php-packages.nix { inherit composerEnv fetchurl fetchgit; } //
  33     rec {
  34       version = packagesource.version;
  35       pname = "aten";
  36       name = "${pname}-${version}";
  37       src = packagesource;
  38       noDev = (environment == "prod");
  39       preInstall = ''
  40         export SYMFONY_ENV="${environment}"
  41         export APP_ENV="${environment}"
  42         '';
  43       postInstall = ''
  44         ln -sf ${yarnModules}/node_modules .
  45         yarn run --offline encore production
  46         rm -rf var/{log,cache}
  47         ln -sf ${varDir}/{log,cache} var/
  48         '';
  49       buildInputs = [ yarnModules yarn2nix-moretea.yarn ];
  50       passthru = {
  51         inherit varDir;
  52         inherit environment;
  53         webRoot = "${app}/public";
  54       };
  55     }
  56   );
  57 in app