Start purifying mastodon: bundler

[perso/Immae/Config/Nix.git] / virtual / modules / websites / tools / mastodon / mastodon.nix

{ env, ruby_2_5, bundlerEnv, defaultGemConfig, fetchedGithub, stdenv, writeText, pkgs, cacert }:
let
  varDir = "/var/lib/mastodon_immae";
  socketsDir = "/run/mastodon";
  gems = bundlerEnv {
    name = "mastodon-env";
    ruby = ruby_2_5;
    gemset = ./gemset.nix;
    gemdir = (fetchedGithub ./mastodon.json).src;
    groups = [ "default" "production" "test" "development" ];
    gemConfig = defaultGemConfig // {
      cld3 = attrs: {
        buildInputs = with pkgs; [ protobuf protobufc pkgconfig ];
      };
      idn-ruby = attrs: {
        buildInputs = with pkgs; [ libidn ];
      };
      rpam2 = attrs: {
        buildInputs = with pkgs; [ pam ];
      };
    };
  };
  mastodon = stdenv.mkDerivation (fetchedGithub ./mastodon.json // rec {
    __noChroot = true;
    buildPhase = ''
      yarn install --pure-lockfile
      patchShebangs node_modules
    '';
    installPhase = ''
      cp -a . $out
    '';
    propagatedBuildInputs = [ gems pkgs.yarn pkgs.python2 pkgs.nodejs ];
  });
  config = writeText "mastodon_environment" ''
    REDIS_HOST=localhost
    REDIS_PORT=6379
    REDIS_DB=13
    DB_HOST=/run/postgresql
    DB_USER=mastodon
    DB_NAME=mastodon
    DB_PASS=${env.postgresql.password}
    DB_PORT=5432

    LOCAL_DOMAIN=mastodon.immae.eu
    LOCAL_HTTPS=true
    ALTERNATE_DOMAINS=immae.eu

    PAPERCLIP_SECRET=${env.paperclip_secret}
    SECRET_KEY_BASE=${env.secret_key_base}
    OTP_SECRET=${env.otp_secret}

    VAPID_PRIVATE_KEY=${env.vapid.private}
    VAPID_PUBLIC_KEY=${env.vapid.public}

    SMTP_SERVER=mail.immae.eu
    SMTP_PORT=587
    SMTP_FROM_ADDRESS=notifications@mastodon.immae.eu
    SMTP_DELIVERY_METHOD=smtp
    PAPERCLIP_ROOT_PATH=${varDir}

    STREAMING_CLUSTER_NUM=1

    # LDAP authentication (optional)
    LDAP_ENABLED=true
    LDAP_HOST=ldap.immae.eu
    LDAP_PORT=636
    LDAP_METHOD=simple_tls
    LDAP_BASE="dc=immae,dc=eu"
    LDAP_BIND_DN="cn=mastodon,ou=services,dc=immae,dc=eu"
    LDAP_PASSWORD="${env.ldap.password}"
    LDAP_UID="uid"
    LDAP_SEARCH_FILTER="(&(%{uid}=%{email})(memberOf=cn=users,cn=mastodon,ou=services,dc=immae,dc=eu))"
    '';

    railsRoot = stdenv.mkDerivation {
      name = "mastodon_immae";
      inherit config mastodon;
      builder = writeText "build_mastodon_immae" ''
        source $stdenv/setup
        set -a
        source $config
        set +a
        cp -a $mastodon $out
        cd $out
        chmod u+rwX . node_modules public
        RAILS_ENV=production ${gems}/bin/rails assets:precompile
        rm -rf tmp/cache
        ln -sf ../../../../../../../${varDir}/tmp/cache tmp
        '';
      buildInputs = [ gems pkgs.nodejs pkgs.yarn ];
    };
in
  {
    inherit railsRoot config varDir socketsDir gems;
    nodeSocket = "${socketsDir}/live_immae_node.sock";
    railsSocket = "${socketsDir}/live_immae_puma.sock";
  }