modules/private/buildbot/default.nix

   1 { lib, pkgs, config, ... }:
   2 let
   3   varDir = "/var/lib/buildbot";
   4   buildbot_common = pkgs.python3Packages.buildPythonPackage rec {
   5     name = "buildbot_common";
   6     src = ./common;
   7     format = "other";
   8     installPhase = ''
   9       mkdir -p $out/${pkgs.python3.pythonForBuild.sitePackages}
  10       cp -a $src $out/${pkgs.python3.pythonForBuild.sitePackages}/buildbot_common
  11       '';
  12   };
  13   buildbot = pkgs.python3Packages.buildbot-full;
  14 in
  15 {
  16   options = {
  17     myServices.buildbot.enable = lib.mkOption {
  18       type = lib.types.bool;
  19       default = false;
  20       description = ''
  21         Whether to enable buildbot.
  22       '';
  23     };
  24   };
  25
  26   config = lib.mkIf config.myServices.buildbot.enable {
  27     services.duplyBackup.profiles.buildbot = {
  28       rootDir = varDir;
  29       remotes = [ "eriomem" "ovh" ];
  30     };
  31     ids.uids.buildbot = config.myEnv.buildbot.user.uid;
  32     ids.gids.buildbot = config.myEnv.buildbot.user.gid;
  33
  34     users.groups.buildbot.gid = config.ids.gids.buildbot;
  35     users.users.buildbot = {
  36       name = "buildbot";
  37       uid = config.ids.uids.buildbot;
  38       group = "buildbot";
  39       description = "Buildbot user";
  40       home = varDir;
  41       extraGroups = [ "keys" ];
  42     };
  43
  44     services.websites.env.tools.watchPaths = lib.attrsets.mapAttrsToList
  45       (k: project: "/var/secrets/buildbot/${project.name}/webhook-httpd-include")
  46       config.myEnv.buildbot.projects;
  47
  48     services.websites.env.tools.vhostConfs.git.extraConfig = lib.attrsets.mapAttrsToList (k: project: ''
  49         RedirectMatch permanent "^/buildbot/${project.name}$" "/buildbot/${project.name}/"
  50         RewriteEngine On
  51         RewriteRule ^/buildbot/${project.name}/ws(.*)$   unix:///run/buildbot/${project.name}.sock|ws://git.immae.eu/ws$1 [P,NE,QSA,L]
  52         ProxyPass /buildbot/${project.name}/             unix:///run/buildbot/${project.name}.sock|http://${project.name}-git.immae.eu/
  53         ProxyPassReverse /buildbot/${project.name}/      unix:///run/buildbot/${project.name}.sock|http://${project.name}-git.immae.eu/
  54         <Location /buildbot/${project.name}/>
  55           Use LDAPConnect
  56           Require ldap-group cn=users,ou=${project.name},cn=buildbot,ou=services,dc=immae,dc=eu
  57
  58           SetEnvIf X-Url-Scheme https HTTPS=1
  59           ProxyPreserveHost On
  60         </Location>
  61         <Location /buildbot/${project.name}/change_hook/base>
  62           <RequireAny>
  63             Require local
  64             Require ldap-group cn=users,ou=${project.name},cn=buildbot,ou=services,dc=immae,dc=eu
  65             Include /var/secrets/buildbot/${project.name}/webhook-httpd-include
  66           </RequireAny>
  67         </Location>
  68         '') config.myEnv.buildbot.projects;
  69
  70     system.activationScripts = lib.attrsets.mapAttrs' (k: project: lib.attrsets.nameValuePair "buildbot-${project.name}" {
  71       deps = [ "users" "wrappers" ];
  72       text = ''
  73         install -m 755 -o buildbot -g buildbot -d ${varDir}/${project.name}
  74
  75         ${project.activationScript}
  76         '';
  77     }) config.myEnv.buildbot.projects;
  78
  79     secrets.keys = (
  80       lib.lists.flatten (
  81         lib.attrsets.mapAttrsToList (k: project:
  82           lib.attrsets.mapAttrsToList (k: v:
  83             {
  84               permissions = "0600";
  85               user = "buildbot";
  86               group = "buildbot";
  87               text = v;
  88               dest = "buildbot/${project.name}/${k}";
  89             }
  90           ) project.secrets
  91           ++ [
  92             {
  93               permissions = "0600";
  94               user = "wwwrun";
  95               group = "wwwrun";
  96               text = lib.optionalString (project.webhookTokens != null) ''
  97                 Require expr "req('Access-Key') in { ${builtins.concatStringsSep ", " (map (x: "'${x}'") project.webhookTokens)} }"
  98                 '';
  99               dest = "buildbot/${project.name}/webhook-httpd-include";
 100             }
 101             {
 102               permissions = "0600";
 103               user = "buildbot";
 104               group = "buildbot";
 105               dest = "buildbot/${project.name}/environment_file";
 106               text = let
 107                 project_env = with lib.attrsets;
 108                   mapAttrs' (k: v: nameValuePair "BUILDBOT_${k}" v) project.environment //
 109                   mapAttrs' (k: v: nameValuePair "BUILDBOT_PATH_${k}" (v pkgs)) (attrByPath ["builderPaths"] {} project) //
 110                   { BUILDBOT_PROJECT_DIR = ./projects + "/${project.name}"; };
 111                 in builtins.concatStringsSep "\n"
 112                   (lib.mapAttrsToList (envK: envV: "${envK}=${envV}") project_env);
 113             }
 114           ]
 115         ) config.myEnv.buildbot.projects
 116       )
 117     ) ++ [
 118       {
 119         permissions = "0600";
 120         user = "buildbot";
 121         group = "buildbot";
 122         text = config.myEnv.buildbot.ldap.password;
 123         dest = "buildbot/ldap";
 124       }
 125       {
 126         permissions = "0600";
 127         user = "buildbot";
 128         group = "buildbot";
 129         text = builtins.readFile "${config.myEnv.privateFiles}/buildbot_ssh_key";
 130         dest = "buildbot/ssh_key";
 131       }
 132     ];
 133
 134     services.filesWatcher = lib.attrsets.mapAttrs' (k: project: lib.attrsets.nameValuePair "buildbot-${project.name}" {
 135       restart = true;
 136       paths = [
 137         "/var/secrets/buildbot/ldap"
 138         "/var/secrets/buildbot/ssh_key"
 139         "/var/secrets/buildbot/${project.name}/environment_file"
 140       ] ++ lib.attrsets.mapAttrsToList (k: v: "/var/secrets/buildbot/${project.name}/${k}") project.secrets;
 141     }) config.myEnv.buildbot.projects;
 142
 143     systemd.slices.buildbot = {
 144       description = "buildbot slice";
 145     };
 146
 147     systemd.services = lib.attrsets.mapAttrs' (k: project: lib.attrsets.nameValuePair "buildbot-${project.name}" {
 148       description = "Buildbot Continuous Integration Server ${project.name}.";
 149       after = [ "network-online.target" ];
 150       wantedBy = [ "multi-user.target" ];
 151       path = project.packages pkgs ++ (project.pythonPackages buildbot.pythonModule pkgs);
 152       preStart = let
 153         master-cfg = "${buildbot_common}/${pkgs.python3.pythonForBuild.sitePackages}/buildbot_common/master.cfg";
 154         tac_file = pkgs.writeText "buildbot.tac" ''
 155             import os
 156
 157             from twisted.application import service
 158             from buildbot.master import BuildMaster
 159
 160             basedir = '${varDir}/${project.name}'
 161             rotateLength = 10000000
 162             maxRotatedFiles = 10
 163             configfile = '${master-cfg}'
 164
 165             # Default umask for server
 166             umask = None
 167
 168             # if this is a relocatable tac file, get the directory containing the TAC
 169             if basedir == '.':
 170                 import os
 171                 basedir = os.path.abspath(os.path.dirname(__file__))
 172
 173             # note: this line is matched against to check that this is a buildmaster
 174             # directory; do not edit it.
 175             application = service.Application('buildmaster')
 176             from twisted.python.logfile import LogFile
 177             from twisted.python.log import ILogObserver, FileLogObserver
 178             logfile = LogFile.fromFullPath(os.path.join(basedir, "twistd.log"), rotateLength=rotateLength,
 179                                             maxRotatedFiles=maxRotatedFiles)
 180             application.setComponent(ILogObserver, FileLogObserver(logfile).emit)
 181
 182             m = BuildMaster(basedir, configfile, umask)
 183             m.setServiceParent(application)
 184             m.log_rotation.rotateLength = rotateLength
 185             m.log_rotation.maxRotatedFiles = maxRotatedFiles
 186           '';
 187       in ''
 188       if [ ! -f ${varDir}/${project.name}/buildbot.tac ]; then
 189         ${buildbot}/bin/buildbot create-master -c "${master-cfg}" "${varDir}/${project.name}"
 190         rm -f ${varDir}/${project.name}/master.cfg.sample
 191         rm -f ${varDir}/${project.name}/buildbot.tac
 192       fi
 193       ln -sf ${tac_file} ${varDir}/${project.name}/buildbot.tac
 194       # different buildbots may be trying that simultaneously, add the || true to avoid complaining in case of race
 195       install -Dm600 -o buildbot -g buildbot -T /var/secrets/buildbot/ssh_key ${varDir}/buildbot_key || true
 196       buildbot_secrets=${varDir}/${project.name}/secrets
 197       install -m 0700 -o buildbot -g buildbot -d $buildbot_secrets
 198       install -Dm600 -o buildbot -g buildbot -T /var/secrets/buildbot/ldap $buildbot_secrets/ldap
 199       ${builtins.concatStringsSep "\n" (lib.attrsets.mapAttrsToList
 200         (k: v: "install -Dm600 -o buildbot -g buildbot -T /var/secrets/buildbot/${project.name}/${k} $buildbot_secrets/${k}") project.secrets
 201       )}
 202       ${buildbot}/bin/buildbot upgrade-master ${varDir}/${project.name}
 203       '';
 204       environment = let
 205         buildbot_config = pkgs.python3Packages.buildPythonPackage (rec {
 206           name = "buildbot_config-${project.name}";
 207           src = ./projects + "/${project.name}";
 208           format = "other";
 209           installPhase = ''
 210             mkdir -p $out/${pkgs.python3.pythonForBuild.sitePackages}
 211             cp -a $src $out/${pkgs.python3.pythonForBuild.sitePackages}/buildbot_config
 212             '';
 213         });
 214         HOME = "${varDir}/${project.name}";
 215         PYTHONPATH = "${buildbot.pythonModule.withPackages (self: project.pythonPackages self pkgs ++ [
 216           pkgs.python3Packages.wokkel
 217           pkgs.python3Packages.treq pkgs.python3Packages.ldap3 buildbot
 218           pkgs.python3Packages.buildbot-worker
 219           buildbot_common buildbot_config
 220         ])}/${buildbot.pythonModule.sitePackages}${if project.pythonPathHome then ":${varDir}/${project.name}/.local/${pkgs.python3.pythonForBuild.sitePackages}" else ""}";
 221       in { inherit PYTHONPATH HOME; };
 222
 223       serviceConfig = {
 224         Slice = "buildbot.slice";
 225         Type = "forking";
 226         User = "buildbot";
 227         Group = "buildbot";
 228         RuntimeDirectory = "buildbot";
 229         RuntimeDirectoryPreserve = "yes";
 230         StateDirectory = "buildbot";
 231         SupplementaryGroups = "keys";
 232         WorkingDirectory = "${varDir}/${project.name}";
 233         ExecStart = "${buildbot}/bin/buildbot start";
 234         EnvironmentFile = "/var/secrets/buildbot/${project.name}/environment_file";
 235       };
 236     }) config.myEnv.buildbot.projects;
 237   };
 238 }