pkgs/webapps/default.nix

   1 { callPackage, mylibs, composerEnv, lib, private }:
   2 rec {
   3   adminer = callPackage ./adminer {};
   4   apache-theme = callPackage ./apache-theme {};
   5   awl = callPackage ./awl {};
   6   davical = callPackage ./davical {};
   7   diaspora = callPackage ./diaspora { inherit mylibs; };
   8
   9   dokuwiki = callPackage ./dokuwiki { inherit mylibs; };
  10   dokuwiki-with-plugins = dokuwiki.withPlugins (builtins.attrValues dokuwiki-plugins);
  11   dokuwiki-plugins = let
  12     names = [ "farmer" "todo" ];
  13   in
  14     lib.attrsets.genAttrs names
  15       (name: callPackage (./dokuwiki/plugins + "/${name}.nix") {});
  16
  17   etherpad-lite = callPackage ./etherpad-lite {};
  18   etherpad-lite-with-modules = etherpad-lite.withModules (builtins.attrValues etherpad-lite-modules);
  19   etherpad-lite-modules = let
  20     nodeEnv = callPackage mylibs.nodeEnv {};
  21     names = [
  22       "ep_aa_file_menu_toolbar" "ep_adminpads" "ep_align" "ep_bookmark"
  23       "ep_clear_formatting" "ep_colors" "ep_copy_paste_select_all"
  24       "ep_cursortrace" "ep_embedmedia" "ep_font_family" "ep_font_size"
  25       "ep_headings2" "ep_ldapauth" "ep_line_height" "ep_markdown"
  26       "ep_previewimages" "ep_ruler" "ep_scrollto" "ep_set_title_on_pad"
  27       "ep_subscript_and_superscript" "ep_timesliderdiff"
  28     ];
  29   in
  30     # nix files are built using node2nix -i node-packages.json
  31     lib.attrsets.genAttrs names
  32     (name: (callPackage (./etherpad-lite/modules + "/${name}/node-packages.nix") { inherit nodeEnv; })
  33       .${name}.overrideAttrs(old: { passthru = (old.passthru or {}) // { moduleName = name; }; }));
  34
  35   grocy = callPackage ./grocy { inherit mylibs composerEnv; };
  36
  37   infcloud = callPackage ./infcloud {};
  38
  39   mantisbt_2 = callPackage ./mantisbt_2 {};
  40   mantisbt_2-with-plugins = mantisbt_2.withPlugins (builtins.attrValues mantisbt_2-plugins);
  41   mantisbt_2-plugins = let
  42     names = [ "slack" "source-integration" ];
  43   in
  44     lib.attrsets.genAttrs names
  45       (name: callPackage (./mantisbt_2/plugins + "/${name}") {});
  46
  47   mastodon = callPackage ./mastodon { inherit mylibs; };
  48
  49   mediagoblin = callPackage ./mediagoblin { inherit mylibs; };
  50   mediagoblin-with-plugins = mediagoblin.withPlugins (builtins.attrValues mediagoblin-plugins);
  51   mediagoblin-plugins = let
  52     names = [ "basicsearch" ];
  53   in
  54     lib.attrsets.genAttrs names
  55       (name: callPackage (./mediagoblin/plugins + "/${name}") {});
  56
  57   nextcloud = callPackage ./nextcloud {};
  58   nextcloud-with-apps = nextcloud.withPlugins (builtins.attrValues nextcloud-apps);
  59   nextcloud-apps = let
  60       names = [
  61         "audioplayer" "bookmarks" "calendar" "contacts" "deck"
  62         "files_markdown" "gpxedit" "gpxpod" "keeweb" "music"
  63         "notes" "ocsms" "passman" "spreed" "tasks"
  64         "flowupload" "carnet" "maps" "cookbook" "polls"
  65         "apporder" "extract" "files_readmemd" "metadata"
  66       ];
  67     in
  68     lib.attrsets.genAttrs names
  69       (name: callPackage (./nextcloud/apps + "/${name}.nix") { buildApp = nextcloud.buildApp; });
  70
  71   peertube = callPackage ./peertube { inherit mylibs; };
  72   phpldapadmin = callPackage ./phpldapadmin {};
  73   rompr = callPackage ./rompr { inherit mylibs; };
  74
  75   roundcubemail = callPackage ./roundcubemail {};
  76   roundcubemail-with-plugins-skins = roundcubemail.withPlugins (builtins.attrValues roundcubemail-plugins) (builtins.attrValues roundcubemail-skins);
  77   roundcubemail-skins = let
  78     names = [];
  79   in
  80     lib.attrsets.genAttrs names
  81       (name: callPackage (./roundcubemail/skins + "/${name}") {});
  82   roundcubemail-plugins = let
  83     names = [
  84       "automatic_addressbook" "carddav" "contextmenu"
  85       "contextmenu_folder" "html5_notifier" "ident_switch"
  86       "message_highlight" "thunderbird_labels"
  87     ];
  88   in
  89     lib.attrsets.genAttrs names
  90       (name: callPackage (./roundcubemail/plugins + "/${name}") { buildPlugin = roundcubemail.buildPlugin; });
  91
  92   spip = callPackage ./spip {};
  93   taskwarrior-web = callPackage ./taskwarrior-web { inherit mylibs; };
  94
  95   ttrss = callPackage ./ttrss { inherit mylibs; };
  96   ttrss-with-plugins = ttrss.withPlugins (builtins.attrValues ttrss-plugins);
  97   ttrss-plugins = let
  98     names = [ "auth_ldap" "af_feedmod" "feediron" "ff_instagram" "tumblr_gdpr_ua" ];
  99     patched = [ "af_feedmod" "feediron" ];
 100   in
 101     lib.attrsets.genAttrs names
 102       (name: callPackage (./ttrss/plugins + "/${name}") (
 103         { inherit mylibs; } //
 104         (if builtins.elem name patched then { patched = true; } else {})
 105         )
 106       );
 107
 108   wallabag = callPackage ./wallabag { inherit composerEnv; };
 109   yourls = callPackage ./yourls { inherit mylibs; };
 110   yourls-with-plugins = yourls.withPlugins (builtins.attrValues yourls-plugins);
 111   yourls-plugins = let
 112     names = [ "ldap" ];
 113   in
 114     lib.attrsets.genAttrs names
 115       (name: callPackage (./yourls/plugins + "/${name}") { inherit mylibs; });
 116 } // private.webapps