Squash changes containing private information

There were a lot of changes since the previous commit, but a lot of them
contained personnal information about users. All thos changes got
stashed into a single commit (history is kept in a different place) and
private information was moved in a separate private repository

5 files changed, 0 insertions, 344 deletions

diff --git a/pkgs/webapps/mediagoblin/bower-packages.nix b/pkgs/webapps/mediagoblin/bower-packages.nix
deleted file mode 100644
index 03af849..0000000
--- a/pkgs/webapps/mediagoblin/bower-packages.nix
+++ /dev/null
@@ -1,8 +0,0 @@
-# Generated by bower2nix v3.2.0 (https://github.com/rvl/bower2nix)
-{ fetchbower, buildEnv }:
-buildEnv { name = "bower-env"; ignoreCollisions = true; paths = [
-  (fetchbower "jquery" "2.1.4" "~2.1.3" "1ywrpk2xsr6ghkm3j9gfnl9r3jn6xarfamp99b0bcm57kq9fm2k0")
-  (fetchbower "video.js" "4.11.4" "~4.11.4" "05prdvyk0rxbkh7sdd0d9ns5l5crwvc68wzkyqmrdjw367pcv8sn")
-  (fetchbower "leaflet" "0.7.7" "~0.7.3" "0jim285bljmxxngpm3yx6bnnd10n2whwkgmmhzpcd1rdksnr5nca")
-  (fetchbower "tinymce" "4.1.10" "~4.1.7" "16jyvdb9bq8gjwhs69q8p88vdixalajrz81nsmbrzzxhkih57dyx")
-]; }
diff --git a/pkgs/webapps/mediagoblin/default.nix b/pkgs/webapps/mediagoblin/default.nix
deleted file mode 100644
index 22cb292..0000000
--- a/pkgs/webapps/mediagoblin/default.nix
+++ /dev/null
@@ -1,210 +0,0 @@
-{ makeWrapper, stdenv, writeScript, fetchurl, buildBowerComponents, mylibs, which, python36, gst_all_1, automake, autoconf, nodejs, nodePackages, lib, callPackage, fetchgit }:
-let
-  overridePython = let
-    packageOverrides = self: super: {
-      pybcrypt = super.buildPythonPackage rec {
-        pname = "pybcrypt";
-        version = "0.4";
-
-        src = self.fetchPypi {
-          inherit pname version;
-          sha256 = "5fa13bce551468350d66c4883694850570f3da28d6866bb638ba44fe5eabda78";
-        };
-      };
-      celery = super.celery.overridePythonAttrs(old: rec {
-        version = "3.1.26.post2";
-        src = self.fetchPypi {
-          inherit version;
-          inherit (old) pname;
-          sha256 = "5493e172ae817b81ba7d09443ada114886765a8ce02f16a56e6fac68d953a9b2";
-        };
-        patches = [];
-        doCheck = false;
-      });
-      billiard = super.billiard.overridePythonAttrs(old: rec {
-        version = "3.3.0.23";
-        src = self.fetchPypi {
-          inherit version;
-          inherit (old) pname;
-          sha256 = "02wxsc6bhqvzh8j6w758kvgqbnj14l796mvmrcms8fgfamd2lak9";
-        };
-        doCheck = false;
-        doInstallCheck = false;
-      });
-      amqp = super.amqp.overridePythonAttrs(old: rec {
-        version = "1.4.9";
-        src = self.fetchPypi {
-          inherit version;
-          inherit (old) pname;
-          sha256 = "2dea4d16d073c902c3b89d9b96620fb6729ac0f7a923bbc777cb4ad827c0c61a";
-        };
-        doCheck = false;
-      });
-      kombu = super.kombu.overridePythonAttrs(old: rec {
-        version = "3.0.37";
-        src = self.fetchPypi {
-          inherit version;
-          inherit (old) pname;
-          sha256 = "e064a00c66b4d1058cd2b0523fb8d98c82c18450244177b6c0f7913016642650";
-        };
-        propagatedBuildInputs = old.propagatedBuildInputs ++ [ self.anyjson ];
-        doCheck = false;
-      });
-      markdown = super.markdown.overridePythonAttrs(old: rec {
-        version = "3.1.1";
-        src = self.fetchPypi {
-          inherit version;
-          inherit (old) pname;
-          sha256 = "2e50876bcdd74517e7b71f3e7a76102050edec255b3983403f1a63e7c8a41e7a";
-        };
-      });
-      sqlalchemy = super.sqlalchemy.overridePythonAttrs(old: rec {
-        version = "1.1.18";
-        src = self.fetchPypi {
-          inherit version;
-          inherit (old) pname;
-          sha256 = "8b0ec71af9291191ba83a91c03d157b19ab3e7119e27da97932a4773a3f664a9";
-        };
-        doCheck = false;
-      });
-      tempita_5_3_dev = super.buildPythonPackage (mylibs.fetchedGithub ./tempita.json // rec {
-        buildInputs = with self; [ nose ];
-        disabled = false;
-      });
-      sqlalchemy_migrate = super.sqlalchemy_migrate.overridePythonAttrs(old: rec {
-        propagatedBuildInputs = with self; [ pbr tempita_5_3_dev decorator sqlalchemy six sqlparse ];
-      });
-      pasteScript = super.pasteScript.overridePythonAttrs(old: rec {
-        version = "2.0.2";
-        name = "PasteScript-${version}";
-        src = fetchurl {
-          url = "mirror://pypi/P/PasteScript/${name}.tar.gz";
-          sha256 = "1h3nnhn45kf4pbcv669ik4faw04j58k8vbj1hwrc532k0nc28gy0";
-        };
-        propagatedBuildInputs = with self; [ six paste PasteDeploy ];
-      });
-      werkzeug = super.werkzeug.overridePythonAttrs(old: rec {
-        version = "0.16.1";
-        src = self.fetchPypi {
-          inherit version;
-          inherit (old) pname;
-          sha256 = "b353856d37dec59d6511359f97f6a4b2468442e454bd1c98298ddce53cac1f04";
-        };
-      });
-    };
-    in
-      python36.override { inherit packageOverrides; };
-  pythonEnv = python-pkgs: with python-pkgs; [
-    waitress alembic dateutil wtforms pybcrypt
-    pytest pytest_xdist werkzeug celery
-    kombu jinja2 Babel webtest configobj markdown
-    sqlalchemy itsdangerous pytz sphinx six
-    oauthlib unidecode jsonschema PasteDeploy
-    requests PyLD exifread
-    typing pasteScript lxml
-    # For images plugin
-    pillow
-    # For video plugin
-    gst-python
-    # migrations
-    sqlalchemy_migrate
-    # authentication
-    ldap3
-    redis
-    psycopg2
-  ];
-  python = overridePython.withPackages pythonEnv;
-  gmg = writeScript "gmg" ''
-    #!${python}/bin/python
-    __requires__ = 'mediagoblin'
-    import sys
-    from pkg_resources import load_entry_point
-
-    if __name__ == '__main__':
-        sys.exit(
-            load_entry_point('mediagoblin', 'console_scripts', 'gmg')()
-        )
-    '';
-  mediagoblinSrc = fetchgit {
-    name = "mediagoblin";
-    url = "git://git.savannah.gnu.org/mediagoblin.git";
-    rev = "cd465ebfec837a75a44c4ebd727dffe2fff6d850";
-    sha256 = "1yz4i4i97z3rxl534a6psaybyjbyp5nnc52v3nvbpzc4pd2s69mx";
-    fetchSubmodules = true; # important!
-  };
-  bowerComponents = buildBowerComponents {
-    name = "mediagoblin-bower-components";
-    generated = ./bower-packages.nix;
-    src = mediagoblinSrc;
-  };
-  pluginNames = [ "basicsearch" ];
-  allPlugins = lib.attrsets.genAttrs pluginNames
-    (name: callPackage (./plugins + "/${name}") {});
-  toPassthru = pkg: {
-    inherit allPlugins;
-    withPlugins = withPlugins pkg;
-  };
-  withPlugins = pkg: toPlugins:
-    let
-      plugins = toPlugins allPlugins;
-      toBuildPlugin = n: "ln -s ${n} mediagoblin/plugins/${n.pluginName}";
-      newMediagoblin = pkg.overrideAttrs(old: {
-        postBuild = old.postBuild + "\n" + builtins.concatStringsSep "\n" (map toBuildPlugin plugins);
-        passthru = toPassthru newMediagoblin;
-      });
-    in newMediagoblin;
-  package = stdenv.mkDerivation rec {
-    pname = "mediagoblin";
-    name = "${pname}-${version}";
-    version = "cd465eb-stable";
-    src = mediagoblinSrc;
-    preConfigure = ''
-      # ./bootstrap.sh
-      aclocal -I m4 --install
-      autoreconf -fvi
-      # end
-      export HOME=$PWD
-      '';
-    configureFlags = [ "--with-python3" "--without-virtualenv" ];
-    postBuild = ''
-      cp -a ${bowerComponents}/bower_components/* extlib
-      chmod -R u+w extlib
-      make extlib
-      '';
-    installPhase = let
-      libpaths = with gst_all_1; [
-        python
-        gstreamer
-        gst-plugins-base
-        gst-libav
-        gst-plugins-good
-        gst-plugins-bad
-        gst-plugins-ugly
-      ];
-      plugin_paths = builtins.concatStringsSep ":" (map (x: "${x}/lib") libpaths);
-      typelib_paths = with gst_all_1; "${gstreamer}/lib/girepository-1.0:${gst-plugins-base}/lib/girepository-1.0";
-    in ''
-      sed -i "s/registry.has_key(current_theme_name)/current_theme_name in registry/" mediagoblin/tools/theme.py
-      sed -i -e "s@\[DEFAULT\]@[DEFAULT]\nhere = $out@" mediagoblin/config_spec.ini
-      sed -i -e "/from gi.repository import GstPbutils/s/^/gi.require_version('GstPbutils', '1.0')\n/" mediagoblin/media_types/video/transcoders.py
-      cp ${./ldap_fix.py} mediagoblin/plugins/ldap/tools.py
-      find . -name '*.pyc' -delete
-      find . -type f -exec sed -i "s|$PWD|$out|g" {} \;
-      python setup.py build
-      cp -a . $out
-      mkdir $out/bin
-      makeWrapper ${gmg} $out/bin/gmg --prefix PYTHONPATH : "$out:$PYTHONPATH" \
-        --prefix GST_PLUGIN_SYSTEM_PATH : ${plugin_paths} \
-        --prefix GI_TYPELIB_PATH : ${typelib_paths}
-      makeWrapper ${python}/bin/paster $out/bin/paster --prefix PYTHONPATH : "$out:$PYTHONPATH" \
-        --prefix GST_PLUGIN_SYSTEM_PATH : ${plugin_paths} \
-        --prefix GI_TYPELIB_PATH : ${typelib_paths}
-      makeWrapper ${python}/bin/celery $out/bin/celery --prefix PYTHONPATH : "$out:$PYTHONPATH" \
-        --prefix GST_PLUGIN_SYSTEM_PATH : ${plugin_paths} \
-        --prefix GI_TYPELIB_PATH : ${typelib_paths}
-      '';
-    buildInputs = [ makeWrapper automake autoconf which nodePackages.bower nodejs python ];
-    propagatedBuildInputs = with gst_all_1; [ python gst-libav gst-plugins-good gst-plugins-bad gst-plugins-ugly gstreamer ];
-    passthru = toPassthru package;
-  };
-in package
diff --git a/pkgs/webapps/mediagoblin/ldap_fix.py b/pkgs/webapps/mediagoblin/ldap_fix.py
deleted file mode 100644
index 10cc375..0000000
--- a/pkgs/webapps/mediagoblin/ldap_fix.py
+++ /dev/null
@@ -1,93 +0,0 @@
-# GNU MediaGoblin -- federated, autonomous media hosting
-# Copyright (C) 2011, 2012 MediaGoblin contributors.  See AUTHORS.
-#
-# This program is free software: you can redistribute it and/or modify
-# it under the terms of the GNU Affero General Public License as published by
-# the Free Software Foundation, either version 3 of the License, or
-# (at your option) any later version.
-#
-# This program is distributed in the hope that it will be useful,
-# but WITHOUT ANY WARRANTY; without even the implied warranty of
-# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
-# GNU Affero General Public License for more details.
-#
-# You should have received a copy of the GNU Affero General Public License
-# along with this program.  If not, see <http://www.gnu.org/licenses/>.
-from ldap3 import Server, Connection, SUBTREE
-from ldap3.core.exceptions import LDAPException
-import logging
-
-import six
-
-from mediagoblin.tools import pluginapi
-
-_log = logging.getLogger(__name__)
-
-
-class LDAP(object):
-    def __init__(self):
-        self.ldap_settings = pluginapi.get_config('mediagoblin.plugins.ldap')
-
-    def _connect(self, server):
-        _log.info('Connecting to {0}.'.format(server['LDAP_SERVER_URI']))
-        self.server = Server(server['LDAP_SERVER_URI'])
-
-        if 'LDAP_START_TLS' in server and server['LDAP_START_TLS'] == 'true':
-            _log.info('Initiating TLS')
-            self.server.start_tls()
-
-    def _manager_auth(self, settings, username, password):
-        conn = Connection(self.server,
-                settings['LDAP_BIND_DN'],
-                settings['LDAP_BIND_PW'],
-                auto_bind=True)
-        found = conn.search(
-                search_base=settings['LDAP_SEARCH_BASE'],
-                search_filter=settings['LDAP_SEARCH_FILTER'].format(username=username),
-                search_scope=SUBTREE,
-                attributes=[settings['EMAIL_SEARCH_FIELD']])
-        if (not found) or len(conn.entries) > 1:
-            return False, None
-
-        user = conn.entries[0]
-        user_dn = user.entry_dn
-        try:
-            email = user.entry_attributes_as_dict[settings['EMAIL_SEARCH_FIELD']][0]
-        except KeyError:
-            email = None
-
-        Connection(self.server, user_dn, password, auto_bind=True)
-
-        return username, email
-
-    def _direct_auth(self, settings, username, password):
-        user_dn = settings['LDAP_USER_DN_TEMPLATE'].format(username=username)
-        conn = Connection(self.server, user_dn, password, auto_bind=True)
-        email_found = conn.search(
-                search_base=settings['LDAP_SEARCH_BASE'],
-                search_filter='uid={0}'.format(username),
-                search_scope=SUBTREE,
-                attributes=[settings['EMAIL_SEARCH_FIELD']])
-
-        if email_found:
-            try:
-                email = conn.entries[0].entry_attributes_as_dict[settings['EMAIL_SEARCH_FIELD']][0]
-            except KeyError:
-                email = None
-
-        return username, email
-
-    def login(self, username, password):
-        for k, v in six.iteritems(self.ldap_settings):
-            try:
-                self._connect(v)
-
-                if 'LDAP_BIND_DN' in v:
-                    return self._manager_auth(v, username, password)
-                else:
-                    return self._direct_auth(v, username, password)
-
-            except LDAPException as e:
-                _log.info(e)
-
-        return False, None
diff --git a/pkgs/webapps/mediagoblin/plugins/basicsearch/default.nix b/pkgs/webapps/mediagoblin/plugins/basicsearch/default.nix
deleted file mode 100644
index 16be613..0000000
--- a/pkgs/webapps/mediagoblin/plugins/basicsearch/default.nix
+++ /dev/null
@@ -1,18 +0,0 @@
-{ stdenv, fetchFromGitHub }:
-stdenv.mkDerivation rec {
-  name = "mediagoblin-plugin-basicsearch-${version}";
-  version = "ba0a154-master";
-  src = fetchFromGitHub {
-    owner = "ayleph";
-    repo = "mediagoblin-basicsearch";
-    rev = "ba0a1547bd24ebaf363227fe17644d38c6ce8a6b";
-    sha256 = "0d4r7xkf4gxmgaxlb264l44xbanis77g49frwfhfzsflxmdwgncy";
-  };
-  phases = "unpackPhase installPhase";
-  installPhase = ''
-    cp -R ./basicsearch $out
-    '';
-  passthru = {
-    pluginName = "basicsearch";
-  };
-}
diff --git a/pkgs/webapps/mediagoblin/tempita.json b/pkgs/webapps/mediagoblin/tempita.json
deleted file mode 100644
index 5371e17..0000000
--- a/pkgs/webapps/mediagoblin/tempita.json
+++ /dev/null
@@ -1,15 +0,0 @@
-{
-  "tag": "47414a7-master",
-  "meta": {
-    "name": "tempita",
-    "url": "https://github.com/gjhiggins/tempita",
-    "branch": "master"
-  },
-  "github": {
-    "owner": "gjhiggins",
-    "repo": "tempita",
-    "rev": "47414a7c6e46a9a9afe78f0bce2ea299fa84d10d",
-    "sha256": "0f33jjjs5rvp7ar2j6ggyfykcrsrn04jaqcq71qfvycf6b7nw3rn",
-    "fetchSubmodules": true
-  }
-}