Upgrade stgit

3 files changed, 66 insertions, 1 deletions

diff --git a/environments/immae-eu.nix b/environments/immae-eu.nix
index df57e55..84d8ea0 100644
--- a/environments/immae-eu.nix
+++ b/environments/immae-eu.nix
@@ -36,7 +36,7 @@ let
     sieve-connect
 
     # git
-    vcsh gitRepo gitAndTools.stgit tig ripgrep mr
+    vcsh gitRepo stgit tig ripgrep mr
 
     # graphical tools
     nextcloud-client firefox
diff --git a/pkgs/default.nix b/pkgs/default.nix
index 603d12e..2f5f529 100644
--- a/pkgs/default.nix
+++ b/pkgs/default.nix
@@ -31,6 +31,7 @@ rec {
   rrsync_sudo = callPackage ./rrsync_sudo {};
   signald = callPackage ./signald {};
   signaldctl = callPackage ./signaldctl {};
+  stgit = callPackage ./stgit {};
   telegram-cli = callPackage ./telegram-cli { inherit mylibs; };
   telegram-history-dump = callPackage ./telegram-history-dump { inherit mylibs; };
   telegramircd = callPackage ./telegramircd { inherit mylibs; telethon = callPackage ./telethon_sync {}; };
diff --git a/pkgs/stgit/default.nix b/pkgs/stgit/default.nix
new file mode 100644
index 0000000..da4f7ec
--- /dev/null
+++ b/pkgs/stgit/default.nix
@@ -0,0 +1,64 @@
+# Taken from nixpkgs repository
+{ lib
+, fetchFromGitHub
+, installShellFiles
+, python3Packages
+, asciidoc
+, docbook_xsl
+, git
+, perl
+, xmlto
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "stgit";
+  version = "1.1";
+
+  src = fetchFromGitHub {
+    owner = "stacked-git";
+    repo = "stgit";
+    rev = "v${version}";
+    sha256 = "sha256-gfPf1yRmx1Mn1TyCBWmjQJBgXLlZrDcew32C9o6uNYk=";
+  };
+
+  nativeBuildInputs = [ installShellFiles asciidoc xmlto docbook_xsl ];
+
+  format = "other";
+
+  checkInputs = [ git perl ];
+
+  postPatch = ''
+    for f in Documentation/*.xsl; do
+      substituteInPlace $f \
+        --replace http://docbook.sourceforge.net/release/xsl-ns/current/manpages/docbook.xsl \
+                  ${docbook_xsl}/xml/xsl/docbook/manpages/docbook.xsl \
+        --replace http://docbook.sourceforge.net/release/xsl/current/html/docbook.xsl \
+                  ${docbook_xsl}/xml/xsl/docbook/html/docbook.xsl
+    done
+  '';
+
+  makeFlags = [
+    "prefix=${placeholder "out"}"
+    "MAN_BASE_URL=${placeholder "out"}/share/man"
+    "XMLTO_EXTRA=--skip-validation"
+  ];
+
+  buildFlags = [ "all" ];
+
+  checkTarget = "test";
+  checkFlags = [ "PERL_PATH=${perl}/bin/perl" ];
+
+  installTargets = [ "install" ];
+  postInstall = ''
+    installShellCompletion \
+      --zsh $out/share/stgit/completion/stgit.zsh
+    '';
+
+  meta = with lib; {
+    description = "A patch manager implemented on top of Git";
+    homepage = "https://stacked-git.github.io/";
+    license = licenses.gpl2Only;
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ jshholland ];
+  };
+}