Add certificate creation and handling to websites

[perso/Immae/Config/Nix.git] / nixops / modules / websites / piedsjaloux / default.nix

{ lib, pkgs, config, myconfig,  ... }:
let
  piedsjaloux_dev  = pkgs.callPackage ./piedsjaloux.nix {
    inherit (pkgs.webapps) piedsjaloux;
    config = myconfig.env.websites.piedsjaloux.integration;
  };
  piedsjaloux_prod = pkgs.callPackage ./piedsjaloux.nix {
    inherit (pkgs.webapps) piedsjaloux;
    config = myconfig.env.websites.piedsjaloux.production;
  };

  cfg = config.services.myWebsites.PiedsJaloux;
in {
  options.services.myWebsites.PiedsJaloux = {
    production = {
      enable = lib.mkEnableOption "enable PiedsJaloux's website in production";
    };
    integration = {
      enable = lib.mkEnableOption "enable PiedsJaloux's website in integration";
    };
  };

  config = lib.mkMerge [
    (lib.mkIf cfg.production.enable {
      secrets.keys = piedsjaloux_prod.keys;
      services.webstats.sites = [ { name = "piedsjaloux.fr"; } ];

      services.myPhpfpm.preStart.piedsjaloux_prod = piedsjaloux_prod.phpFpm.preStart;
      services.myPhpfpm.serviceDependencies.piedsjaloux_prod = piedsjaloux_prod.phpFpm.serviceDeps;
      services.myPhpfpm.poolConfigs.piedsjaloux_prod = piedsjaloux_prod.phpFpm.pool;
      system.activationScripts.piedsjaloux_prod = piedsjaloux_prod.activationScript;
      system.extraSystemBuilderCmds = ''
        mkdir -p $out/webapps
        ln -s ${piedsjaloux_prod.app.webRoot} $out/webapps/${piedsjaloux_prod.apache.webappName}
        '';
      services.websites.production.modules = piedsjaloux_prod.apache.modules;
      services.websites.production.vhostConfs.piedsjaloux = {
        certName     = "piedsjaloux";
        certMainHost = "piedsjaloux.fr";
        hosts        = [ "piedsjaloux.fr" "www.piedsjaloux.fr" ];
        root         = piedsjaloux_prod.apache.root;
        extraConfig  = [ piedsjaloux_prod.apache.vhostConf ];
      };
    })
    (lib.mkIf cfg.integration.enable {
      secrets.keys = piedsjaloux_dev.keys;
      services.myPhpfpm.preStart.piedsjaloux_dev = piedsjaloux_dev.phpFpm.preStart;
      services.myPhpfpm.serviceDependencies.piedsjaloux_dev = piedsjaloux_dev.phpFpm.serviceDeps;
      services.myPhpfpm.poolConfigs.piedsjaloux_dev = piedsjaloux_dev.phpFpm.pool;
      system.activationScripts.piedsjaloux_dev = piedsjaloux_dev.activationScript;
      system.extraSystemBuilderCmds = ''
        mkdir -p $out/webapps
        ln -s ${piedsjaloux_dev.app.webRoot} $out/webapps/${piedsjaloux_dev.apache.webappName}
        '';
      services.websites.integration.modules = piedsjaloux_dev.apache.modules;
      services.websites.integration.vhostConfs.piedsjaloux = {
        certName    = "eldiron";
        addToCerts  = true;
        hosts       = [ "piedsjaloux.immae.eu" ];
        root        = piedsjaloux_dev.apache.root;
        extraConfig = [ piedsjaloux_dev.apache.vhostConf ];
      };
    })
  ];
}