modules/private/websites/tools/cloud/default.nix

   1 { lib, pkgs, config,  ... }:
   2 let
   3   nextcloud = pkgs.webapps.nextcloud.withApps (builtins.attrValues pkgs.webapps.nextcloud-apps);
   4   env = config.myEnv.tools.nextcloud;
   5   varDir = "/var/lib/nextcloud";
   6   webappName = "tools_nextcloud";
   7   apacheRoot = "/run/current-system/webapps/${webappName}";
   8   cfg = config.myServices.websites.tools.cloud;
   9   phpFpm = rec {
  10     basedir = builtins.concatStringsSep ":" (
  11       [ nextcloud varDir ]
  12       ++ builtins.attrValues pkgs.webapps.nextcloud-apps);
  13     socket = "/var/run/phpfpm/nextcloud.sock";
  14     phpConfig = ''
  15       extension=${pkgs.phpPackages.redis}/lib/php/extensions/redis.so
  16       extension=${pkgs.phpPackages.apcu}/lib/php/extensions/apcu.so
  17       zend_extension=${pkgs.php}/lib/php/extensions/opcache.so
  18       '';
  19     pool = ''
  20       user = wwwrun
  21       group = wwwrun
  22       listen.owner = wwwrun
  23       listen.group = wwwrun
  24       pm = ondemand
  25       pm.max_children = 60
  26       pm.process_idle_timeout = 60
  27
  28       php_admin_value[output_buffering] = 0
  29       php_admin_value[max_execution_time] = 1800
  30       php_admin_value[zend_extension] = "opcache"
  31       ;already enabled by default?
  32       ;php_value[opcache.enable] = 1
  33       php_value[opcache.enable_cli] = 1
  34       php_value[opcache.interned_strings_buffer] = 8
  35       php_value[opcache.max_accelerated_files] = 10000
  36       php_value[opcache.memory_consumption] = 128
  37       php_value[opcache.save_comments] = 1
  38       php_value[opcache.revalidate_freq] = 1
  39       php_admin_value[memory_limit] = 512M
  40
  41       php_admin_value[open_basedir] = "/run/wrappers/bin/sendmail:${basedir}:/proc/meminfo:/dev/urandom:/proc/self/fd:/tmp"
  42       php_admin_value[session.save_path] = "${varDir}/phpSessions"
  43       '';
  44   };
  45 in {
  46   options.myServices.websites.tools.cloud = {
  47     enable = lib.mkEnableOption "enable cloud website";
  48   };
  49
  50   config = lib.mkIf cfg.enable {
  51     # FIXME: find a way to backup the data
  52     services.websites.env.tools.modules = [ "proxy_fcgi" ];
  53
  54     services.websites.env.tools.vhostConfs.cloud = {
  55       certName    = "eldiron";
  56       addToCerts  = true;
  57       hosts       = ["cloud.immae.eu" ];
  58       root        = apacheRoot;
  59       extraConfig = [
  60         ''
  61           SetEnvIf Authorization "(.*)" HTTP_AUTHORIZATION=$1
  62           <Directory ${apacheRoot}>
  63             AcceptPathInfo On
  64             DirectoryIndex index.php
  65             Options FollowSymlinks
  66             Require all granted
  67             AllowOverride all
  68
  69             <IfModule mod_headers.c>
  70               Header always set Strict-Transport-Security "max-age=15552000; includeSubDomains; preload"
  71             </IfModule>
  72             <FilesMatch "\.php$">
  73               CGIPassAuth on
  74               SetHandler "proxy:unix:${phpFpm.socket}|fcgi://localhost"
  75             </FilesMatch>
  76
  77           </Directory>
  78         ''
  79       ];
  80     };
  81
  82     secrets.keys = [{
  83       dest = "webapps/tools-nextcloud";
  84       user = "wwwrun";
  85       group = "wwwrun";
  86       permissions = "0600";
  87       text = ''
  88         <?php
  89         $CONFIG = array (
  90           // FIXME: change this value when nextcloud starts getting slow
  91           'instanceid' => '${env.instance_id}1',
  92           'datadirectory' => '/var/lib/nextcloud/',
  93           'passwordsalt' => '${env.password_salt}',
  94           'debug' => false,
  95           'dbtype' => 'pgsql',
  96           'version' => '16.0.0.9',
  97           'dbname' => '${env.postgresql.database}',
  98           'dbhost' => '${env.postgresql.socket}',
  99           'dbtableprefix' => 'oc_',
 100           'dbuser' => '${env.postgresql.user}',
 101           'dbpassword' => '${env.postgresql.password}',
 102           'installed' => true,
 103           'maxZipInputSize' => 0,
 104           'allowZipDownload' => true,
 105           'forcessl' => true,
 106           'theme' => ${"''"},
 107           'maintenance' => false,
 108           'trusted_domains' =>
 109           array (
 110             0 => 'cloud.immae.eu',
 111           ),
 112           'secret' => '${env.secret}',
 113           'appstoreenabled' => false,
 114           'appstore.experimental.enabled' => true,
 115           'loglevel' => 2,
 116           'trashbin_retention_obligation' => 'auto',
 117           'htaccess.RewriteBase' => '/',
 118           'mail_smtpmode' => 'sendmail',
 119           'mail_smtphost' => '127.0.0.1',
 120           'mail_smtpname' => ''',
 121           'mail_smtppassword' => ''',
 122           'mail_from_address' => 'nextcloud',
 123           'mail_smtpauth' => false,
 124           'mail_domain' => 'tools.immae.eu',
 125           'memcache.local' => '\\OC\\Memcache\\APCu',
 126           'memcache.locking' => '\\OC\\Memcache\\Redis',
 127           'filelocking.enabled' => true,
 128           'redis' =>
 129           array (
 130             'host' => '${env.redis.socket}',
 131             'port' => 0,
 132             'dbindex' => ${env.redis.db},
 133           ),
 134           'overwrite.cli.url' => 'https://cloud.immae.eu',
 135           'ldapIgnoreNamingRules' => false,
 136           'ldapProviderFactory' => '\\OCA\\User_LDAP\\LDAPProviderFactory',
 137           'has_rebuilt_cache' => true,
 138         );
 139       '';
 140     }];
 141     users.users.root.packages = let
 142       occ = pkgs.writeScriptBin "nextcloud-occ" ''
 143         #! ${pkgs.stdenv.shell}
 144         cd ${nextcloud}
 145         NEXTCLOUD_CONFIG_DIR="${nextcloud}/config" \
 146           exec \
 147           sudo -u wwwrun ${pkgs.php}/bin/php \
 148           -c ${pkgs.php}/etc/php.ini \
 149           occ $*
 150         '';
 151     in [ occ ];
 152
 153     system.activationScripts.nextcloud = {
 154       deps = [ "secrets" ];
 155       text = let
 156         confs = lib.attrsets.mapAttrs (n: v: pkgs.writeText "${n}.json" (builtins.toJSON v)) nextcloud.otherConfig;
 157       in
 158         ''
 159         install -m 0755 -o wwwrun -g wwwrun -d ${varDir}
 160         install -m 0750 -o wwwrun -g wwwrun -d ${varDir}/phpSessions
 161         ${builtins.concatStringsSep "\n" (lib.attrsets.mapAttrsToList (n: v:
 162           "install -D -m 0644 -o wwwrun -g wwwrun -T ${v} ${varDir}/config/${n}.json"
 163           ) confs)}
 164         install -D -m 0600 -o wwwrun -g wwwrun -T /var/secrets/webapps/tools-nextcloud ${varDir}/config/config.php
 165       '';
 166     };
 167     # FIXME: add a warning when config.php changes
 168     system.extraSystemBuilderCmds = ''
 169       mkdir -p $out/webapps
 170       ln -s ${nextcloud} $out/webapps/${webappName}
 171       '';
 172
 173     services.phpfpm.pools.nextcloud = {
 174       listen = phpFpm.socket;
 175       extraConfig = phpFpm.pool;
 176       phpOptions = config.services.phpfpm.phpOptions + phpFpm.phpConfig;
 177     };
 178
 179     services.cron = {
 180       enable = true;
 181       systemCronJobs = let
 182         script = pkgs.writeScriptBin "nextcloud-cron" ''
 183           #! ${pkgs.stdenv.shell}
 184           export LOCALE_ARCHIVE=/run/current-system/sw/lib/locale/locale-archive
 185           export PATH=/run/wrappers/bin:$PATH
 186           ${pkgs.php}/bin/php -d memory_limit=512M -f ${nextcloud}/cron.php
 187           '';
 188       in [
 189         ''
 190           */15 * * * * wwwrun ${script}/bin/nextcloud-cron
 191         ''
 192       ];
 193     };
 194   };
 195 }