flakes/loginctl-linger/flake.nix

   1 {
   2   outputs = { self }: {
   3     nixosModule = { config, lib, pkgs, ... }:
   4       # https://github.com/michalrus/dotfiles/commit/ebd5fa9583f82589f23531647aa677feb3f8d344#diff-4d353005ef5b3e37f33c07332b8523edR1
   5       # A temporary hack to `loginctl enable-linger $somebody` (for
   6       # multiplexer sessions to last), until this one is unresolved:
   7       # https://github.com/NixOS/nixpkgs/issues/3702
   8       #
   9       # Usage: `users.extraUsers.somebody.linger = true` or slt.
  10
  11       with lib;
  12
  13       let
  14
  15         dataDir = "/var/lib/systemd/linger";
  16
  17         lingeringUsers = map (u: u.name) (attrValues (flip filterAttrs config.users.users (n: u: u.linger)));
  18
  19         lingeringUsersFile = builtins.toFile "lingering-users"
  20           (concatStrings (map (s: "${s}\n")
  21             (sort (a: b: a < b) lingeringUsers))); # this sorting is important for `comm` to work correctly
  22
  23         updateLingering = pkgs.writeScript "update-lingering" ''
  24           if [ ! -e ${dataDir} ]; then
  25             install -m 0755 -o root -g root -d ${dataDir}
  26           fi
  27           if [ -e ${dataDir} ] ; then
  28             ls ${dataDir} | sort | comm -3 -1 ${lingeringUsersFile} - | xargs -r ${pkgs.systemd}/bin/loginctl disable-linger
  29             ls ${dataDir} | sort | comm -3 -2 ${lingeringUsersFile} - | xargs -r ${pkgs.systemd}/bin/loginctl  enable-linger
  30           fi
  31         '';
  32
  33       in
  34
  35       {
  36         # Necessary for situations where flake gets included multiple times
  37         key = builtins.hashString "sha256" (builtins.path { path = self.sourceInfo.outPath; name = "source"; });
  38         options = {
  39           users.users = mkOption {
  40             type = lib.types.attrsOf (lib.types.submodule {
  41               options = {
  42                 linger = mkEnableOption "lingering for the user";
  43               };
  44             });
  45           };
  46         };
  47
  48         config = {
  49           system.activationScripts.update-lingering = {
  50             deps = ["users"];
  51             text = "${updateLingering}";
  52           };
  53         };
  54       };
  55   };
  56 }