flakes/mypackages/pkgs/perl-ical-parser-html/default.nix

   1 { perlPackages, fetchurl }:
   2 let
   3   TestXML = perlPackages.buildPerlPackage rec {
   4     pname = "Test-XML";
   5     version = "0.08";
   6     src = fetchurl {
   7       url = "mirror://cpan/authors/id/S/SE/SEMANTICO/Test-XML-0.08.tar.gz";
   8       sha256 = "sha256-61TMI83shg062KyKaXy/A40N7JUimRLZdcMBiQyoPuI=";
   9     };
  10     propagatedBuildInputs = with perlPackages; [
  11       ModuleBuild XMLSemanticDiff XMLParser
  12     ];
  13   };
  14   iCalParserSAX = perlPackages.buildPerlPackage rec {
  15     pname = "iCal-Parser-SAX";
  16     version = "1.09";
  17     src = fetchurl {
  18       url = "mirror://cpan/authors/id/R/RF/RFRANKEL/iCal-Parser-SAX-1.09.tar.gz";
  19       sha256 = "sha256-fouAjQ+MTUgwZ/j3dIarOK0rVBZcZy6aOJFor4pLql0=";
  20     };
  21     propagatedBuildInputs = with perlPackages; [
  22       ModuleBuild DateTime IOString XMLSAXBase XMLSAXWriter iCalParser
  23       LWPUserAgent
  24     ];
  25     buildInputs = [ TestXML ];
  26     doCheck = false;
  27   };
  28 in
  29 perlPackages.buildPerlPackage rec {
  30   pname = "iCal-Parser-HTML";
  31   version = "1.07";
  32   src = fetchurl {
  33     url = "mirror://cpan/authors/id/R/RF/RFRANKEL/${pname}-${version}.tar.gz";
  34     sha256 = "sha256-cxRS2M6aVrCtAXHQae0Y6EtEfGnGx41UuB7z442NSrU=";
  35   };
  36   patchPhase = ''
  37     sed -i -e "s/qw(week month year)/(qw(week month year))/" lib/iCal/Parser/HTML.pm
  38   '';
  39   doCheck = false;
  40   postInstall = ''
  41     mkdir -p $out/bin
  42     cp scripts/ical2html $out/bin
  43     chmod +x $out/bin/ical2html
  44   '';
  45   propagatedBuildInputs = with perlPackages; [
  46     ModuleBuild XMLLibXML XMLLibXSLT iCalParser iCalParserSAX
  47   ];
  48 }