modules/private/gitolite/default.nix

   1 { lib, pkgs, config, ... }:
   2 let
   3     cfg = config.myServices.gitolite;
   4 in {
   5   options.myServices.gitolite = {
   6     enable = lib.mkEnableOption "my gitolite service";
   7     gitoliteDir = lib.mkOption {
   8       type = lib.types.str;
   9       default = "/var/lib/gitolite";
  10     };
  11   };
  12
  13   config = lib.mkIf cfg.enable {
  14     myServices.ssh.modules = [{
  15       snippet = builtins.readFile ./ldap_gitolite.sh;
  16       dependencies = [ pkgs.gitolite ];
  17     }];
  18     services.duplyBackup.profiles.gitolite = {
  19       rootDir = cfg.gitoliteDir;
  20       remotes = [ "eriomem" "ovh" ];
  21     };
  22     networking.firewall.allowedTCPPorts = [ 9418 ];
  23
  24     secrets.keys."gitolite/ldap_password" = {
  25       user = "gitolite";
  26       group = "gitolite";
  27       permissions = "0400";
  28       text = config.myEnv.tools.gitolite.ldap.password;
  29     };
  30
  31     services.gitDaemon = {
  32       enable = true;
  33       user = "gitolite";
  34       group = "gitolite";
  35       basePath = "${cfg.gitoliteDir}/repositories";
  36     };
  37
  38     system.activationScripts.gitolite = let
  39       deps = [ pkgs.openldap pkgs.stdenv.shellPackage pkgs.gnugrep pkgs.coreutils ];
  40       gitolite_ldap_groups = pkgs.runCommand "gitolite_ldap_groups.sh" {
  41         buildInputs = [ pkgs.makeWrapper ];
  42       } ''
  43         makeWrapper "${./gitolite_ldap_groups.sh}" "$out" \
  44           --prefix PATH : ${lib.makeBinPath deps} \
  45           --set LDAP_PASS_PATH ${config.secrets.fullPaths."gitolite/ldap_password"}
  46         '';
  47     in {
  48       deps = [ "users" ];
  49       text = ''
  50         if [ -d ${cfg.gitoliteDir} ]; then
  51           ln -sf ${gitolite_ldap_groups} ${cfg.gitoliteDir}/gitolite_ldap_groups.sh
  52           chmod g+rx ${cfg.gitoliteDir}
  53         fi
  54         if [ -f ${cfg.gitoliteDir}/projects.list ]; then
  55           chmod g+r ${cfg.gitoliteDir}/projects.list
  56         fi
  57       '';
  58     };
  59
  60     users.users.wwwrun.extraGroups = [ "gitolite" ];
  61     users.users.gitolite.extraGroups = [ "keys" ];
  62
  63     users.users.gitolite.packages = let
  64       python-packages = python-packages: with python-packages; [
  65         simplejson
  66         urllib3
  67         sleekxmpp
  68       ];
  69     in
  70       [
  71         (pkgs.python3.withPackages python-packages)
  72         pkgs.nettools
  73         pkgs.findutils
  74       ];
  75     # Installation: https://git.immae.eu/mantisbt/view.php?id=93
  76     services.gitolite = {
  77       enable = true;
  78       adminPubkey = config.myEnv.sshd.rootKeys.immae_dilion;
  79     };
  80   };
  81 }