Use attrs for secrets instead of lists

[perso/Immae/Config/Nix.git] / modules / private / system / monitoring-1.nix

{ config, pkgs, resources, ... }:
{
  deployment = {
    targetUser = "root";
    targetHost = config.hostEnv.ips.main.ip4;
    substituteOnDestination = true;
  };
  # ssh-keyscan monitoring-1 | nix-shell -p ssh-to-age --run ssh-to-age
  secrets.ageKeys = [ "age1dn4lzhgxusqrpjjnzm7w8ml39ptf326htuzmpqdqs2gg3wq7cqzqxuvx8k" ];
  boot.kernelPackages = pkgs.linuxPackages_latest;
  myEnv = import ../../../nixops/secrets/environment.nix;

  imports = [ <nixpkgs/nixos/modules/profiles/qemu-guest.nix> ] ++ builtins.attrValues (import ../..);

  myServices.monitoring.enable = true;
  myServices.monitoring.master = true;
  myServices.status.enable = true;
  networking = {
    firewall.enable = true;
    interfaces."ens3".ipv4.addresses = pkgs.lib.attrsets.mapAttrsToList
      (n: ips: { address = ips.ip4; prefixLength = 32; })
      (pkgs.lib.attrsets.filterAttrs (n: v: n != "main") config.hostEnv.ips);
    interfaces."ens3".ipv6.addresses = pkgs.lib.flatten (pkgs.lib.attrsets.mapAttrsToList
      (n: ips: map (ip: { address = ip; prefixLength = (if n == "main" && ip == pkgs.lib.head ips.ip6 then 64 else 128); }) (ips.ip6 or []))
      config.hostEnv.ips);
    defaultGateway6 = { address = "fe80::1"; interface = "ens3"; };
  };
  boot.loader.grub.device = "nodev";
  fileSystems."/" = { device = "/dev/sda1"; fsType = "ext4"; };
  myServices.mailRelay.enable = true;

  security.pki.certificateFiles = [
    (pkgs.fetchurl {
      url = "http://downloads.e.eriomem.net/eriomemca.pem";
      sha256 = "1ixx4c6j3m26j8dp9a3dkvxc80v1nr5aqgmawwgs06bskasqkvvh";
    })
  ];

  services.netdata.enable = true;
  services.netdata.config.web."allow dashboard from" = "localhost";
  services.netdata.config.web."allow badges from" = "*";
  services.netdata.config.web."allow streaming from" = "*";
  services.netdata.config.web."allow netdata.conf from" = "fd*";
  services.netdata.config.web."allow management from" = "fd*";
  networking.firewall.allowedTCPPorts = [ 19999 ];
  environment.etc."netdata/stream.conf".source = config.secrets.fullPaths."netdata-stream.conf";

  secrets.keys = {
    "netdata-stream.conf" = {
      user = config.services.netdata.user;
      group = config.services.netdata.group;
      permissions = "0400";
      text = builtins.concatStringsSep "\n" (pkgs.lib.mapAttrsToList (_: key: ''
        [${key}]
            enabled = yes
            default history = 3600
            default memory = ram
            health enabled by default = auto
      '') config.myEnv.monitoring.netdata_keys);
    };
  };
  users.users."${config.services.netdata.user}".extraGroups = [ "keys" ];
  # This value determines the NixOS release with which your system is
  # to be compatible, in order to avoid breaking some software such as
  # database servers. You should change this only after NixOS release
  # notes say you should.
  # https://nixos.org/nixos/manual/release-notes.html
  system.stateVersion = "20.03"; # Did you read the comment?
}