path: root/virtual/modules/databases/default.nix

{ lib, pkgs, config, myconfig, mylibs, ... }:
let
    cfg = config.services.myDatabases;
in {
  options.services.myDatabases = {
    enable = lib.mkEnableOption "my databases service";
    postgresql = {
      enable = lib.mkOption {
        default = cfg.enable;
        example = true;
        description = "Whether to enable postgresql database";
        type = lib.types.bool;
      };
    };

    mariadb = {
      enable = lib.mkOption {
        default = cfg.enable;
        example = true;
        description = "Whether to enable mariadb database";
        type = lib.types.bool;
      };
    };

    redis = {
      enable = lib.mkOption {
        default = cfg.enable;
        example = true;
        description = "Whether to enable redis database";
        type = lib.types.bool;
      };
    };
  };

  config = lib.mkIf cfg.enable {
    nixpkgs.config.packageOverrides = oldpkgs: rec {
      postgresql = postgresql111;
      postgresql111 = oldpkgs.postgresql100.overrideAttrs(old: rec {
        passthru = old.passthru // { psqlSchema = "11.0"; };
        name = "postgresql-11.1";
        src = pkgs.fetchurl {
          url = "mirror://postgresql/source/v11.1/${name}.tar.bz2";
          sha256 = "026v0sicsh7avzi45waf8shcbhivyxmi7qgn9fd1x0vl520mx0ch";
        };
        configureFlags = old.configureFlags ++ [ "--with-pam" ];
        buildInputs = (old.buildInputs or []) ++ [ pkgs.pam ];
        patches = old.patches ++ [
          ./postgresql_run_socket_path.patch
        ];
      });
      mariadb = mariadbPAM;
      mariadbPAM = oldpkgs.mariadb.overrideAttrs(old: rec {
        cmakeFlags = old.cmakeFlags ++ [ "-DWITH_AUTHENTICATION_PAM=ON" ];
        buildInputs = old.buildInputs ++ [ pkgs.pam ];
      });
    };

    networking.firewall.allowedTCPPorts = [ 3306 5432 ];

    services.mysql = rec {
      enable = cfg.mariadb.enable;
      package = pkgs.mariadb;
    };

    security.acme.certs."postgresql" = config.services.myCertificates.certConfig // {
      user = "postgres";
      group = "postgres";
      plugins = [ "fullchain.pem" "key.pem" "account_key.json" ];
      domain = "db-1.immae.eu";
      postRun = ''
        systemctl reload postgresql.service
      '';
    };

    system.activationScripts.postgresql = ''
      install -m 0755 -o postgres -g postgres -d ${myconfig.env.databases.postgresql.socket}
      '';

    services.postgresql = rec {
      enable = cfg.postgresql.enable;
      package = pkgs.postgresql;
      enableTCPIP = true;
      extraConfig = ''
        max_connections = 100
        wal_level = logical
        shared_buffers = 128MB
        max_wal_size = 1GB
        min_wal_size = 80MB
        log_timezone = 'Europe/Paris'
        datestyle = 'iso, mdy'
        timezone = 'Europe/Paris'
        lc_messages = 'en_US.UTF-8'
        lc_monetary = 'en_US.UTF-8'
        lc_numeric = 'en_US.UTF-8'
        lc_time = 'en_US.UTF-8'
        default_text_search_config = 'pg_catalog.english'
        ssl = on
        ssl_cert_file = '/var/lib/acme/postgresql/fullchain.pem'
        ssl_key_file = '/var/lib/acme/postgresql/key.pem'
        '';
      authentication = ''
        local	all	postgres				ident
        local	all	all					md5
        hostssl	all	all		samehost		md5
        hostssl	all	all		178.33.252.96/32	md5
        hostssl	all	all		188.165.209.148/32	md5
        hostssl	all	all		all			pam
        hostssl	replication	backup-1	2001:41d0:302:1100::9:e5a9/128	pam pamservice=postgresql_replication
        hostssl	replication	backup-1	54.37.151.137/32		pam pamservice=postgresql_replication
      '';
    };

    security.pam.services = let
      pam_ldap = "${pkgs.pam_ldap}/lib/security/pam_ldap.so";
      pam_ldap_mysql = pkgs.writeText "mysql.conf" ''
        host ${myconfig.env.ldap.host}
        base ${myconfig.env.ldap.base}
        binddn cn=mysql,cn=pam,ou=services,dc=immae,dc=eu
        bindpw ${myconfig.env.databases.mysql.pam_password}
        ssl start_tls
        pam_filter memberOf=cn=users,cn=mysql,cn=pam,ou=services,dc=immae,dc=eu
        '';
      pam_ldap_postgresql_replication = pkgs.writeText "postgresql.conf" ''
        host ${myconfig.env.ldap.host}
        base ${myconfig.env.ldap.base}
        binddn ${myconfig.env.ldap.host_dn}
        bindpw ${myconfig.env.ldap.password}
        ssl start_tls
        pam_login_attribute cn
        '';
    in [
      {
        name = "mysql";
        text = ''
          # https://mariadb.com/kb/en/mariadb/pam-authentication-plugin/
          auth    required ${pam_ldap} config=${pam_ldap_mysql}
          account required ${pam_ldap} config=${pam_ldap_mysql}
          '';
      }
      {
        name = "postgresql";
        text = ''
          auth    required ${pam_ldap} config=${pam_ldap_postgresql_replication}
          account required ${pam_ldap} config=${pam_ldap_postgresql_replication}
          '';
      }
      {
        name = "postgresql_replication";
        text = ''
          auth    required ${pam_ldap} config=${pam_ldap_postgresql_replication}
          account required ${pam_ldap} config=${pam_ldap_postgresql_replication}
          '';
      }
    ];

    services.redis = rec {
      enable = config.services.myDatabases.redis.enable;
      bind = "127.0.0.1";
      unixSocket = myconfig.env.databases.redis.socket;
      extraConfig = ''
        unixsocketperm 777
        maxclients 1024
        '';
    };
    system.activationScripts.redis = ''
      mkdir -p $(dirname ${myconfig.env.databases.redis.socket})
      chown redis $(dirname ${myconfig.env.databases.redis.socket})
    '';
  };
}