path: root/modules/private/websites/patrick_fodella/ecolyeu.nix

{ lib, pkgs, config,  ... }:
let
  cfg = config.myServices.websites.patrick_fodella.ecolyeu;
  varDir = "/var/lib/ftp/patrick_fodella/ecolyeu_pessicart";
  apacheUser = config.services.httpd.Prod.user;
  apacheGroup = config.services.httpd.Prod.group;
in {
  options.myServices.websites.patrick_fodella.ecolyeu.enable = lib.mkEnableOption "enable Patrick Fodella Ecolyeu's website";

  config = lib.mkIf cfg.enable {
    services.webstats.sites = [ { name = "ecolyeu-pessicart-nice.fr"; } ];

    system.activationScripts.patrick_fodella_ecolyeu = {
      deps = [ "httpd" ];
      text = ''
        install -m 0755 -o ${apacheUser} -g ${apacheGroup} -d /var/lib/php/sessions/patrick_fodella_ecolyeu
        '';
    };
    systemd.services.phpfpm-patrick_fodella_ecolyeu.after = lib.mkAfter [ "mysql.service" ];
    systemd.services.phpfpm-patrick_fodella_ecolyeu.wants = [ "mysql.service" ];
    services.phpfpm.pools.patrick_fodella_ecolyeu = {
      user = apacheUser;
      group = apacheGroup;
      settings = {
        "listen.owner" = apacheUser;
        "listen.group" = apacheGroup;

        "pm" = "ondemand";
        "pm.max_children" = "5";
        "pm.process_idle_timeout" = "60";

        "php_admin_value[open_basedir]" = "/var/lib/php/sessions/patrick_fodella_ecolyeu:${varDir}:/tmp";
        "php_admin_value[session.save_path]" = "/var/lib/php/sessions/patrick_fodella_ecolyeu";
      };
      phpOptions = config.services.phpfpm.phpOptions + ''
        disable_functions = "mail"
      '';
      phpPackage = pkgs.php72;
    };
    services.websites.env.production.modules = [ "proxy_fcgi" ];
    services.websites.env.production.vhostConfs.patrick_fodella_ecolyeu = {
      certName     = "patrick_fodella";
      certMainHost = "ecolyeu-pessicart-nice.fr";
      hosts        = ["ecolyeu-pessicart-nice.fr" "www.ecolyeu-pessicart-nice.fr" ];
      root         = varDir;
      extraConfig  = [
        ''
        Use Stats ecolyeu-pessicart-nice.fr

        RewriteEngine on
        RewriteCond "%{HTTP_HOST}" "!^www\.ecolyeu-pessicart-nice\.fr$" [NC]
        RewriteRule ^(.+)$ https://www.ecolyeu-pessicart-nice.fr$1 [R=302,L]

        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${config.services.phpfpm.pools.patrick_fodella_ecolyeu.socket}|fcgi://localhost"
        </FilesMatch>

        <Location /xmlrpc.php>
          AllowOverride None
          Require all denied
        </Location>
        <Directory ${varDir}>
          DirectoryIndex index.php index.htm index.html
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride all
          Require all granted
        </Directory>
          ''
      ];
    };
  };
}