path: root/modules/private/websites/ludivine/production.nix

{ lib, pkgs, config,  ... }:
let
  secrets = config.myEnv.websites.ludivine.production;
  app = pkgs.callPackage ./app {
    composerEnv = pkgs.composerEnv.override { php = pkgs.php72; };
    environment = secrets.environment;
    varDir = "/var/lib/ludivine_production";
    secretsPath = config.secrets.fullPaths."websites/ludivine/production";
  };
  pcfg = config.services.phpApplication;
  cfg = config.myServices.websites.ludivine.production;
in {
  options.myServices.websites.ludivine.production.enable = lib.mkEnableOption "enable Ludivine's website in production";

  config = lib.mkIf cfg.enable {
    services.duplyBackup.profiles.ludivine_production.rootDir = app.varDir;
    services.duplyBackup.profiles.ludivine_production.remotes = ["eriomem" "ovh"];
    services.webstats.sites = [ { name = "ludivinecassal.com"; } ];
    services.phpApplication.apps.ludivine_production = {
      websiteEnv = "production";
      httpdUser = config.services.httpd.Prod.user;
      httpdGroup = config.services.httpd.Prod.group;
      inherit (app) webRoot varDir;
      varDirPaths = {
        "tmp" = "0700";
      };
      inherit app;
      serviceDeps = [ "mysql.service" ];
      preStartActions = [
        "./bin/console --env=${app.environment} cache:clear --no-warmup"
      ];
      phpOpenbasedir = [ "/tmp" ];
      phpPool = {
        "php_admin_value[upload_max_filesize]" = "20M";
        "php_admin_value[post_max_size]" = "20M";
        #"php_admin_flag[log_errors]" = "on";
        "pm" = "dynamic";
        "pm.max_children" = "20";
        "pm.start_servers" = "2";
        "pm.min_spare_servers" = "1";
        "pm.max_spare_servers" = "3";
      };
      phpWatchFiles = [
        config.secrets.fullPaths."websites/ludivine/production"
      ];
      phpEnv = {
        PATH = lib.makeBinPath [
          # below ones don't need to be in the PATH but they’re used in
          # secrets
          pkgs.imagemagick pkgs.sass pkgs.ruby
        ];
      };
      phpPackage = pkgs.php72;
    };

    secrets.keys."websites/ludivine/production" = {
      user = config.services.httpd.Prod.user;
      group = config.services.httpd.Prod.group;
      permissions = "0400";
      text = ''
        # This file is auto-generated during the composer install
        parameters:
            database_host: ${secrets.mysql.host}
            database_port: ${secrets.mysql.port}
            database_name: ${secrets.mysql.database}
            database_user: ${secrets.mysql.user}
            database_password: ${secrets.mysql.password}
            database_server_version: ${pkgs.mariadb.mysqlVersion}
            mailer_transport: smtp
            mailer_host: 127.0.0.1
            mailer_user: null
            mailer_password: null
            secret: ${secrets.secret}
            ldap_host: ldap.immae.eu
            ldap_port: 636
            ldap_version: 3
            ldap_ssl: true
            ldap_tls: false
            ldap_user_bind: 'uid={username},ou=users,dc=immae,dc=eu'
            ldap_base_dn: 'dc=immae,dc=eu'
            ldap_search_dn: '${secrets.ldap.dn}'
            ldap_search_password: '${secrets.ldap.password}'
            ldap_search_filter: '${secrets.ldap.filter}'
        leapt_im:
            binary_path: ${pkgs.imagemagick}/bin
        assetic:
            sass: ${pkgs.sass}/bin/sass
            ruby: ${pkgs.ruby}/bin/ruby
      '';
    };

    services.websites.env.production.vhostConfs.ludivine_production = {
      certName     = "ludivine";
      certMainHost = "ludivinecassal.com";
      hosts        = ["ludivinecassal.com" "www.ludivinecassal.com" ];
      root         = app.webRoot;
      extraConfig  = [
        ''
        RewriteEngine on
        RewriteCond "%{HTTP_HOST}" "!^ludivinecassal\.com$" [NC]
        RewriteRule ^(.+)$ https://ludivinecassal.com$1 [R=302,L]

        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${pcfg.phpListenPaths.ludivine_production}|fcgi://localhost"
        </FilesMatch>

        Use Stats ludivinecassal.com

        <Directory ${app.webRoot}>
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride All
          Require all granted
        </Directory>
        ''
      ];
    };
  };
}