Rename virtual folder to nixops

Fixes https://git.immae.eu/mantisbt/view.php?id=82

1 files changed, 48 insertions, 0 deletions

diff --git a/nixops/modules/websites/tools/git/default.nix b/nixops/modules/websites/tools/git/default.nix
new file mode 100644
index 0000000..91aa1d0
--- /dev/null
+++ b/nixops/modules/websites/tools/git/default.nix
@@ -0,0 +1,48 @@
+{ lib, pkgs, config, myconfig, mylibs, ... }:
+let
+    mantisbt = pkgs.callPackage ./mantisbt/mantisbt.nix {
+      inherit (mylibs) fetchedGithub;
+      env = myconfig.env.tools.mantisbt;
+    };
+    gitweb = pkgs.callPackage ./gitweb/gitweb.nix { gitoliteDir = config.services.myGitolite.gitoliteDir; };
+
+    cfg = config.services.myWebsites.tools.git;
+in {
+  options.services.myWebsites.tools.git = {
+    enable = lib.mkEnableOption "enable git's website";
+  };
+
+  config = lib.mkIf cfg.enable {
+    security.acme.certs."eldiron".extraDomains."git.immae.eu" = null;
+
+    nixpkgs.config.packageOverrides = oldpkgs: rec {
+      gitweb = oldpkgs.gitweb.overrideAttrs(old: {
+        installPhase = old.installPhase + ''
+          cp -r ${./gitweb/theme} $out/gitweb-theme;
+          '';
+      });
+    };
+
+    services.myWebsites.tools.modules =
+      gitweb.apache.modules ++
+      mantisbt.apache.modules;
+
+    services.myWebsites.tools.vhostConfs.git = {
+      certName    = "eldiron";
+      hosts       = ["git.immae.eu" ];
+      root        = gitweb.webRoot;
+      extraConfig = [
+        gitweb.apache.vhostConf
+        mantisbt.apache.vhostConf
+        ''
+          RewriteEngine on
+          RewriteCond %{REQUEST_URI}       ^/releases
+          RewriteRule /releases(.*)        https://release.immae.eu$1 [P,L]
+          ''
+      ];
+    };
+    services.myPhpfpm.poolConfigs = {
+      mantisbt = mantisbt.phpFpm.pool;
+    };
+  };
+}