modules/private/certificates.nix

   1 { lib, pkgs, config, name, ... }:
   2 {
   3   options.myServices.certificates = {
   4     enable = lib.mkEnableOption "enable certificates";
   5     certConfig = lib.mkOption {
   6       default = {
   7         webroot = "/var/lib/acme/acme-challenges";
   8         email = "ismael@bouya.org";
   9         postRun = builtins.concatStringsSep "\n" [
  10           (lib.optionalString config.services.httpd.Prod.enable "systemctl reload httpdProd.service")
  11           (lib.optionalString config.services.httpd.Tools.enable "systemctl reload httpdTools.service")
  12           (lib.optionalString config.services.httpd.Inte.enable "systemctl reload httpdInte.service")
  13           (lib.optionalString config.services.nginx.enable "systemctl reload nginx.service")
  14         ];
  15       };
  16       description = "Default configuration for certificates";
  17     };
  18   };
  19
  20   config = lib.mkIf config.myServices.certificates.enable {
  21     services.duplyBackup.profiles.system.excludeFile = ''
  22       + /var/lib/acme/acme-challenges
  23       '';
  24     services.nginx = {
  25       recommendedTlsSettings = true;
  26       virtualHosts = {
  27         "${config.hostEnv.fqdn}" = {
  28           acmeRoot = config.security.acme.certs."${name}".webroot;
  29           useACMEHost = name;
  30           forceSSL = true;
  31         };
  32       };
  33     };
  34     services.websites.certs = config.myServices.certificates.certConfig;
  35     myServices.databasesCerts = config.myServices.certificates.certConfig;
  36     myServices.ircCerts = config.myServices.certificates.certConfig;
  37
  38     security.acme.acceptTerms = true;
  39     security.acme.preliminarySelfsigned = true;
  40
  41     security.acme.certs = {
  42       "${name}" = config.myServices.certificates.certConfig // {
  43         domain = config.hostEnv.fqdn;
  44       };
  45     };
  46
  47     systemd.services = lib.attrsets.mapAttrs' (k: v:
  48       lib.attrsets.nameValuePair "acme-selfsigned-${k}" {
  49           wantedBy = [ "acme-selfsigned-certificates.target" ];
  50           script = lib.mkAfter ''
  51           cp $workdir/server.crt ${config.security.acme.certs."${k}".directory}/cert.pem
  52           chown '${v.user}:${v.group}' ${config.security.acme.certs."${k}".directory}/cert.pem
  53           chmod ${if v.allowKeysForGroup then "750" else "700"} ${config.security.acme.certs."${k}".directory}/cert.pem
  54
  55           cp $workdir/ca.crt ${config.security.acme.certs."${k}".directory}/chain.pem
  56           chown '${v.user}:${v.group}' ${config.security.acme.certs."${k}".directory}/chain.pem
  57           chmod ${if v.allowKeysForGroup then "750" else "700"} ${config.security.acme.certs."${k}".directory}/chain.pem
  58           '';
  59         }
  60       ) config.security.acme.certs //
  61     lib.attrsets.mapAttrs' (k: data:
  62       lib.attrsets.nameValuePair "acme-${k}" {
  63         serviceConfig.ExecStartPre =
  64           let
  65             script = pkgs.writeScript "acme-pre-start" ''
  66               #!${pkgs.runtimeShell} -e
  67               mkdir -p '${data.webroot}/.well-known/acme-challenge'
  68               chmod a+w '${data.webroot}/.well-known/acme-challenge'
  69               #doesn't work for multiple concurrent runs
  70               #chown -R '${data.user}:${data.group}' '${data.webroot}/.well-known/acme-challenge'
  71             '';
  72           in
  73           "+${script}";
  74         # This is a workaround to
  75         # https://github.com/NixOS/nixpkgs/issues/84409
  76         # https://github.com/NixOS/nixpkgs/issues/84633
  77         serviceConfig.RemainAfterExit = lib.mkForce false;
  78         serviceConfig.WorkingDirectory = lib.mkForce "/var/lib/acme/${k}/.lego";
  79         serviceConfig.StateDirectory = lib.mkForce "acme/${k}/.lego acme/${k}";
  80         serviceConfig.ExecStartPost =
  81           let
  82             keyName = builtins.replaceStrings ["*"] ["_"] data.domain;
  83             fileMode = if data.allowKeysForGroup then "640" else "600";
  84             spath = "/var/lib/acme/${k}/.lego";
  85             script = pkgs.writeScript "acme-post-start" ''
  86               #!${pkgs.runtimeShell} -e
  87               cd /var/lib/acme/${k}
  88
  89               # Test that existing cert is older than new cert
  90               KEY=${spath}/certificates/${keyName}.key
  91               if [ -e $KEY -a $KEY -nt key.pem ]; then
  92                 cp -p ${spath}/certificates/${keyName}.key key.pem
  93                 cp -p ${spath}/certificates/${keyName}.crt fullchain.pem
  94                 cp -p ${spath}/certificates/${keyName}.issuer.crt chain.pem
  95                 ln -sf fullchain.pem cert.pem
  96                 cat key.pem fullchain.pem > full.pem
  97
  98                 ${data.postRun}
  99               fi
 100
 101               chmod ${fileMode} *.pem
 102               chown '${data.user}:${data.group}' *.pem
 103             '';
 104           in
 105             lib.mkForce "+${script}";
 106
 107       }
 108     ) config.security.acme.certs //
 109     {
 110       httpdProd = lib.mkIf config.services.httpd.Prod.enable
 111         { after = [ "acme-selfsigned-certificates.target" ]; wants = [ "acme-selfsigned-certificates.target" ]; };
 112       httpdTools = lib.mkIf config.services.httpd.Tools.enable
 113         { after = [ "acme-selfsigned-certificates.target" ]; wants = [ "acme-selfsigned-certificates.target" ]; };
 114       httpdInte = lib.mkIf config.services.httpd.Inte.enable
 115         { after = [ "acme-selfsigned-certificates.target" ]; wants = [ "acme-selfsigned-certificates.target" ]; };
 116     };
 117   };
 118 }