Remove direct dependency to myconfig in database modules

[perso/Immae/Config/Nix.git] / nixops / modules / websites / connexionswing / default.nix

{ lib, pkgs, config,  myconfig, ... }:
let
  connexionswing_dev  = pkgs.callPackage ./connexionswing.nix {
    inherit (pkgs.webapps) connexionswing;
    config = myconfig.env.websites.connexionswing.integration;
  };
  connexionswing_prod = pkgs.callPackage ./connexionswing.nix {
    inherit (pkgs.webapps) connexionswing;
    config = myconfig.env.websites.connexionswing.production;
  };

  cfg = config.services.myWebsites.Connexionswing;
in {
  options.services.myWebsites.Connexionswing = {
    production = {
      enable = lib.mkEnableOption "enable Connexionswing's website in production";
    };
    integration = {
      enable = lib.mkEnableOption "enable Connexionswing's website in integration";
    };
  };

  config = lib.mkMerge [
    (lib.mkIf cfg.production.enable {
      secrets.keys = connexionswing_prod.keys;
      services.webstats.sites = [ { name = "connexionswing.com"; } ];

      services.myPhpfpm.preStart.connexionswing_prod = connexionswing_prod.phpFpm.preStart;
      services.myPhpfpm.serviceDependencies.connexionswing_prod = connexionswing_prod.phpFpm.serviceDeps;
      services.myPhpfpm.poolConfigs.connexionswing_prod = connexionswing_prod.phpFpm.pool;
      services.myPhpfpm.poolPhpConfigs.connexionswing_prod = connexionswing_prod.phpFpm.phpConfig;
      system.activationScripts.connexionswing_prod = connexionswing_prod.activationScript;
      system.extraSystemBuilderCmds = ''
        mkdir -p $out/webapps
        ln -s ${connexionswing_prod.app.webRoot} $out/webapps/${connexionswing_prod.apache.webappName}
        '';
      services.websites.production.modules = connexionswing_prod.apache.modules;
      services.websites.production.vhostConfs.connexionswing = {
        certName     = "connexionswing";
        certMainHost = "connexionswing.com";
        hosts        = ["connexionswing.com" "sandetludo.com" "www.connexionswing.com" "www.sandetludo.com" ];
        root         = connexionswing_prod.apache.root;
        extraConfig  = [ connexionswing_prod.apache.vhostConf ];
      };
    })
    (lib.mkIf cfg.integration.enable {
      secrets.keys = connexionswing_dev.keys;
      services.myPhpfpm.preStart.connexionswing_dev = connexionswing_dev.phpFpm.preStart;
      services.myPhpfpm.serviceDependencies.connexionswing_dev = connexionswing_dev.phpFpm.serviceDeps;
      services.myPhpfpm.poolConfigs.connexionswing_dev = connexionswing_dev.phpFpm.pool;
      services.myPhpfpm.poolPhpConfigs.connexionswing_dev = connexionswing_dev.phpFpm.phpConfig;
      system.activationScripts.connexionswing_dev = connexionswing_dev.activationScript;
      system.extraSystemBuilderCmds = ''
        mkdir -p $out/webapps
        ln -s ${connexionswing_dev.app.webRoot} $out/webapps/${connexionswing_dev.apache.webappName}
        '';
      services.websites.integration.modules = connexionswing_dev.apache.modules;
      services.websites.integration.vhostConfs.connexionswing = {
        certName    = "eldiron";
        addToCerts  = true;
        hosts       = ["connexionswing.immae.eu" "sandetludo.immae.eu" ];
        root        = connexionswing_dev.apache.root;
        extraConfig = [ connexionswing_dev.apache.vhostConf ];
      };
    })
  ];
}