pkgs/webapps/mediagoblin/default.nix

   1 { makeWrapper, stdenv, writeScript, fetchurl, buildBowerComponents, mylibs, which, python36, gst_all_1, automake, autoconf, nodejs, nodePackages, lib, callPackage }:
   2 let
   3   overridePython = let
   4     packageOverrides = self: super: {
   5       pybcrypt = super.buildPythonPackage rec {
   6         pname = "pybcrypt";
   7         version = "0.4";
   8
   9         src = self.fetchPypi {
  10           inherit pname version;
  11           sha256 = "5fa13bce551468350d66c4883694850570f3da28d6866bb638ba44fe5eabda78";
  12         };
  13       };
  14       celery = super.celery.overridePythonAttrs(old: rec {
  15         version = "3.1.26.post2";
  16         src = self.fetchPypi {
  17           inherit version;
  18           inherit (old) pname;
  19           sha256 = "5493e172ae817b81ba7d09443ada114886765a8ce02f16a56e6fac68d953a9b2";
  20         };
  21         patches = [];
  22         doCheck = false;
  23       });
  24       billiard = super.billiard.overridePythonAttrs(old: rec {
  25         version = "3.3.0.23";
  26         src = self.fetchPypi {
  27           inherit version;
  28           inherit (old) pname;
  29           sha256 = "02wxsc6bhqvzh8j6w758kvgqbnj14l796mvmrcms8fgfamd2lak9";
  30         };
  31         doCheck = false;
  32         doInstallCheck = false;
  33       });
  34       amqp = super.amqp.overridePythonAttrs(old: rec {
  35         version = "1.4.9";
  36         src = self.fetchPypi {
  37           inherit version;
  38           inherit (old) pname;
  39           sha256 = "2dea4d16d073c902c3b89d9b96620fb6729ac0f7a923bbc777cb4ad827c0c61a";
  40         };
  41       });
  42       kombu = super.kombu.overridePythonAttrs(old: rec {
  43         version = "3.0.37";
  44         src = self.fetchPypi {
  45           inherit version;
  46           inherit (old) pname;
  47           sha256 = "e064a00c66b4d1058cd2b0523fb8d98c82c18450244177b6c0f7913016642650";
  48         };
  49         propagatedBuildInputs = old.propagatedBuildInputs ++ [ self.anyjson ];
  50         doCheck = false;
  51       });
  52       sqlalchemy = super.sqlalchemy.overridePythonAttrs(old: rec {
  53         version = "1.1.18";
  54         src = self.fetchPypi {
  55           inherit version;
  56           inherit (old) pname;
  57           sha256 = "8b0ec71af9291191ba83a91c03d157b19ab3e7119e27da97932a4773a3f664a9";
  58         };
  59         doCheck = false;
  60       });
  61       tempita_5_3_dev = super.buildPythonPackage (mylibs.fetchedGithub ./tempita.json // rec {
  62         buildInputs = with self; [ nose ];
  63         disabled = false;
  64       });
  65       sqlalchemy_migrate = super.sqlalchemy_migrate.overridePythonAttrs(old: rec {
  66         propagatedBuildInputs = with self; [ pbr tempita_5_3_dev decorator sqlalchemy six sqlparse ];
  67       });
  68       pasteScript = super.pasteScript.overridePythonAttrs(old: rec {
  69         version = "2.0.2";
  70         name = "PasteScript-${version}";
  71         src = fetchurl {
  72           url = "mirror://pypi/P/PasteScript/${name}.tar.gz";
  73           sha256 = "1h3nnhn45kf4pbcv669ik4faw04j58k8vbj1hwrc532k0nc28gy0";
  74         };
  75         propagatedBuildInputs = with self; [ six paste PasteDeploy ];
  76       });
  77     };
  78     in
  79       python36.override { inherit packageOverrides; };
  80   pythonEnv = python-pkgs: with python-pkgs; [
  81     waitress alembic dateutil wtforms pybcrypt
  82     pytest pytest_xdist werkzeug celery
  83     kombu jinja2 Babel webtest configobj markdown
  84     sqlalchemy itsdangerous pytz sphinx six
  85     oauthlib unidecode jsonschema PasteDeploy
  86     requests PyLD exifread
  87     typing pasteScript lxml
  88     # For images plugin
  89     pillow
  90     # For video plugin
  91     gst-python
  92     # migrations
  93     sqlalchemy_migrate
  94     # authentication
  95     ldap3
  96     redis
  97     psycopg2
  98   ];
  99   python = overridePython.withPackages pythonEnv;
 100   gmg = writeScript "gmg" ''
 101     #!${python}/bin/python
 102     __requires__ = 'mediagoblin'
 103     import sys
 104     from pkg_resources import load_entry_point
 105
 106     if __name__ == '__main__':
 107         sys.exit(
 108             load_entry_point('mediagoblin', 'console_scripts', 'gmg')()
 109         )
 110     '';
 111   bowerComponents = buildBowerComponents {
 112     name = "mediagoblin-bower-components";
 113     generated = ./bower-packages.nix;
 114     src = (mylibs.fetchedGit ./mediagoblin.json).src;
 115   };
 116   pluginNames = [ "basicsearch" ];
 117   allPlugins = lib.attrsets.genAttrs pluginNames
 118     (name: callPackage (./plugins + "/${name}") {});
 119   toPassthru = pkg: {
 120     inherit allPlugins;
 121     withPlugins = withPlugins pkg;
 122   };
 123   withPlugins = pkg: toPlugins:
 124     let
 125       plugins = toPlugins allPlugins;
 126       toBuildPlugin = n: "ln -s ${n} mediagoblin/plugins/${n.pluginName}";
 127       newMediagoblin = pkg.overrideAttrs(old: {
 128         postBuild = old.postBuild + "\n" + builtins.concatStringsSep "\n" (map toBuildPlugin plugins);
 129         passthru = toPassthru newMediagoblin;
 130       });
 131     in newMediagoblin;
 132   package = stdenv.mkDerivation (mylibs.fetchedGit ./mediagoblin.json // rec {
 133     preConfigure = ''
 134       # ./bootstrap.sh
 135       aclocal -I m4 --install
 136       autoreconf -fvi
 137       # end
 138       export HOME=$PWD
 139       '';
 140     configureFlags = [ "--with-python3" "--without-virtualenv" ];
 141     postBuild = ''
 142       cp -a ${bowerComponents}/bower_components/* extlib
 143       chmod -R u+w extlib
 144       make extlib
 145       '';
 146     installPhase = let
 147       libpaths = with gst_all_1; [
 148         python
 149         gstreamer
 150         gst-plugins-base
 151         gst-libav
 152         gst-plugins-good
 153         gst-plugins-bad
 154         gst-plugins-ugly
 155       ];
 156       plugin_paths = builtins.concatStringsSep ":" (map (x: "${x}/lib") libpaths);
 157       typelib_paths = with gst_all_1; "${gstreamer}/lib/girepository-1.0:${gst-plugins-base}/lib/girepository-1.0";
 158     in ''
 159       sed -i "s/registry.has_key(current_theme_name)/current_theme_name in registry/" mediagoblin/tools/theme.py
 160       sed -i -e "s@\[DEFAULT\]@[DEFAULT]\nhere = $out@" mediagoblin/config_spec.ini
 161       sed -i -e "/from gi.repository import GstPbutils/s/^/gi.require_version('GstPbutils', '1.0')\n/" mediagoblin/media_types/video/transcoders.py
 162       cp ${./ldap_fix.py} mediagoblin/plugins/ldap/tools.py
 163       find . -name '*.pyc' -delete
 164       find . -type f -exec sed -i "s|$PWD|$out|g" {} \;
 165       python setup.py build
 166       cp -a . $out
 167       mkdir $out/bin
 168       makeWrapper ${gmg} $out/bin/gmg --prefix PYTHONPATH : "$out:$PYTHONPATH" \
 169         --prefix GST_PLUGIN_SYSTEM_PATH : ${plugin_paths} \
 170         --prefix GI_TYPELIB_PATH : ${typelib_paths}
 171       makeWrapper ${python}/bin/paster $out/bin/paster --prefix PYTHONPATH : "$out:$PYTHONPATH" \
 172         --prefix GST_PLUGIN_SYSTEM_PATH : ${plugin_paths} \
 173         --prefix GI_TYPELIB_PATH : ${typelib_paths}
 174       makeWrapper ${python}/bin/celery $out/bin/celery --prefix PYTHONPATH : "$out:$PYTHONPATH" \
 175         --prefix GST_PLUGIN_SYSTEM_PATH : ${plugin_paths} \
 176         --prefix GI_TYPELIB_PATH : ${typelib_paths}
 177       '';
 178     buildInputs = [ makeWrapper automake autoconf which nodePackages.bower nodejs python ];
 179     propagatedBuildInputs = with gst_all_1; [ python gst-libav gst-plugins-good gst-plugins-bad gst-plugins-ugly gstreamer ];
 180     passthru = toPassthru package;
 181   });
 182 in package