nixops/modules/websites/default.nix

   1 { lib, pkgs, config, mylibs, myconfig, ... }:
   2 let
   3   cfg = config.services.myWebsites;
   4   makeService = name: cfg: let
   5     toVhost = vhostConf: {
   6       enableSSL = true;
   7       sslServerCert = "/var/lib/acme/${vhostConf.certName}/cert.pem";
   8       sslServerKey = "/var/lib/acme/${vhostConf.certName}/key.pem";
   9       sslServerChain = "/var/lib/acme/${vhostConf.certName}/fullchain.pem";
  10       logFormat = "combinedVhost";
  11       listen = [
  12         { ip = cfg.ip;  port = 443; }
  13       ];
  14       hostName = builtins.head vhostConf.hosts;
  15       serverAliases = builtins.tail vhostConf.hosts or [];
  16       documentRoot = vhostConf.root;
  17       extraConfig = builtins.concatStringsSep "\n" vhostConf.extraConfig;
  18     };
  19     redirectVhost = { # Should go last, catchall http -> https redirect
  20       listen = [ { ip = cfg.ip; port = 80; } ];
  21       hostName = "redirectSSL";
  22       serverAliases = [ "*" ];
  23       enableSSL = false;
  24       logFormat = "combinedVhost";
  25       documentRoot = "/var/lib/acme/acme-challenge";
  26       extraConfig = ''
  27         RewriteEngine on
  28         RewriteCond "%{REQUEST_URI}"   "!^/\.well-known"
  29         RewriteRule ^(.+)              https://%{HTTP_HOST}$1  [R=301]
  30         # To redirect in specific "VirtualHost *:80", do
  31         #   RedirectMatch 301 ^/((?!\.well-known.*$).*)$ https://host/$1
  32         # rather than rewrite
  33       '';
  34     };
  35     fallbackVhost = toVhost { # Should go first, default choice
  36       certName    = "eldiron";
  37       hosts       = ["eldiron.immae.eu" ];
  38       root        = ../../www;
  39       extraConfig = [ "DirectoryIndex index.htm" ];
  40     };
  41   in rec {
  42     enable = true;
  43     listen = [
  44       { ip = cfg.ip;  port = 443; }
  45     ];
  46     stateDir = "/run/httpd_${name}";
  47     logPerVirtualHost = true;
  48     multiProcessingModule = "worker";
  49     adminAddr = "httpd@immae.eu";
  50     logFormat = "combinedVhost";
  51     extraModules = pkgs.lib.lists.unique (pkgs.lib.lists.flatten cfg.modules);
  52     extraConfig = builtins.concatStringsSep "\n" cfg.extraConfig;
  53     virtualHosts = [ fallbackVhost ]
  54       ++ (pkgs.lib.attrsets.mapAttrsToList (n: v: toVhost v) cfg.vhostConfs)
  55       ++ [ redirectVhost ];
  56   };
  57   makeServiceOptions = name: ip: {
  58     enable = lib.mkEnableOption "enable websites in ${name}";
  59     ip = lib.mkOption {
  60       type = lib.types.string;
  61       default = ip;
  62       description = "${name} ip to listen to";
  63     };
  64     modules = lib.mkOption {
  65       type = lib.types.listOf (lib.types.str);
  66       default = [];
  67     };
  68     extraConfig = lib.mkOption {
  69       type = lib.types.listOf (lib.types.lines);
  70       default = [];
  71     };
  72     vhostConfs = lib.mkOption {
  73       type = lib.types.attrsOf (lib.types.submodule {
  74         options = {
  75           certName = lib.mkOption { type = lib.types.string; };
  76           hosts    = lib.mkOption { type = lib.types.listOf lib.types.string; };
  77           root     = lib.mkOption { type = lib.types.nullOr lib.types.path; };
  78           extraConfig = lib.mkOption { type = lib.types.listOf lib.types.lines; default = []; };
  79         };
  80       });
  81     };
  82   };
  83   makeModules = cfg: pkgs.lib.lists.flatten (pkgs.lib.attrsets.mapAttrsToList (n: v: v.modules or []) cfg.apacheConfig);
  84   makeExtraConfig = cfg: (builtins.filter (x: x != null) (pkgs.lib.attrsets.mapAttrsToList (n: v: v.extraConfig or null) cfg.apacheConfig));
  85 in
  86 {
  87   imports = [
  88     ./chloe
  89     ./ludivine
  90     ./aten
  91     ./piedsjaloux
  92     ./connexionswing
  93     ./tellesflorian
  94     ./ftp/jerome.nix
  95     ./ftp/nassime.nix
  96     ./ftp/florian.nix
  97     ./ftp/denisejerome.nix
  98     ./tools/db
  99     ./tools/tools
 100     ./tools/dav
 101     ./tools/cloud
 102     ./tools/git
 103     ./tools/mastodon
 104     ./tools/mediagoblin
 105     ./tools/diaspora
 106     ./tools/ether
 107     # built using:
 108     # sed -e "s/services\.httpd/services\.httpdProd/g" .nix-defexpr/channels/nixpkgs/nixos/modules/services/web-servers/apache-httpd/default.nix
 109     # Removed allGranted
 110     # And removed users / groups
 111     ./apache/httpd_prod.nix
 112     ./apache/httpd_inte.nix
 113     # except for this one for users/groups
 114     ./apache/httpd_tools.nix
 115     # Adapted from base phpfpm
 116     ./phpfpm
 117   ];
 118
 119   options.services.myWebsites = {
 120     production = makeServiceOptions "production" myconfig.ips.production;
 121     integration = makeServiceOptions "integration" myconfig.ips.integration;
 122     tools = makeServiceOptions "tools" myconfig.ips.main;
 123
 124     apacheConfig = lib.mkOption {
 125       type = lib.types.attrsOf (lib.types.submodule {
 126         options = {
 127           modules = lib.mkOption {
 128             type = lib.types.listOf (lib.types.str);
 129             default = [];
 130           };
 131           extraConfig = lib.mkOption {
 132             type = lib.types.nullOr lib.types.lines;
 133             default = null;
 134           };
 135         };
 136       });
 137       default = {};
 138       description = "Extra global config";
 139     };
 140
 141   };
 142
 143   config = {
 144     networking = {
 145       firewall = {
 146         enable = true;
 147         allowedTCPPorts = [ 80 443 ];
 148       };
 149       interfaces."eth0".ipv4.addresses = [
 150         # 176.9.151.89 declared in nixops -> infra / tools
 151         { address = myconfig.ips.production; prefixLength = 32; }
 152         { address = myconfig.ips.integration; prefixLength = 32; }
 153       ];
 154     };
 155
 156     nixpkgs.config.packageOverrides = oldpkgs: rec {
 157       php = php72;
 158       php72 = (oldpkgs.php72.override {
 159         mysql.connector-c = pkgs.mariadb;
 160         config.php.mysqlnd = false;
 161         config.php.mysqli = false;
 162       }).overrideAttrs(old: rec {
 163         # Didn't manage to build with mysqli + mysql_config connector
 164         configureFlags = old.configureFlags ++ [
 165           "--with-mysqli=shared,mysqlnd"
 166           ];
 167         # preConfigure = (old.preConfigure or "") + ''
 168         #   export CPPFLAGS="$CPPFLAGS -I${pkgs.mariadb}/include/mysql/server";
 169         #   sed -i -e 's/#include "mysqli_priv.h"/#include "mysqli_priv.h"\n#include <mysql_version.h>/' \
 170         #     ext/mysqli/mysqli.c ext/mysqli/mysqli_prop.c
 171         #   '';
 172       });
 173       phpPackages = oldpkgs.php72Packages.override { inherit php; };
 174       composerEnv = import ./commons/composer-env.nix {
 175         inherit (pkgs) stdenv writeTextFile fetchurl php unzip;
 176       };
 177     };
 178
 179     services.myWebsites.tools.databases.enable = true;
 180     services.myWebsites.tools.tools.enable = true;
 181     services.myWebsites.tools.dav.enable = true;
 182     services.myWebsites.tools.cloud.enable = true;
 183     services.myWebsites.tools.git.enable = true;
 184     services.myWebsites.tools.mastodon.enable = true;
 185     services.myWebsites.tools.mediagoblin.enable = true;
 186     services.myWebsites.tools.diaspora.enable = true;
 187     services.myWebsites.tools.etherpad-lite.enable = true;
 188
 189     services.myWebsites.Chloe.production.enable = cfg.production.enable;
 190     services.myWebsites.Ludivine.production.enable = cfg.production.enable;
 191     services.myWebsites.Aten.production.enable = cfg.production.enable;
 192     services.myWebsites.PiedsJaloux.production.enable = cfg.production.enable;
 193     services.myWebsites.Connexionswing.production.enable = cfg.production.enable;
 194     services.myWebsites.Jerome.production.enable = cfg.production.enable;
 195     services.myWebsites.Nassime.production.enable = cfg.production.enable;
 196     services.myWebsites.Florian.production.enable = cfg.production.enable;
 197     services.myWebsites.DeniseJerome.production.enable = cfg.production.enable;
 198
 199     services.myWebsites.Chloe.integration.enable = cfg.integration.enable;
 200     services.myWebsites.Ludivine.integration.enable = cfg.integration.enable;
 201     services.myWebsites.Aten.integration.enable = cfg.integration.enable;
 202     services.myWebsites.PiedsJaloux.integration.enable = cfg.integration.enable;
 203     services.myWebsites.Connexionswing.integration.enable = cfg.integration.enable;
 204     services.myWebsites.TellesFlorian.integration.enable = true;
 205     services.myWebsites.Florian.integration.enable = true;
 206
 207     services.myWebsites.apacheConfig = {
 208       gzip = {
 209         modules = [ "deflate" "filter" ];
 210         extraConfig = ''
 211           AddOutputFilterByType DEFLATE text/html text/plain text/xml text/css text/javascript application/javascript
 212         '';
 213       };
 214       macros = {
 215         modules = [ "macro" ];
 216       };
 217       ldap = {
 218         modules = [ "ldap" "authnz_ldap" ];
 219         extraConfig = ''
 220           <IfModule ldap_module>
 221             LDAPSharedCacheSize 500000
 222             LDAPCacheEntries 1024
 223             LDAPCacheTTL 600
 224             LDAPOpCacheEntries 1024
 225             LDAPOpCacheTTL 600
 226           </IfModule>
 227
 228           <Macro LDAPConnect>
 229             <IfModule authnz_ldap_module>
 230               AuthLDAPURL          ldap://ldap.immae.eu:389/dc=immae,dc=eu STARTTLS
 231               AuthLDAPBindDN       cn=httpd,ou=services,dc=immae,dc=eu
 232               AuthLDAPBindPassword "${myconfig.env.httpd.ldap.password}"
 233               AuthType             Basic
 234               AuthName             "Authentification requise (Acces LDAP)"
 235               AuthBasicProvider    ldap
 236             </IfModule>
 237           </Macro>
 238
 239           <Macro Stats %{domain}>
 240             Alias /awstats /var/lib/goaccess/%{domain}
 241             <Directory /var/lib/goaccess/%{domain}>
 242               DirectoryIndex index.html
 243               AllowOverride None
 244               Require all granted
 245             </Directory>
 246             <Location /awstats>
 247               Use LDAPConnect
 248               Require ldap-group cn=%{domain},ou=stats,cn=httpd,ou=services,dc=immae,dc=eu
 249             </Location>
 250           </Macro>
 251
 252           ErrorDocument 500 /maintenance_immae.html
 253           ErrorDocument 501 /maintenance_immae.html
 254           ErrorDocument 502 /maintenance_immae.html
 255           ErrorDocument 503 /maintenance_immae.html
 256           ErrorDocument 504 /maintenance_immae.html
 257           Alias /maintenance_immae.html ${../../www}/maintenance_immae.html
 258           ProxyPass /maintenance_immae.html !
 259
 260           AliasMatch "(.*)/googleb6d69446ff4ca3e5.html" ${../../www}/googleb6d69446ff4ca3e5.html
 261         '';
 262       };
 263       http2 = {
 264         modules = [ "http2" ];
 265         extraConfig = ''
 266           Protocols h2 http/1.1
 267         '';
 268       };
 269       customLog = {
 270         extraConfig = ''
 271           LogFormat "%v:%p %h %l %u %t \"%r\" %>s %b \"%{Referer}i\" \"%{User-Agent}i\"" combinedVhost
 272         '';
 273       };
 274     };
 275
 276     system.activationScripts = {
 277       httpd = ''
 278         install -d -m 0755 /var/lib/acme/acme-challenge
 279         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions
 280         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions/adminer
 281         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions/mantisbt
 282         install -d -m 0750 -o wwwrun -g wwwrun /var/lib/php/sessions/davical
 283         '';
 284     };
 285
 286     services.myPhpfpm = {
 287       phpPackage = pkgs.php;
 288       phpOptions = ''
 289         session.save_path = "/var/lib/php/sessions"
 290         session.gc_maxlifetime = 60*60*24*15
 291         session.cache_expire = 60*24*30
 292         '';
 293       extraConfig = ''
 294         log_level = notice
 295         '';
 296     };
 297
 298     services.httpdProd = makeService "production" config.services.myWebsites.production;
 299     services.myWebsites.production.modules = makeModules cfg;
 300     services.myWebsites.production.extraConfig = makeExtraConfig cfg;
 301
 302     services.httpdInte = makeService "integration" config.services.myWebsites.integration;
 303     services.myWebsites.integration.modules = makeModules cfg;
 304     services.myWebsites.integration.extraConfig = makeExtraConfig cfg;
 305
 306     services.httpdTools = makeService "tools" config.services.myWebsites.tools;
 307     services.myWebsites.tools.modules = makeModules cfg;
 308     services.myWebsites.tools.extraConfig = makeExtraConfig cfg ++
 309     [ ''
 310         RedirectMatch ^/licen[cs]es?_et_tip(ping)?$ https://www.immae.eu/licences_et_tip.html
 311         RedirectMatch ^/licen[cs]es?_and_tip(ping)?$ https://www.immae.eu/licenses_and_tipping.html
 312         RedirectMatch ^/licen[cs]es?$ https://www.immae.eu/licenses_and_tipping.html
 313         RedirectMatch ^/tip(ping)?$ https://www.immae.eu/licenses_and_tipping.html
 314         RedirectMatch ^/(mentions|mentions_legales|legal)$ https://www.immae.eu/mentions.html
 315         RedirectMatch ^/CGU$ https://www.immae.eu/CGU
 316       ''
 317       ]
 318     ;
 319   };
 320 }