3 files changed, 97 insertions, 0 deletions

diff --git a/flakes/mypackages/pkgs/webapps/dokuwiki/default.nix b/flakes/mypackages/pkgs/webapps/dokuwiki/default.nix
new file mode 100644
index 0000000..db8be30
--- /dev/null
+++ b/flakes/mypackages/pkgs/webapps/dokuwiki/default.nix
@@ -0,0 +1,54 @@
+{ varDir ? "/var/lib/dokuwiki", preload ? "", lib, callPackage, stdenv, fetchFromGitHub, writeText }:
+let
+  preloadFile = plugins: let preloads = [preload]
+      ++ builtins.concatMap (p: lib.optional (lib.hasAttr "preload" p) (p.preload p)) plugins;
+    in writeText "preload.php" (''
+      <?php
+      '' + builtins.concatStringsSep "\n" preloads
+    );
+  pluginNames = [ "farmer" "todo" ];
+  allPlugins = lib.attrsets.genAttrs pluginNames
+    (name: callPackage (./plugins + "/${name}.nix") {});
+  toPassthru = pkg: plugins: {
+    inherit plugins varDir allPlugins;
+    withPlugins = withPlugins pkg;
+  };
+  withPlugins = pkg: toPlugins:
+    let
+      plugins = toPlugins allPlugins;
+      toInstallPlugin = n:
+        "ln -sf ${n} $out/lib/plugins/${n.pluginName}";
+      newDokuwiki = pkg.overrideAttrs(old: {
+        installPhase = old.installPhase + "\n" + builtins.concatStringsSep "\n" (map toInstallPlugin plugins);
+        installPreloadPhase = ''
+          cp ${preloadFile (pkg.plugins ++ plugins)} $out/inc/preload.php
+        '';
+        passthru = toPassthru newDokuwiki (pkg.plugins ++ plugins);
+      });
+    in newDokuwiki;
+  package = stdenv.mkDerivation (rec {
+    pname = "dokuwiki";
+    version = "release_stable_2018-04-22b";
+    src = fetchFromGitHub {
+      owner = "splitbrain";
+      repo = "dokuwiki";
+      rev = "871dae1320b40211626c7ec665f5e6d5290aca95";
+      sha256 = "1syvd5dvv3v75swf8ig7dxqs0g5xikb0f6vlcy7g4c4ghldkw7nz";
+      fetchSubmodules = true;
+    };
+    phases = "unpackPhase buildPhase installPhase installPreloadPhase fixupPhase";
+    buildPhase = ''
+      mv conf conf.dist
+      mv data data.dist
+    '';
+    installPhase = ''
+      cp -a . $out
+      ln -sf ${varDir}/{conf,data} $out/
+      ln -sf ${varDir}/conf/.htaccess $out/
+    '';
+    installPreloadPhase = ''
+      cp ${preloadFile []} $out/inc/preload.php
+      '';
+    passthru = toPassthru package [];
+  });
+in package
diff --git a/flakes/mypackages/pkgs/webapps/dokuwiki/plugins/farmer.nix b/flakes/mypackages/pkgs/webapps/dokuwiki/plugins/farmer.nix
new file mode 100644
index 0000000..b737b2d
--- /dev/null
+++ b/flakes/mypackages/pkgs/webapps/dokuwiki/plugins/farmer.nix
@@ -0,0 +1,25 @@
+{ stdenv, fetchFromGitHub }:
+stdenv.mkDerivation rec {
+  version = "72b8577-master";
+  name = "dokuwiki-plugin-farmer-${version}";
+  src = fetchFromGitHub {
+    owner = "cosmocode";
+    repo = "dokuwiki-plugin-farmer";
+    rev = "72b857734fd164bf79cc6e17abe56491d55c1072";
+    sha256 = "1c9vc1z7yvzjz4p054kshb9yd00a4bb52s43k9zav0lvwvjij9l0";
+  };
+  installPhase = ''
+    mkdir $out
+    cp -a * $out
+    '';
+  passthru = {
+    pluginName = "farmer";
+    preload = out: ''
+      # farm setup by farmer plugin
+      if (file_exists('${out}/DokuWikiFarmCore.php'))
+      {
+        include('${out}/DokuWikiFarmCore.php');
+      }
+    '';
+  };
+}
diff --git a/flakes/mypackages/pkgs/webapps/dokuwiki/plugins/todo.nix b/flakes/mypackages/pkgs/webapps/dokuwiki/plugins/todo.nix
new file mode 100644
index 0000000..a3e03fb
--- /dev/null
+++ b/flakes/mypackages/pkgs/webapps/dokuwiki/plugins/todo.nix
@@ -0,0 +1,18 @@
+{ stdenv, fetchFromGitHub }:
+stdenv.mkDerivation rec {
+  version = "49068ec-master";
+  name = "dokuwiki-plugin-todo-${version}";
+  src = fetchFromGitHub {
+    owner = "leibler";
+    repo = "dokuwiki-plugin-todo";
+    rev = "49068ecea455ea997d1e4a7adab171ccaf8228e8";
+    sha256 = "1jaq623kp14fyhamsas5mk9ryqlk4q6x6znijrb5xhcdg3r83gmq";
+  };
+  installPhase = ''
+    mkdir $out
+    cp -a * $out
+    '';
+  passthru = {
+    pluginName = "todo";
+  };
+}