Move websites to their own modules: php config and scripts

[perso/Immae/Config/Nix.git] / virtual / modules / websites / ludivine.nix

{ lib, pkgs, config, mylibs, ... }:
let
    ludivinecassal = pkgs.callPackage ../../packages/ludivinecassal.nix { inherit (mylibs) checkEnv fetchedGitPrivate; };
    ludivinecassal_dev  = ludivinecassal { environment = "dev"; };
    ludivinecassal_prod = ludivinecassal { environment = "prod"; };

    cfg = config.services.myWebsites.Ludivine;
in {
  options.services.myWebsites.Ludivine = {
    production = {
      enable = lib.mkEnableOption "enable Ludivine's website in production";
    };
    integration = {
      enable = lib.mkEnableOption "enable Ludivine's website in integration";
    };
  };

  config = lib.mkMerge [
    (lib.mkIf cfg.production.enable {
      security.acme.certs."ludivinecassal" = config.services.myCertificates.certConfig // {
        domain = "ludivinecassal.com";
        extraDomains = {
          "www.ludivinecassal.com" = null;
        };
      };

      services.phpfpm.poolConfigs.ludivinecassal_prod = ludivinecassal_prod.phpFpm.pool;
      system.activationScripts.ludivinecassal_prod = ludivinecassal_prod.activationScript;
    })
    (lib.mkIf cfg.integration.enable {
      security.acme.certs."eldiron".extraDomains."ludivine.immae.eu" = null;

      services.phpfpm.poolConfigs.ludivinecassal_dev = ludivinecassal_dev.phpFpm.pool;
      system.activationScripts.ludivinecassal_dev = ludivinecassal_dev.activationScript;
    })
  ];
}