path: root/libs.nix

let nixpkgs_unstable = import (builtins.fetchTarball {
  # FIXME: upgrade to nixpkgs 19 when stable and stick to stable
  # versions
  name = "nixos-unstable-2018-12-08";
  url = https://github.com/nixos/nixpkgs/archive/61c3169a0e17d789c566d5b241bfe309ce4a6275.tar.gz;
  sha256 = "0qbycg7wkb71v20rchlkafrjfpbk2fnlvvbh3ai9pyfisci5wxvq";
}) {};
in
  with nixpkgs_unstable;
rec {
  inherit nixpkgs_unstable;
  fetchedGithub = path:
    let
      json = lib.importJSON path;
    in rec {
      version = json.tag;
      name = "${json.meta.name}-${version}";
      src = fetchFromGitHub json.github;
    };

  fetchedGit = path:
    let
      json = lib.importJSON path;
    in rec {
      version = json.tag;
      name = "${json.meta.name}-${version}";
      src = fetchgit json.git;
    };

  fetchedGitPrivate = path:
    let
      json = lib.importJSON path;
    in rec {
      version = json.tag;
      name = "${json.meta.name}-${version}";
      src = fetchgitPrivate json.git;
    };

  wrap = { paths ? [], vars ? {}, file ? null, script ? null, name ? "wrap" }:
    assert file != null || script != null ||
      abort "wrap needs 'file' or 'script' argument";
    with rec {
      set  = n: v: "--set ${pkgs.lib.escapeShellArg n} " +
                    "${pkgs.lib.escapeShellArg v}";
      args = (map (p: "--prefix PATH : ${p}/bin") paths) ++
            (builtins.attrValues (pkgs.lib.mapAttrs set vars));
    };
    runCommand name
      {
        f           = if file == null then writeScript name script else file;
        buildInputs = [ makeWrapper ];
      }
      ''
        makeWrapper "$f" "$out" ${toString args}
      '';

  yarn2nixPackage = callPackage (fetchedGithub ./fetched/yarn2nix.json).src {};
}