virtual/eldiron.nix

   1 {
   2   network = {
   3     description = "Immae's network";
   4     enableRollback = true;
   5   };
   6
   7   eldiron = { config, pkgs, ... }:
   8     with import ../libs.nix;
   9     let
  10         mypkgs = pkgs.callPackage ./packages.nix {
  11           inherit checkEnv fetchedGit fetchedGitPrivate fetchedGithub;
  12         };
  13     in
  14   {
  15     nixpkgs.config.packageOverrides = oldpkgs: rec {
  16       gitolite = oldpkgs.gitolite.overrideAttrs(old: rec {
  17         name = "gitolite-${version}";
  18         version = "3.6.10";
  19         src = pkgs.fetchFromGitHub {
  20           owner = "sitaramc";
  21           repo = "gitolite";
  22           rev = "v${version}";
  23           sha256 = "0p2697mn6rwm03ndlv7q137zczai82n41aplq1g006ii7f12xy8h";
  24         };
  25       });
  26       gitweb = oldpkgs.gitweb.overrideAttrs(old: {
  27         installPhase = old.installPhase + ''
  28           cp -r ${./packages/gitweb} $out/gitweb-theme;
  29           '';
  30       });
  31       postgresql = postgresql111;
  32       postgresql111 = oldpkgs.postgresql100.overrideAttrs(old: rec {
  33         passthru = old.passthru // { psqlSchema = "11.0"; };
  34         name = "postgresql-11.1";
  35         src = pkgs.fetchurl {
  36           url = "mirror://postgresql/source/v11.1/${name}.tar.bz2";
  37           sha256 = "026v0sicsh7avzi45waf8shcbhivyxmi7qgn9fd1x0vl520mx0ch";
  38         };
  39       });
  40       mariadb = mariadbPAM;
  41       mariadbPAM = oldpkgs.mariadb.overrideAttrs(old: rec {
  42         cmakeFlags = old.cmakeFlags ++ [ "-DWITH_AUTHENTICATION_PAM=ON" ];
  43         buildInputs = old.buildInputs ++ [ pkgs.pam ];
  44       });
  45       goaccess = oldpkgs.goaccess.overrideAttrs(old: rec {
  46         name = "goaccess-${version}";
  47         version = "1.3";
  48         src = pkgs.fetchurl {
  49           url = "https://tar.goaccess.io/${name}.tar.gz";
  50           sha256 = "16vv3pj7pbraq173wlxa89jjsd279004j4kgzlrsk1dz4if5qxwc";
  51         };
  52         configureFlags = old.configureFlags ++ [ "--enable-tcb=btree" ];
  53         buildInputs = old.buildInputs ++ [ pkgs.tokyocabinet pkgs.bzip2 ];
  54       });
  55     };
  56
  57     networking = {
  58       firewall = {
  59         enable = true;
  60         allowedTCPPorts = [ 22 80 443 3306 5432 9418 ];
  61       };
  62     };
  63
  64     deployment = {
  65       targetEnv = "hetzner";
  66       hetzner = {
  67         #robotUser = "defined in HETZNER_ROBOT_USER";
  68         #robotPass = "defined in HETZNER_ROBOT_PASS";
  69         mainIPv4 = "176.9.151.89";
  70         partitions = ''
  71           clearpart --all --initlabel --drives=sda,sdb
  72
  73           part swap1 --recommended --label=swap1 --fstype=swap --ondisk=sda
  74           part swap2 --recommended --label=swap2 --fstype=swap --ondisk=sdb
  75
  76           part raid.1 --grow --ondisk=sda
  77           part raid.2 --grow --ondisk=sdb
  78
  79           raid / --level=1 --device=md0 --fstype=ext4 --label=root raid.1 raid.2
  80         '';
  81       };
  82     };
  83
  84     environment.systemPackages = let
  85       # FIXME: move it to nextcloud
  86       occ = pkgs.writeScriptBin "nextcloud-occ" ''
  87         #! ${pkgs.stdenv.shell}
  88         cd ${mypkgs.nextcloud.webRoot}
  89         NEXTCLOUD_CONFIG_DIR="${mypkgs.nextcloud.webRoot}/config" \
  90           exec \
  91           ${config.services.phpfpm.phpPackage}/bin/php \
  92           -c ${config.services.phpfpm.phpPackage}/etc/php.ini \
  93           occ $*
  94         '';
  95     in [
  96       pkgs.telnet
  97       pkgs.htop
  98       pkgs.vim
  99       pkgs.goaccess
 100       occ
 101     ];
 102
 103     # FIXME: doesn't work with httpd?
 104     security.acme.preliminarySelfsigned = true;
 105     security.acme.certs = {
 106       # FIXME: /!\ To create a new certificate, create it before using
 107       # it in httpd
 108       "eldiron" = {
 109         webroot = "/var/lib/acme/acme-challenge";
 110         email = "ismael@bouya.org";
 111         domain = "eldiron.immae.eu";
 112         plugins = [ "cert.pem" "chain.pem" "fullchain.pem" "full.pem" "key.pem" "account_key.json" ];
 113         postRun = ''
 114           systemctl reload httpd.service
 115         '';
 116         allowKeysForGroup = true;
 117         extraDomains = {
 118           "db-1.immae.eu" = null;
 119           "git.immae.eu" = null;
 120           "tools.immae.eu" = null;
 121           "connexionswing.immae.eu" = null;
 122           "sandetludo.immae.eu" = null;
 123           "cloud.immae.eu" = null;
 124           "ludivine.immae.eu" = null;
 125           "dev.aten.pro" = null;
 126           "piedsjaloux.immae.eu" = null;
 127           "chloe.immae.eu" = null;
 128         };
 129       };
 130       "ludivinecassal" = {
 131         webroot = "/var/lib/acme/acme-challenge";
 132         email = "ismael@bouya.org";
 133         domain = "ludivinecassal.com";
 134         plugins = [ "cert.pem" "chain.pem" "fullchain.pem" "full.pem" "key.pem" "account_key.json" ];
 135         postRun = ''
 136           systemctl reload httpd.service
 137         '';
 138         extraDomains = {
 139           "www.ludivinecassal.com" = null;
 140         };
 141       };
 142       "aten" = {
 143         webroot = "/var/lib/acme/acme-challenge";
 144         email = "ismael@bouya.org";
 145         domain = "aten.pro";
 146         plugins = [ "cert.pem" "chain.pem" "fullchain.pem" "full.pem" "key.pem" "account_key.json" ];
 147         postRun = ''
 148           systemctl reload httpd.service
 149         '';
 150         extraDomains = {
 151           "www.aten.pro" = null;
 152         };
 153       };
 154       "piedsjaloux" = {
 155         webroot = "/var/lib/acme/acme-challenge";
 156         email = "ismael@bouya.org";
 157         domain = "piedsjaloux.fr";
 158         plugins = [ "cert.pem" "chain.pem" "fullchain.pem" "full.pem" "key.pem" "account_key.json" ];
 159         postRun = ''
 160           systemctl reload httpd.service
 161         '';
 162         extraDomains = {
 163           "www.piedsjaloux.fr" = null;
 164         };
 165       };
 166       "chloe" = {
 167         webroot = "/var/lib/acme/acme-challenge";
 168         email = "ismael@bouya.org";
 169         domain = "osteopathe-cc.fr";
 170         plugins = [ "cert.pem" "chain.pem" "fullchain.pem" "full.pem" "key.pem" "account_key.json" ];
 171         postRun = ''
 172           systemctl reload httpd.service
 173         '';
 174         extraDomains = {
 175           "www.osteopathe-cc.fr" = null;
 176         };
 177       };
 178       # "connexionswing" = {
 179       #   webroot = "/var/lib/acme/acme-challenge";
 180       #   email = "ismael@bouya.org";
 181       #   domain = "connexionswing.com";
 182       #   plugins = [ "cert.pem" "chain.pem" "fullchain.pem" "full.pem" "key.pem" "account_key.json" ];
 183       #   postRun = ''
 184       #     systemctl reload httpd.service
 185       #   '';
 186       #   extraDomains = {
 187       #     "www.connexionswing.com" = null;
 188       #     "sandetludo.com" = null;
 189       #     "www.sandetludo.com" = null;
 190       #   };
 191       # };
 192     };
 193
 194     services.openssh.extraConfig = ''
 195       AuthorizedKeysCommand     /etc/ssh/ldap_authorized_keys
 196       AuthorizedKeysCommandUser nobody
 197       '';
 198
 199     users.users.wwwrun.extraGroups = [ "gitolite" ];
 200
 201     users.users.gitolite.packages = let
 202       python-packages = python-packages: with python-packages; [
 203         simplejson
 204         urllib3
 205       ];
 206     in
 207       [
 208         (pkgs.python3.withPackages python-packages)
 209       ];
 210     # FIXME: after initial install, need to
 211     # (1) copy rc file (adjust gitolite_ldap_groups.sh)
 212     # (2) (mark old readonly and) sync repos except gitolite-admin
 213     #     rsync -av --exclude=gitolite-admin.git old:/var/lib/gitolite/repositories /var/lib/gitolite/
 214     #     chown -R gitolite:gitolite /var/lib/gitolite
 215     # (3) push force the gitolite-admin to new location (from external point)
 216     #     Don't use an existing key, it will take precedence over
 217     #     gitolite-admin
 218     # (4) su -u gitolite gitolite setup
 219     services.gitolite = {
 220       enable = true;
 221       # FIXME: key from ./ssh
 222       adminPubkey = "ssh-rsa AAAAB3NzaC1yc2EAAAADAQABAAABAQDXqRbiHw7QoHADNIEuo4nUT9fSOIEBMdJZH0bkQAxXyJFyCM1IMz0pxsHV0wu9tdkkr36bPEUj2aV5bkYLBN6nxcV2Y49X8bjOSCPfx3n6Own1h+NeZVBj4ZByrFmqCbTxUJIZ2bZKcWOFncML39VmWdsVhNjg0X4NBBehqXRIKr2gt3E/ESAxTYJFm0BnU0baciw9cN0bsRGqvFgf5h2P48CIAfwhVcGmPQnnAwabnosYQzRWxR0OygH5Kd8mePh6FheIRIigfXsDO8f/jdxwut8buvNIf3m5EBr3tUbTsvM+eV3M5vKGt7sk8T64DVtepTSdOOWtp+47ktsnHOMh immae@immae.eu";
 223     };
 224
 225     services.ympd = mypkgs.ympd.config // { enable = false; };
 226
 227     services.phpfpm = {
 228       # FIXME: move session files to separate dirs
 229       # /!\ phppackage is used in nextcloud configuation
 230       phpOptions = ''
 231         session.save_path = "/var/lib/php/sessions"
 232         session.gc_maxlifetime = 60*60*24*15
 233         session.cache_expire = 60*24*30
 234         ; For nextcloud
 235         extension=${pkgs.phpPackages.redis}/lib/php/extensions/redis.so
 236         ; For nextcloud
 237         extension=${pkgs.phpPackages.apcu}/lib/php/extensions/apcu.so
 238         ; For nextcloud
 239         zend_extension=${pkgs.php}/lib/php/extensions/opcache.so
 240         '';
 241       extraConfig = ''
 242         log_level = notice
 243         '';
 244       poolConfigs = {
 245         adminer = mypkgs.adminer.phpFpm.pool;
 246         connexionswing_dev = mypkgs.connexionswing_dev.phpFpm.pool;
 247         connexionswing_prod = mypkgs.connexionswing_prod.phpFpm.pool;
 248         ludivinecassal_dev = mypkgs.ludivinecassal_dev.phpFpm.pool;
 249         ludivinecassal_prod = mypkgs.ludivinecassal_prod.phpFpm.pool;
 250         piedsjaloux_dev = mypkgs.piedsjaloux_dev.phpFpm.pool;
 251         piedsjaloux_prod = mypkgs.piedsjaloux_prod.phpFpm.pool;
 252         chloe_dev = mypkgs.chloe_dev.phpFpm.pool;
 253         chloe_prod = mypkgs.chloe_prod.phpFpm.pool;
 254         aten_dev = mypkgs.aten_dev.phpFpm.pool;
 255         aten_prod = mypkgs.aten_prod.phpFpm.pool;
 256         nextcloud = mypkgs.nextcloud.phpFpm.pool;
 257         mantisbt = mypkgs.mantisbt.phpFpm.pool;
 258         ttrss = mypkgs.ttrss.phpFpm.pool;
 259       };
 260     };
 261
 262     system.activationScripts = {
 263       connexionswing_dev  = mypkgs.connexionswing_dev.activationScript;
 264       connexionswing_prod = mypkgs.connexionswing_prod.activationScript;
 265       ludivinecassal_dev  = mypkgs.ludivinecassal_dev.activationScript;
 266       ludivinecassal_prod = mypkgs.ludivinecassal_prod.activationScript;
 267       piedsjaloux_dev     = mypkgs.piedsjaloux_dev.activationScript;
 268       piedsjaloux_prod    = mypkgs.piedsjaloux_prod.activationScript;
 269       chloe_dev  = mypkgs.chloe_dev.activationScript;
 270       chloe_prod = mypkgs.chloe_prod.activationScript;
 271       aten_dev  = mypkgs.aten_dev.activationScript;
 272       aten_prod = mypkgs.aten_prod.activationScript;
 273       nextcloud = mypkgs.nextcloud.activationScript;
 274       ttrss = mypkgs.ttrss.activationScript;
 275       httpd = ''
 276         install -d -m 0755 /var/lib/acme/acme-challenge
 277         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions
 278         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions/adminer
 279         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions/mantisbt
 280         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions/ttrss
 281         '';
 282       redis = ''
 283         mkdir -p /run/redis
 284         chown redis /run/redis
 285         '';
 286       gitolite =
 287         assert checkEnv "NIXOPS_GITOLITE_LDAP_PASSWORD";
 288         let
 289         gitolite_ldap_groups = wrap {
 290           name = "gitolite_ldap_groups.sh";
 291           file = ./packages/gitolite_ldap_groups.sh;
 292           vars = {
 293             LDAP_PASS = builtins.getEnv "NIXOPS_GITOLITE_LDAP_PASSWORD";
 294           };
 295           paths = [ pkgs.openldap pkgs.stdenv.shellPackage pkgs.gnugrep pkgs.coreutils ];
 296         };
 297       in {
 298         deps = [ "users" ];
 299         text = ''
 300           if [ -d /var/lib/gitolite ]; then
 301             ln -sf ${gitolite_ldap_groups} /var/lib/gitolite/gitolite_ldap_groups.sh
 302             chmod g+rx /var/lib/gitolite
 303           fi
 304           if [ -f /var/lib/gitolite/projects.list ]; then
 305             chmod g+r /var/lib/gitolite/projects.list
 306           fi
 307         '';
 308       };
 309       # FIXME: initial sync
 310       goaccess = ''
 311         mkdir -p /var/lib/goaccess
 312         mkdir -p /var/lib/goaccess/aten.pro
 313         mkdir -p /var/lib/goaccess/ludivinecassal.com
 314         mkdir -p /var/lib/goaccess/piedsjaloux.fr
 315         mkdir -p /var/lib/goaccess/osteopathe-cc.fr
 316         '';
 317     };
 318
 319     environment.etc."ssh/ldap_authorized_keys" = let
 320       ldap_authorized_keys =
 321         assert checkEnv "NIXOPS_SSHD_LDAP_PASSWORD";
 322         wrap {
 323           name = "ldap_authorized_keys";
 324           file = ./ldap_authorized_keys.sh;
 325           vars = {
 326             LDAP_PASS = builtins.getEnv "NIXOPS_SSHD_LDAP_PASSWORD";
 327             GITOLITE_SHELL = "${pkgs.gitolite}/bin/gitolite-shell";
 328             ECHO = "${pkgs.coreutils}/bin/echo";
 329           };
 330           paths = [ pkgs.openldap pkgs.stdenv.shellPackage pkgs.gnugrep pkgs.gnused pkgs.coreutils ];
 331         };
 332     in {
 333       enable = true;
 334       mode = "0755";
 335       user = "root";
 336       source = ldap_authorized_keys;
 337     };
 338
 339     services.gitDaemon = {
 340       enable = true;
 341       user = "gitolite";
 342       group = "gitolite";
 343       basePath = "${mypkgs.git.web.varDir}/repositories";
 344     };
 345
 346     # FIXME: logrotate
 347     services.httpd = let
 348       withConf = domain: {
 349         enableSSL = true;
 350         sslServerCert = "/var/lib/acme/${domain}/cert.pem";
 351         sslServerKey = "/var/lib/acme/${domain}/key.pem";
 352         sslServerChain = "/var/lib/acme/${domain}/fullchain.pem";
 353         logFormat = "combinedVhost";
 354         listen = [ { ip = "*"; port = 443; } ];
 355       };
 356       apacheConfig = {
 357         gzip = {
 358           modules = [ "deflate" "filter" ];
 359           extraConfig = ''
 360             AddOutputFilterByType DEFLATE text/html text/plain text/xml text/css text/javascript application/javascript
 361           '';
 362         };
 363         ldap = {
 364           modules = [ "ldap" "authnz_ldap" ];
 365           extraConfig = assert checkEnv "NIXOPS_HTTP_LDAP_PASSWORD"; ''
 366             <IfModule ldap_module>
 367               LDAPSharedCacheSize 500000
 368               LDAPCacheEntries 1024
 369               LDAPCacheTTL 600
 370               LDAPOpCacheEntries 1024
 371               LDAPOpCacheTTL 600
 372             </IfModule>
 373
 374             <Macro LDAPConnect>
 375               <IfModule authnz_ldap_module>
 376                 AuthLDAPURL          ldap://ldap.immae.eu:389/dc=immae,dc=eu
 377                 AuthLDAPBindDN       cn=httpd,ou=services,dc=immae,dc=eu
 378                 AuthLDAPBindPassword "${builtins.getEnv "NIXOPS_HTTP_LDAP_PASSWORD"}"
 379                 AuthType             Basic
 380                 AuthName             "Authentification requise (Acces LDAP)"
 381                 AuthBasicProvider    ldap
 382               </IfModule>
 383             </Macro>
 384
 385             <Macro Stats %{domain}>
 386               Alias /awstats /var/lib/goaccess/%{domain}
 387               <Directory /var/lib/goaccess/%{domain}>
 388                 DirectoryIndex index.html
 389                 AllowOverride None
 390                 Require all granted
 391               </Directory>
 392               <Location /awstats>
 393                 Use LDAPConnect
 394                 Require ldap-group cn=%{domain},ou=stats,cn=httpd,ou=services,dc=immae,dc=eu
 395               </Location>
 396             </Macro>
 397           '';
 398         };
 399         http2 = {
 400           modules = [ "http2" ];
 401           extraConfig = ''
 402             Protocols h2 http/1.1
 403           '';
 404         };
 405         customLog = {
 406           modules = [];
 407           extraConfig = ''
 408             LogFormat "%v:%p %h %l %u %t \"%r\" %>s %b \"%{Referer}i\" \"%{User-Agent}i\"" combinedVhost
 409           '';
 410         };
 411       };
 412     in rec {
 413       enable = true;
 414       logPerVirtualHost = true;
 415       multiProcessingModule = "worker";
 416       adminAddr = "httpd@immae.eu";
 417       logFormat = "combinedVhost";
 418       extraModules = pkgs.lib.lists.unique (
 419         mypkgs.adminer.apache.modules ++
 420         mypkgs.nextcloud.apache.modules ++
 421         mypkgs.connexionswing_dev.apache.modules ++
 422         mypkgs.connexionswing_prod.apache.modules ++
 423         mypkgs.ludivinecassal_dev.apache.modules ++
 424         mypkgs.ludivinecassal_prod.apache.modules ++
 425         mypkgs.piedsjaloux_dev.apache.modules ++
 426         mypkgs.piedsjaloux_prod.apache.modules ++
 427         mypkgs.chloe_dev.apache.modules ++
 428         mypkgs.chloe_prod.apache.modules ++
 429         mypkgs.aten_dev.apache.modules ++
 430         mypkgs.aten_prod.apache.modules ++
 431         mypkgs.ympd.apache.modules ++
 432         mypkgs.git.web.apache.modules ++
 433         mypkgs.mantisbt.apache.modules ++
 434         mypkgs.ttrss.apache.modules ++
 435         pkgs.lib.lists.flatten (pkgs.lib.attrsets.mapAttrsToList (n: v: v.modules) apacheConfig) ++
 436         [ "macro" ]);
 437       extraConfig = builtins.concatStringsSep "\n"
 438         (pkgs.lib.attrsets.mapAttrsToList (n: v: v.extraConfig) apacheConfig);
 439       virtualHosts = [
 440         (withConf "eldiron" // {
 441           hostName = "eldiron.immae.eu";
 442           documentRoot = ./www;
 443           extraConfig = ''
 444             DirectoryIndex index.htm
 445             '';
 446         })
 447         (withConf "eldiron" // {
 448           hostName = "db-1.immae.eu";
 449           documentRoot = null;
 450           extraConfig = builtins.concatStringsSep "\n" [
 451             mypkgs.adminer.apache.vhostConf
 452           ];
 453         })
 454         (withConf "eldiron" // {
 455           hostName = "tools.immae.eu";
 456           documentRoot = null;
 457           extraConfig = builtins.concatStringsSep "\n" [
 458             mypkgs.adminer.apache.vhostConf
 459             mypkgs.ympd.apache.vhostConf
 460             mypkgs.ttrss.apache.vhostConf
 461           ];
 462         })
 463         (withConf "eldiron" // {
 464           hostName = "connexionswing.immae.eu";
 465           serverAliases = [ "sandetludo.immae.eu" ];
 466           documentRoot = mypkgs.connexionswing_dev.webRoot;
 467           extraConfig = builtins.concatStringsSep "\n" [
 468             mypkgs.connexionswing_dev.apache.vhostConf
 469           ];
 470         })
 471         (withConf "eldiron" // {
 472           hostName = "ludivine.immae.eu";
 473           documentRoot = mypkgs.ludivinecassal_dev.webRoot;
 474           extraConfig = builtins.concatStringsSep "\n" [
 475             mypkgs.ludivinecassal_dev.apache.vhostConf
 476           ];
 477         })
 478         (withConf "ludivinecassal" // {
 479           hostName = "ludivinecassal.com";
 480           serverAliases = [ "www.ludivinecassal.com" ];
 481           documentRoot = mypkgs.ludivinecassal_prod.webRoot;
 482           extraConfig = builtins.concatStringsSep "\n" [
 483             mypkgs.ludivinecassal_prod.apache.vhostConf
 484           ];
 485         })
 486         (withConf "eldiron" // {
 487           hostName = "piedsjaloux.immae.eu";
 488           documentRoot = mypkgs.piedsjaloux_dev.webRoot;
 489           extraConfig = builtins.concatStringsSep "\n" [
 490             mypkgs.piedsjaloux_dev.apache.vhostConf
 491           ];
 492         })
 493         (withConf "piedsjaloux" // {
 494           hostName = "piedsjaloux.fr";
 495           serverAliases = [ "www.piedsjaloux.fr" ];
 496           documentRoot = mypkgs.piedsjaloux_prod.webRoot;
 497           extraConfig = builtins.concatStringsSep "\n" [
 498             mypkgs.piedsjaloux_prod.apache.vhostConf
 499           ];
 500         })
 501         (withConf "eldiron" // {
 502           hostName = "chloe.immae.eu";
 503           documentRoot = mypkgs.chloe_dev.webRoot;
 504           extraConfig = builtins.concatStringsSep "\n" [
 505             mypkgs.chloe_dev.apache.vhostConf
 506           ];
 507         })
 508         (withConf "chloe" // {
 509           hostName = "osteopathe-cc.fr";
 510           serverAliases = [ "www.osteopathe-cc.fr" ];
 511           documentRoot = mypkgs.chloe_prod.webRoot;
 512           extraConfig = builtins.concatStringsSep "\n" [
 513             mypkgs.chloe_prod.apache.vhostConf
 514           ];
 515         })
 516         (withConf "eldiron" // {
 517           hostName = "dev.aten.pro";
 518           documentRoot = mypkgs.aten_dev.webRoot;
 519           extraConfig = builtins.concatStringsSep "\n" [
 520             mypkgs.aten_dev.apache.vhostConf
 521           ];
 522         })
 523         (withConf "aten" // {
 524           hostName = "aten.pro";
 525           serverAliases = [ "www.aten.pro" ];
 526           documentRoot = mypkgs.aten_prod.webRoot;
 527           extraConfig = builtins.concatStringsSep "\n" [
 528             mypkgs.aten_prod.apache.vhostConf
 529           ];
 530         })
 531         (withConf "eldiron" // {
 532           hostName = "cloud.immae.eu";
 533           documentRoot = mypkgs.nextcloud.webRoot;
 534           extraConfig = builtins.concatStringsSep "\n" [
 535             mypkgs.nextcloud.apache.vhostConf
 536           ];
 537         })
 538         (withConf "eldiron" // {
 539           hostName = "git.immae.eu";
 540           documentRoot = mypkgs.git.web.webRoot;
 541           extraConfig = builtins.concatStringsSep "\n" [
 542             mypkgs.git.web.apache.vhostConf
 543             mypkgs.mantisbt.apache.vhostConf
 544           ] + ''
 545             RewriteEngine on
 546             RewriteCond %{REQUEST_URI}       ^/releases
 547             RewriteRule /releases(.*)        https://release.immae.eu$1 [P,L]
 548             '';
 549         })
 550         { # Should go last, default fallback
 551           listen = [ { ip = "*"; port = 80; } ];
 552           hostName = "redirectSSL";
 553           serverAliases = [ "*" ];
 554           enableSSL = false;
 555           logFormat = "combinedVhost";
 556           documentRoot = "/var/lib/acme/acme-challenge";
 557           extraConfig = ''
 558             RewriteEngine on
 559             RewriteCond "%{REQUEST_URI}"   "!^/\.well-known"
 560             RewriteRule ^(.+)              https://%{HTTP_HOST}$1  [R=301]
 561             # To redirect in specific "VirtualHost *:80", do
 562             #   RedirectMatch 301 ^/((?!\.well-known.*$).*)$ https://host/$1
 563             # rather than rewrite
 564             '';
 565         }
 566         ];
 567     };
 568
 569     security.pam.services = let
 570       pam_ldap = pkgs.pam_ldap;
 571       pam_ldap_mysql = assert checkEnv "NIXOPS_MYSQL_PAM_PASSWORD";
 572               pkgs.writeText "mysql.conf" ''
 573         host ldap.immae.eu
 574         base dc=immae,dc=eu
 575         binddn cn=mysql,cn=pam,ou=services,dc=immae,dc=eu
 576         bindpw ${builtins.getEnv "NIXOPS_MYSQL_PAM_PASSWORD"}
 577         pam_filter memberOf=cn=users,cn=mysql,cn=pam,ou=services,dc=immae,dc=eu
 578         '';
 579     in [
 580       {
 581         name = "mysql";
 582         text = ''
 583           # https://mariadb.com/kb/en/mariadb/pam-authentication-plugin/
 584           auth    required ${pam_ldap}/lib/security/pam_ldap.so config=${pam_ldap_mysql}
 585           account required ${pam_ldap}/lib/security/pam_ldap.so config=${pam_ldap_mysql}
 586           '';
 587       }
 588     ];
 589
 590     # FIXME: backup
 591     # Nextcloud: 14
 592     services.redis = rec {
 593       enable = true;
 594       bind = "127.0.0.1";
 595       unixSocket = "/run/redis/redis.sock";
 596       extraConfig = ''
 597         unixsocketperm 777
 598         maxclients 1024
 599         '';
 600     };
 601
 602     # FIXME: initial sync
 603     # FIXME: backup
 604     # FIXME: restart after pam
 605     # FIXME: pam access doesn’t work (because of php module)
 606     # FIXME: ssl
 607     services.mysql = rec {
 608       enable = true;
 609       package = pkgs.mariadb;
 610     };
 611
 612     # FIXME: initial sync
 613     # FIXME: backup
 614     # FIXME: ssl
 615     services.postgresql = rec {
 616       enable = true;
 617       package = pkgs.postgresql;
 618       enableTCPIP = true;
 619       extraConfig = ''
 620         max_connections = 100
 621         wal_level = logical
 622         shared_buffers = 128MB
 623         max_wal_size = 1GB
 624         min_wal_size = 80MB
 625         log_timezone = 'Europe/Paris'
 626         datestyle = 'iso, mdy'
 627         timezone = 'Europe/Paris'
 628         lc_messages = 'en_US.UTF-8'
 629         lc_monetary = 'en_US.UTF-8'
 630         lc_numeric = 'en_US.UTF-8'
 631         lc_time = 'en_US.UTF-8'
 632         default_text_search_config = 'pg_catalog.english'
 633         # ssl = on
 634         # ssl_cert_file = '/var/lib/acme/eldiron/fullchain.pem'
 635         # ssl_key_file = '/var/lib/acme/eldiron/key.pem'
 636         '';
 637       authentication = ''
 638         local   all     postgres                                ident
 639         local   all     all                                     md5
 640         host    all     all             samehost                md5
 641         host    all     all             178.33.252.96/32        md5
 642         host    all     all             188.165.209.148/32      md5
 643         #host   all     all             all                     pam
 644       '';
 645     };
 646
 647     services.cron = {
 648       enable = true;
 649       systemCronJobs = let
 650         stats = domain: conf: let
 651           d = pkgs.writeScriptBin "stats-${domain}" "${pkgs.gnused}/bin/sed -n '/\\['$(LC_ALL=C ${pkgs.coreutils}/bin/date -d yesterday +'%d\\/%b\\/%Y')'/ p' /var/log/httpd/access_log-${domain} | ${pkgs.goaccess}/bin/goaccess -o /var/lib/goaccess/${domain}/index.html -p ${conf}";
 652           in "${d}/bin/stats-${domain}";
 653       in [
 654         "5 0 * * * root ${stats "aten.pro" ./packages/aten_goaccess.conf}"
 655         "5 0 * * * root ${stats "ludivinecassal.com" ./packages/ludivinecassal_goaccess.conf}"
 656         "5 0 * * * root ${stats "piedsjaloux.fr" ./packages/piedsjaloux_goaccess.conf}"
 657         "5 0 * * * root ${stats "osteopathe-cc.fr" ./packages/chloe_goaccess.conf}"
 658         ];
 659     };
 660
 661     systemd.services.tt-rss = {
 662       description = "Tiny Tiny RSS feeds update daemon";
 663       serviceConfig = {
 664         User = "wwwrun";
 665         ExecStart = "${pkgs.php}/bin/php ${mypkgs.ttrss.webRoot}/update.php --daemon";
 666         StandardOutput = "syslog";
 667         StandardError = "syslog";
 668         PermissionsStartOnly = true;
 669       };
 670
 671       wantedBy = [ "multi-user.target" ];
 672       requires = ["postgresql.service"];
 673       after = ["network.target" "postgresql.service"];
 674     };
 675   };
 676 }