nixops/modules/websites/commons/adminer.nix

   1 { stdenv, fetchurl, nginx }:
   2 let
   3   adminer = rec {
   4     webRoot = stdenv.mkDerivation rec {
   5       version = "4.7.0";
   6       name = "adminer-${version}";
   7       src = fetchurl {
   8         url = "https://www.adminer.org/static/download/${version}/${name}.php";
   9         sha256 = "1qq2g7rbfh2vrqfm3g0bz0qs057b049n0mhabnsbd1sgnpvnc5z7";
  10       };
  11       phases = "installPhase";
  12       installPhase = ''
  13         mkdir -p $out
  14         cp $src $out/index.php
  15       '';
  16     };
  17     phpFpm = rec {
  18       socket = "/var/run/phpfpm/adminer.sock";
  19       pool = ''
  20         listen = ${socket}
  21         user = ${apache.user}
  22         group = ${apache.group}
  23         listen.owner = ${apache.user}
  24         listen.group = ${apache.group}
  25         pm = ondemand
  26         pm.max_children = 5
  27         pm.process_idle_timeout = 60
  28         ;php_admin_flag[log_errors] = on
  29         ; Needed to avoid clashes in browser cookies (same domain)
  30         php_value[session.name] = AdminerPHPSESSID
  31         php_admin_value[open_basedir] = "${webRoot}:/tmp"
  32         php_admin_value[session.save_path] = "/var/lib/php/sessions/adminer"
  33         '';
  34     };
  35     apache = rec {
  36       user = "wwwrun";
  37       group = "wwwrun";
  38       modules = [ "proxy_fcgi" ];
  39       webappName = "_adminer";
  40       root = "/run/current-system/webapps/${webappName}";
  41       vhostConf = ''
  42         Alias /adminer ${root}
  43         <Directory ${root}>
  44           DirectoryIndex index.php
  45           Require all granted
  46           <FilesMatch "\.php$">
  47             SetHandler "proxy:unix:${phpFpm.socket}|fcgi://localhost"
  48           </FilesMatch>
  49         </Directory>
  50         '';
  51     };
  52     nginxConf = {
  53       alias = webRoot;
  54       index = "index.php";
  55       extraConfig = ''
  56         include ${nginx}/conf/fastcgi.conf;
  57         fastcgi_split_path_info ^(.+?\.php)(/.*)$;
  58         fastcgi_param HTTP_PROXY "";
  59         fastcgi_param SCRIPT_FILENAME ${webRoot}/index.php;
  60         fastcgi_pass unix:${phpFpm.socket};
  61         fastcgi_index index.php;
  62         fastcgi_intercept_errors on;
  63         '';
  64     };
  65   };
  66 in
  67   adminer