Remove overlay that overrides the php version

[perso/Immae/Config/Nix.git] / modules / private / websites / connexionswing / production.nix

{ lib, pkgs, config,  ... }:
let
  secrets = config.myEnv.websites.connexionswing.production;
  app = pkgs.callPackage ./app {
    composerEnv = pkgs.composerEnv.override { php = pkgs.php72; };
    environment = secrets.environment;
    varDir = "/var/lib/connexionswing_production";
    secretsPath = config.secrets.fullPaths."websites/connexionswing/production";
  };
  cfg = config.myServices.websites.connexionswing.production;
  pcfg = config.services.phpApplication;
in {
  options.myServices.websites.connexionswing.production.enable = lib.mkEnableOption "enable Connexionswing's website in production";

  config = lib.mkIf cfg.enable {
    services.duplyBackup.profiles.connexionswing_produdction.rootDir = app.varDir;
    services.webstats.sites = [ { name = "connexionswing.com"; } ];
    services.phpApplication.apps.connexionswing_production = {
      websiteEnv = "production";
      httpdUser = config.services.httpd.Prod.user;
      httpdGroup = config.services.httpd.Prod.group;
      inherit (app) webRoot varDir;
      varDirPaths = {
        "medias" = "0700";
        "uploads" = "0700";
        "var" = "0700";
      };
      inherit app;
      serviceDeps = [ "mysql.service" ];
      preStartActions = [
        "./bin/console --env=${app.environment} cache:clear --no-warmup"
      ];
      phpOpenbasedir = [ "/tmp" "/run/wrappers/bin/sendmail" ];
      phpPool = {
        "php_admin_value[upload_max_filesize]" = "20M";
        "php_admin_value[post_max_size]" = "20M";
        #"php_admin_flag[log_errors]" = "on";
        "pm" = "dynamic";
        "pm.max_children" = "20";
        "pm.start_servers" = "2";
        "pm.min_spare_servers" = "1";
        "pm.max_spare_servers" = "3";
      };
      phpWatchFiles = [
        config.secrets.fullPaths."websites/connexionswing/production"
      ];
      phpPackage = pkgs.php72;
    };

    secrets.keys = [
      {
        dest = "websites/connexionswing/production";
        user = config.services.httpd.Prod.user;
        group = config.services.httpd.Prod.group;
        permissions = "0400";
        text = ''
          # This file is auto-generated during the composer install
          parameters:
              database_host: ${secrets.mysql.host}
              database_port: ${secrets.mysql.port}
              database_name: ${secrets.mysql.database}
              database_user: ${secrets.mysql.user}
              database_password: ${secrets.mysql.password}
              database_server_version: ${pkgs.mariadb.mysqlVersion}
              mailer_transport: sendmail
              mailer_host: null
              mailer_user: null
              mailer_password: null
              subscription_email: ${secrets.email}
              allow_robots: true
              secret: ${secrets.secret}
          services:
            swiftmailer.mailer.default.transport:
                class:     Swift_SendmailTransport
                arguments: ['/run/wrappers/bin/sendmail -bs']
        '';
      }
    ];

    services.websites.env.production.vhostConfs.connexionswing_production = {
      certName     = "connexionswing";
      certMainHost = "connexionswing.com";
      hosts        = ["connexionswing.com" "sandetludo.com" "www.connexionswing.com" "www.sandetludo.com" ];
      root         = pcfg.webappDirs.connexionswing_production;
      extraConfig  = [
        ''
        <FilesMatch "\.php$">
          SetHandler "proxy:unix:${pcfg.phpListenPaths.connexionswing_production}|fcgi://localhost"
        </FilesMatch>

        <Directory ${app.varDir}/medias>
          Options FollowSymLinks
          AllowOverride None
          Require all granted
        </Directory>

        <Directory ${app.varDir}/uploads>
          Options FollowSymLinks
          AllowOverride None
          Require all granted
        </Directory>

        Use Stats connexionswing.com

        <Directory ${pcfg.webappDirs.connexionswing_production}>
          Options Indexes FollowSymLinks MultiViews Includes
          AllowOverride All
          Require all granted
        </Directory>
        ''
      ];
    };
  };
}