PKGBUILD

   1 # Maintainer: Immae <ismael.bouya@normalesup.org>
   2 # Maintainer: Jonathan Steel <jsteel at archlinux.org>
   3
   4 pkgname='naemon-livestatus'
   5 pkgdesc="Event broker for naemon"
   6 pkgver=1.0.10
   7 pkgrel=1
   8 arch=('i686' 'x86_64')
   9 url="http://naemon.org"
  10 license=('GPL2')
  11 depends=('icu' 'naemon')
  12 source=("naemon-livestatus-git::git+https://github.com/naemon/naemon-livestatus.git#commit=33dbcfe18e42158f25c27cff95a1e07b73be53b0")
  13 sha512sums=('SKIP')
  14 backup=('etc/naemon/livestatus.cfg')
  15
  16 build() {
  17   cd "$srcdir/$pkgname-git"
  18
  19   export PKG_CONFIG_PATH="/usr/lib/naemon/pkgconfig:$PKG_CONFIG_PATH"
  20   ./autogen.sh
  21   ./configure --prefix=/usr \
  22               --bindir=/usr/bin \
  23               --datadir="/usr/share/naemon" \
  24               --libdir="/usr/lib/naemon" \
  25               --localstatedir="/var/lib/naemon" \
  26               --sysconfdir="/etc/naemon" \
  27               --mandir="/usr/share/man"
  28
  29   make
  30 }
  31
  32 package() {
  33   cd "$srcdir/$pkgname-git"
  34
  35   make DESTDIR="$pkgdir" install
  36 }