path: root/overlays/bonfire/default.nix

self: super: {
  bonfire = let
    click = self.python3Packages.click.overridePythonAttrs(old: rec {
      version = "6.7";
      src = self.python3Packages.fetchPypi {
        pname = "click";
        inherit version;
        sha256 = "02qkfpykbq35id8glfgwc38yc430427yd05z1wc5cnld8zgicmgi";
      };
      postPatch = ''
        substituteInPlace click/_unicodefun.py --replace "'locale'" "'${self.locale}/bin/locale'"
      '';
      doCheck = false;
    });
    keyring = self.python3Packages.keyring.overridePythonAttrs(old: rec {
      version = "20.0.1";
      src = self.python3Packages.fetchPypi {
        pname = "keyring";
        inherit version;
        sha256 = "963bfa7f090269d30bdc5e25589e5fd9dad2cf2a7c6f176a7f2386910e5d0d8d";
      };
    });
  in
    super.bonfire.overridePythonAttrs(old: {
      version = "0.0.8";
      src = self.fetchFromGitHub {
        owner = "blue-yonder";
        repo = "bonfire";
        rev = "0a0f18469d484aba6871fa7421bbb2c00ccefcb0";
        sha256 = "1y2r537ibghhmk6jngw0zwvh1vn2bihqcvji50ffh1j0qc6q3x6x";
      };
      postPatch = "";
      propagatedBuildInputs = self.lib.subtractLists [ self.python3Packages.click self.python3Packages.keyring ] old.propagatedBuildInputs ++ [ click keyring ];
      meta.broken = false;
    });
}