Upgrade nixos

[perso/Immae/Config/Nix.git] / modules / private / websites / teliotortay / production.nix

{ lib, pkgs, config,  ... }:
let
  adminer = pkgs.callPackage ../commons/adminer.nix { inherit config; };
  cfg = config.myServices.websites.telioTortay.production;
  varDir = "/var/lib/ftp/telio_tortay";
  env = config.myEnv.websites.telioTortay;
in {
  options.myServices.websites.telioTortay.production.enable = lib.mkEnableOption "enable Telio Tortay's website";

  config = lib.mkIf cfg.enable {
    services.webstats.sites = [ { name = "telio-tortay.immae.eu"; } ];

    security.acme.certs."ftp".extraDomains."telio-tortay.immae.eu" = null;

    system.activationScripts.telio-tortay = {
      deps = [ "httpd" ];
      text = ''
        install -m 0755 -o wwwrun -g wwwrun -d /var/lib/ftp/telio_tortay/logs
        install -m 0755 -o wwwrun -g wwwrun -d /var/lib/php/sessions/telio-tortay
        '';
    };
    systemd.services.phpfpm-telio-tortay.after = lib.mkAfter [ "mysql.service" ];
    systemd.services.phpfpm-telio-tortay.wants = [ "mysql.service" ];
    services.phpfpm.pools.telio-tortay = {
      user = "wwwrun";
      group = "wwwrun";
      settings = {
        "listen.owner" = "wwwrun";
        "listen.group" = "wwwrun";

        "pm" = "ondemand";
        "pm.max_children" = "5";
        "pm.process_idle_timeout" = "60";

        "php_admin_value[open_basedir]" = "/var/lib/php/sessions/telio-tortay:${varDir}:/tmp";
        "php_admin_value[session.save_path]" = "/var/lib/php/sessions/telio-tortay";
      };
      phpOptions = config.services.phpfpm.phpOptions + ''
        disable_functions = "mail"
        extension=${pkgs.php}/lib/php/extensions/mysqli.so
        '';
    };
    services.websites.env.production.modules = adminer.apache.modules ++ [ "proxy_fcgi" ];
    services.websites.env.production.vhostConfs.telio-tortay = {
      certName     = "telio-tortay";
      certMainHost = "telio-tortay.immae.eu";
      hosts        = ["telio-tortay.immae.eu" "realistesmedia.fr" "www.realistesmedia.fr" ];
      root         = varDir;
      extraConfig  = [
        (adminer.apache.vhostConf null)
        ''
        Use Stats telio-tortay.immae.eu
        ServerAdmin ${env.server_admin}
        ErrorLog "${varDir}/logs/error_log"
        CustomLog "${varDir}/logs/access_log" combined

        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${config.services.phpfpm.pools.telio-tortay.socket}|fcgi://localhost"
        </FilesMatch>

        <Directory ${varDir}/logs>
          AllowOverride None
          Require all denied
        </Directory>
        <Directory ${varDir}>
          DirectoryIndex index.php index.htm index.html
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride all
          Require all granted
        </Directory>
          ''
      ];
    };
  };
}