modules/private/websites/tools/tools/default.nix

   1 { lib, pkgs, config, ... }:
   2 let
   3   adminer = pkgs.callPackage ./adminer.nix {
   4     inherit (pkgs.webapps) adminer;
   5   };
   6   ympd = pkgs.callPackage ./ympd.nix {
   7     env = config.myEnv.tools.ympd;
   8   };
   9   ttrss = pkgs.callPackage ./ttrss.nix {
  10     inherit (pkgs.webapps) ttrss ttrss-plugins;
  11     env = config.myEnv.tools.ttrss;
  12   };
  13   kanboard = pkgs.callPackage ./kanboard.nix  {
  14     env = config.myEnv.tools.kanboard;
  15   };
  16   wallabag = pkgs.callPackage ./wallabag.nix {
  17     inherit (pkgs.webapps) wallabag;
  18     env = config.myEnv.tools.wallabag;
  19   };
  20   yourls = pkgs.callPackage ./yourls.nix {
  21     inherit (pkgs.webapps) yourls yourls-plugins;
  22     env = config.myEnv.tools.yourls;
  23   };
  24   rompr = pkgs.callPackage ./rompr.nix {
  25     inherit (pkgs.webapps) rompr;
  26     env = config.myEnv.tools.rompr;
  27   };
  28   shaarli = pkgs.callPackage ./shaarli.nix {
  29     env = config.myEnv.tools.shaarli;
  30   };
  31   dokuwiki = pkgs.callPackage ./dokuwiki.nix {
  32     inherit (pkgs.webapps) dokuwiki dokuwiki-plugins;
  33   };
  34   ldap = pkgs.callPackage ./ldap.nix {
  35     inherit (pkgs.webapps) phpldapadmin;
  36     env = config.myEnv.tools.phpldapadmin;
  37   };
  38
  39   cfg = config.myServices.websites.tools.tools;
  40 in {
  41   options.myServices.websites.tools.tools = {
  42     enable = lib.mkEnableOption "enable tools website";
  43   };
  44
  45   config = lib.mkIf cfg.enable {
  46     secrets.keys =
  47       kanboard.keys
  48       ++ ldap.keys
  49       ++ shaarli.keys
  50       ++ ttrss.keys
  51       ++ wallabag.keys
  52       ++ yourls.keys;
  53
  54     services.duplyBackup.profiles = {
  55       dokuwiki = dokuwiki.backups;
  56       kanboard = kanboard.backups;
  57       rompr = rompr.backups;
  58       shaarli = shaarli.backups;
  59       ttrss = ttrss.backups;
  60       wallabag = wallabag.backups;
  61     };
  62
  63     services.websites.env.tools.modules =
  64       [ "proxy_fcgi" ]
  65       ++ adminer.apache.modules
  66       ++ ympd.apache.modules
  67       ++ ttrss.apache.modules
  68       ++ wallabag.apache.modules
  69       ++ yourls.apache.modules
  70       ++ rompr.apache.modules
  71       ++ shaarli.apache.modules
  72       ++ dokuwiki.apache.modules
  73       ++ ldap.apache.modules
  74       ++ kanboard.apache.modules;
  75
  76     services.websites.env.integration.vhostConfs.devtools = {
  77       certName    = "eldiron";
  78       addToCerts  = true;
  79       hosts       = ["devtools.immae.eu" ];
  80       root        = "/var/lib/ftp/devtools.immae.eu";
  81       extraConfig = [
  82         ''
  83           <Directory "/var/lib/ftp/devtools.immae.eu">
  84             DirectoryIndex index.php index.htm index.html
  85             AllowOverride all
  86             Require all granted
  87             <FilesMatch "\.php$">
  88               SetHandler "proxy:unix:/var/run/phpfpm/devtools.sock|fcgi://localhost"
  89             </FilesMatch>
  90           </Directory>
  91           ''
  92       ];
  93     };
  94
  95     services.websites.env.tools.vhostConfs.tools = {
  96       certName    = "eldiron";
  97       addToCerts  = true;
  98       hosts       = ["tools.immae.eu" ];
  99       root        = "/var/lib/ftp/tools.immae.eu";
 100       extraConfig = [
 101         ''
 102           RedirectMatch 301 ^/roundcube(.*)$   https://mail.immae.eu/roundcube$1
 103
 104           <Directory "/var/lib/ftp/tools.immae.eu">
 105             DirectoryIndex index.php index.htm index.html
 106             AllowOverride all
 107             Require all granted
 108             <FilesMatch "\.php$">
 109               SetHandler "proxy:unix:/var/run/phpfpm/tools.sock|fcgi://localhost"
 110             </FilesMatch>
 111           </Directory>
 112           ''
 113         adminer.apache.vhostConf
 114         ympd.apache.vhostConf
 115         ttrss.apache.vhostConf
 116         wallabag.apache.vhostConf
 117         yourls.apache.vhostConf
 118         rompr.apache.vhostConf
 119         shaarli.apache.vhostConf
 120         dokuwiki.apache.vhostConf
 121         ldap.apache.vhostConf
 122         kanboard.apache.vhostConf
 123       ];
 124     };
 125
 126     services.websites.env.tools.vhostConfs.outils = {
 127       certName   = "eldiron";
 128       addToCerts = true;
 129       hosts      = [ "outils.immae.eu" ];
 130       root       = null;
 131       extraConfig = [
 132         ''
 133         RedirectMatch 301 ^/mediagoblin(.*)$ https://mgoblin.immae.eu$1
 134
 135         RedirectMatch 301 ^/ether(.*)$       https://ether.immae.eu$1
 136
 137         RedirectMatch 301 ^/nextcloud(.*)$   https://cloud.immae.eu$1
 138         RedirectMatch 301 ^/owncloud(.*)$    https://cloud.immae.eu$1
 139
 140         RedirectMatch 301 ^/carddavmate(.*)$ https://dav.immae.eu/infcloud$1
 141         RedirectMatch 301 ^/caldavzap(.*)$   https://dav.immae.eu/infcloud$1
 142         RedirectMatch 301 ^/caldav.php(.*)$  https://dav.immae.eu/caldav.php$1
 143         RedirectMatch 301 ^/davical(.*)$     https://dav.immae.eu/davical$1
 144
 145         RedirectMatch 301 ^/taskweb(.*)$     https://task.immae.eu/taskweb$1
 146
 147         RedirectMatch 301 ^/roundcube(.*)$   https://mail.immae.eu/roundcube$1
 148
 149         RedirectMatch 301 ^/(.*)$            https://tools.immae.eu/$1
 150         ''
 151       ];
 152     };
 153
 154     systemd.services = {
 155       phpfpm-dokuwiki = {
 156         after = lib.mkAfter dokuwiki.phpFpm.serviceDeps;
 157         wants = dokuwiki.phpFpm.serviceDeps;
 158       };
 159       phpfpm-kanboard = {
 160         after = lib.mkAfter kanboard.phpFpm.serviceDeps;
 161         wants = kanboard.phpFpm.serviceDeps;
 162       };
 163       phpfpm-ldap = {
 164         after = lib.mkAfter ldap.phpFpm.serviceDeps;
 165         wants = ldap.phpFpm.serviceDeps;
 166       };
 167       phpfpm-shaarli = {
 168         after = lib.mkAfter shaarli.phpFpm.serviceDeps;
 169         wants = shaarli.phpFpm.serviceDeps;
 170       };
 171       phpfpm-ttrss = {
 172         after = lib.mkAfter ttrss.phpFpm.serviceDeps;
 173         wants = ttrss.phpFpm.serviceDeps;
 174       };
 175       phpfpm-wallabag = {
 176         after = lib.mkAfter wallabag.phpFpm.serviceDeps;
 177         wants = wallabag.phpFpm.serviceDeps;
 178         preStart = lib.mkAfter wallabag.phpFpm.preStart;
 179       };
 180       phpfpm-yourls = {
 181         after = lib.mkAfter yourls.phpFpm.serviceDeps;
 182         wants = yourls.phpFpm.serviceDeps;
 183       };
 184       ympd = {
 185         description = "Standalone MPD Web GUI written in C";
 186         wantedBy = [ "multi-user.target" ];
 187         script = ''
 188           export MPD_PASSWORD=$(cat /var/secrets/mpd)
 189           ${pkgs.ympd}/bin/ympd --host ${ympd.config.host} --port ${toString ympd.config.port} --webport ${ympd.config.webPort} --user nobody
 190           '';
 191       };
 192       tt-rss = {
 193         description = "Tiny Tiny RSS feeds update daemon";
 194         serviceConfig = {
 195           User = "wwwrun";
 196           ExecStart = "${pkgs.php}/bin/php ${ttrss.webRoot}/update.php --daemon";
 197           StandardOutput = "syslog";
 198           StandardError = "syslog";
 199           PermissionsStartOnly = true;
 200         };
 201
 202         wantedBy = [ "multi-user.target" ];
 203         requires = ["postgresql.service"];
 204         after = ["network.target" "postgresql.service"];
 205       };
 206     };
 207
 208     services.filesWatcher.ympd = {
 209       restart = true;
 210       paths = [ "/var/secrets/mpd" ];
 211     };
 212
 213     services.phpfpm.pools.devtools = {
 214       listen = "/var/run/phpfpm/devtools.sock";
 215       extraConfig = ''
 216         user = wwwrun
 217         group = wwwrun
 218         listen.owner = wwwrun
 219         listen.group = wwwrun
 220         pm = dynamic
 221         pm.max_children = 60
 222         pm.start_servers = 2
 223         pm.min_spare_servers = 1
 224         pm.max_spare_servers = 10
 225
 226         php_admin_value[open_basedir] = "/run/wrappers/bin/sendmail:/var/lib/ftp/devtools.immae.eu:/tmp"
 227         '';
 228       phpOptions = config.services.phpfpm.phpOptions + ''
 229         extension=${pkgs.php}/lib/php/extensions/mysqli.so
 230         extension=${pkgs.phpPackages.redis}/lib/php/extensions/redis.so
 231         extension=${pkgs.phpPackages.apcu}/lib/php/extensions/apcu.so
 232         zend_extension=${pkgs.php}/lib/php/extensions/opcache.so
 233         '';
 234     };
 235
 236     services.phpfpm.poolConfigs = {
 237       adminer = adminer.phpFpm.pool;
 238       ttrss = ttrss.phpFpm.pool;
 239       wallabag = wallabag.phpFpm.pool;
 240       yourls = yourls.phpFpm.pool;
 241       rompr = rompr.phpFpm.pool;
 242       shaarli = shaarli.phpFpm.pool;
 243       dokuwiki = dokuwiki.phpFpm.pool;
 244       ldap = ldap.phpFpm.pool;
 245       kanboard = kanboard.phpFpm.pool;
 246       tools = ''
 247         listen = /var/run/phpfpm/tools.sock
 248         user = wwwrun
 249         group = wwwrun
 250         listen.owner = wwwrun
 251         listen.group = wwwrun
 252         pm = dynamic
 253         pm.max_children = 60
 254         pm.start_servers = 2
 255         pm.min_spare_servers = 1
 256         pm.max_spare_servers = 10
 257
 258         ; Needed to avoid clashes in browser cookies (same domain)
 259         php_value[session.name] = ToolsPHPSESSID
 260         php_admin_value[open_basedir] = "/run/wrappers/bin/sendmail:/var/lib/ftp/tools.immae.eu:/tmp"
 261         '';
 262     };
 263
 264     system.activationScripts = {
 265       adminer = adminer.activationScript;
 266       ttrss = ttrss.activationScript;
 267       wallabag = wallabag.activationScript;
 268       yourls = yourls.activationScript;
 269       rompr = rompr.activationScript;
 270       shaarli = shaarli.activationScript;
 271       dokuwiki = dokuwiki.activationScript;
 272       kanboard = kanboard.activationScript;
 273       ldap = ldap.activationScript;
 274     };
 275
 276     myServices.websites.webappDirs = {
 277       _adminer = adminer.webRoot;
 278       "${dokuwiki.apache.webappName}" = dokuwiki.webRoot;
 279       "${ldap.apache.webappName}" = "${ldap.webRoot}/htdocs";
 280       "${rompr.apache.webappName}" = rompr.webRoot;
 281       "${shaarli.apache.webappName}" = shaarli.webRoot;
 282       "${ttrss.apache.webappName}" = ttrss.webRoot;
 283       "${wallabag.apache.webappName}" = wallabag.webRoot;
 284       "${yourls.apache.webappName}" = yourls.webRoot;
 285       "${kanboard.apache.webappName}" = kanboard.webRoot;
 286     };
 287
 288     services.websites.env.tools.watchPaths = [
 289       "/var/secrets/webapps/tools-shaarli"
 290     ];
 291     services.filesWatcher.phpfpm-wallabag = {
 292       restart = true;
 293       paths = [ "/var/secrets/webapps/tools-wallabag" ];
 294     };
 295   };
 296 }
 297