path: root/modules/private/websites/piedsjaloux/production.nix

{ lib, pkgs, config,  ... }:
let
  secrets = config.myEnv.websites.piedsjaloux.production;
  app = pkgs.webapps.piedsjaloux.override { environment = secrets.environment; };
  cfg = config.myServices.websites.piedsjaloux.production;
  pcfg = config.services.phpApplication;
in {
  options.myServices.websites.piedsjaloux.production.enable = lib.mkEnableOption "enable PiedsJaloux's website in production";

  config = lib.mkIf cfg.enable {
    services.duplyBackup.profiles.piedsjaloux_prod.rootDir = app.varDir;
    services.webstats.sites = [ { name = "piedsjaloux.fr"; } ];
    services.phpApplication.apps.piedsjaloux_prod = {
      websiteEnv = "production";
      httpdUser = config.services.httpd.Prod.user;
      httpdGroup = config.services.httpd.Prod.group;
      inherit (app) webRoot varDir;
      varDirPaths = {
        "tmp" = "0700";
      };
      inherit app;
      serviceDeps = [ "mysql.service" ];
      preStartActions = [
        "./bin/console --env=${app.environment} cache:clear --no-warmup"
      ];
      phpOpenbasedir = [ "/tmp" ];
      phpPool = {
        "php_admin_value[upload_max_filesize]" = "20M";
        "php_admin_value[post_max_size]" = "20M";
        #"php_admin_flag[log_errors]" = "on";
        "pm" = "dynamic";
        "pm.max_children" = "20";
        "pm.start_servers" = "2";
        "pm.min_spare_servers" = "1";
        "pm.max_spare_servers" = "3";
      };
      phpEnv = {
        PATH = lib.makeBinPath [ pkgs.apg pkgs.unzip ];
      };
      phpWatchFiles = [
        config.secrets.fullPaths."webapps/${app.environment}-piedsjaloux"
      ];
    };

    secrets.keys = [
      {
        dest = "webapps/${app.environment}-piedsjaloux";
        user = config.services.httpd.Prod.user;
        group = config.services.httpd.Prod.group;
        permissions = "0400";
        text = ''
          # This file is auto-generated during the composer install
          parameters:
              database_host: ${secrets.mysql.host}
              database_port: ${secrets.mysql.port}
              database_name: ${secrets.mysql.database}
              database_user: ${secrets.mysql.user}
              database_password: ${secrets.mysql.password}
              database_server_version: ${pkgs.mariadb.mysqlVersion}
              mailer_transport: smtp
              mailer_host: 127.0.0.1
              mailer_user: null
              mailer_password: null
              secret: ${secrets.secret}
              pdflatex: "${pkgs.texlive.combine { inherit (pkgs.texlive) attachfile preprint scheme-small; }}/bin/pdflatex"
          leapt_im:
              binary_path: ${pkgs.imagemagick}/bin
        '';
      }
    ];

    services.websites.env.production.vhostConfs.piedsjaloux_prod = {
      certName     = "piedsjaloux";
      certMainHost = "piedsjaloux.fr";
      hosts        = [ "piedsjaloux.fr" "www.piedsjaloux.fr" ];
      root         = pcfg.webappDirs.piedsjaloux_prod;
      extraConfig  = [
        ''
        RewriteEngine on
        RewriteCond "%{HTTP_HOST}" "!^www.piedsjaloux\.fr$" [NC]
        RewriteRule ^(.+)$ https://www.piedsjaloux.fr$1 [R=302,L]

        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${pcfg.phpListenPaths.piedsjaloux_prod}|fcgi://localhost"
        </FilesMatch>

        Use Stats piedsjaloux.fr

        <Directory ${pcfg.webappDirs.piedsjaloux_prod}>
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride All
          Require all granted
        </Directory>
        ''
      ];
    };
  };
}