Replace myPhpfpm with correct overrides

[perso/Immae/Config/Nix.git] / modules / private / websites / chloe / integration.nix

{ lib, pkgs, config, myconfig,  ... }:
let
  chloe  = pkgs.callPackage ./builder.nix {
    inherit (pkgs.webapps) chloe;
    config = myconfig.env.websites.chloe.integration;
    apacheUser = config.services.httpd.Inte.user;
    apacheGroup = config.services.httpd.Inte.group;
  };

  cfg = config.myServices.websites.chloe.integration;
in {
  options.myServices.websites.chloe.integration.enable = lib.mkEnableOption "enable Chloe's website in integration";

  config = lib.mkIf cfg.enable {
    secrets.keys = chloe.keys;
    systemd.services.phpfpm-chloe_dev.after = lib.mkAfter chloe.phpFpm.serviceDeps;
    systemd.services.phpfpm-chloe_dev.wants = chloe.phpFpm.serviceDeps;
    services.phpfpm.pools.chloe_dev = {
      listen = chloe.phpFpm.socket;
      extraConfig = chloe.phpFpm.pool;
      phpOptions = config.services.phpfpm.phpOptions + ''
        extension=${pkgs.php}/lib/php/extensions/mysqli.so
      '';
    };
    system.activationScripts.chloe_dev = chloe.activationScript;
    system.extraSystemBuilderCmds = ''
      mkdir -p $out/webapps
      ln -s ${chloe.app.webRoot} $out/webapps/${chloe.apache.webappName}
      '';
    services.websites.integration.modules = chloe.apache.modules;
    services.websites.integration.vhostConfs.chloe = {
      certName    = "eldiron";
      addToCerts  = true;
      hosts       = ["chloe.immae.eu" ];
      root        = chloe.apache.root;
      extraConfig = [ chloe.apache.vhostConf ];
    };
  };
}