Add missing default route for ip6

[perso/Immae/Config/Nix.git] / modules / private / system / backup-2.nix

{ privateFiles }:
{ config, pkgs, resources, ... }:
{
  boot.kernelPackages = pkgs.linuxPackages_latest;
  myEnv = import "${privateFiles}/environment.nix" // { inherit privateFiles; };
  hostEnv.FQDN = "backup-2.v.immae.eu";

  imports = builtins.attrValues (import ../..);

  deployment = {
    targetEnv = "hetznerCloud";
    hetznerCloud = {
      authToken = config.myEnv.hetznerCloud.authToken;
      datacenter = "hel1-dc2";
      location  ="hel1";
      serverType = "cx11";
    };
  };

  fileSystems = {
    "/backup2" = {
      fsType = "ext4";
      device = "UUID=b9425333-f567-435d-94d8-b26c22d93426";
    };
  };

  networking = {
    firewall.enable = true;
    interfaces."ens3".ipv4.addresses = pkgs.lib.attrsets.mapAttrsToList
      (n: ips: { address = ips.ip4; prefixLength = 32; })
      (pkgs.lib.attrsets.filterAttrs (n: v: n != "main") config.myEnv.servers.backup-2.ips);
    interfaces."ens3".ipv6.addresses = pkgs.lib.flatten (pkgs.lib.attrsets.mapAttrsToList
      (n: ips: map (ip: { address = ip; prefixLength = (if n == "main" && ip == pkgs.lib.head ips.ip6 then 64 else 128); }) (ips.ip6 or []))
      config.myEnv.servers.backup-2.ips);
    defaultGateway6 = { address = "fe80::1"; interface = "ens3"; };

    defaultMailServer = {
      directDelivery = true;
      hostName = "eldiron.immae.eu:25";
      useTLS = true;
      useSTARTTLS = true;
      root = "postmaster@immae.eu";
    };
  };

  services.cron = {
    mailto = "cron@immae.eu";
    enable = true;
  };

  services.rsyncBackup = {
    mountpoint = "/backup2";
    mailto = config.myEnv.rsync_backup.mailto;
    profiles = config.myEnv.rsync_backup.profiles;
    ssh_key_public = config.myEnv.rsync_backup.ssh_key.public;
    ssh_key_private = config.myEnv.rsync_backup.ssh_key.private;
  };

  myServices.monitoring.enable = true;
  myServices.databasesReplication = {
    postgresql = {
      enable = true;
      base = "/backup2";
      hosts = {
        eldiron = {
          slot = "backup_2";
          connection = "postgresql://backup-2:${config.myEnv.servers.backup-2.ldap.password}@eldiron.immae.eu";
        };
      };
    };
    mariadb = {
      enable = true;
      base = "/backup2";
      hosts = {
        eldiron = {
          serverId = 2;
          # mysql resolves "backup-2" host and checks the ip, but uses /etc/hosts which only contains ip4
          host = config.myEnv.servers.eldiron.ips.main.ip4;
          port = "3306";
          user = "backup-2";
          password = config.myEnv.servers.backup-2.ldap.password;
          dumpUser = "root";
          dumpPassword = config.myEnv.databases.mysql.systemUsers.root;
        };
      };
    };
    redis = {
      enable = true;
      base = "/backup2";
      hosts = {
        eldiron = {
          host = "127.0.0.1";
          port = "16379";
        };
      };
    };
    openldap = {
      enable = true;
      base = "/backup2";
      hosts = {
        eldiron = {
          url = "ldaps://${config.myEnv.ldap.host}:636";
          dn = config.myEnv.ldap.replication_dn;
          password = config.myEnv.ldap.replication_pw;
          base = config.myEnv.ldap.base;
        };
      };
    };
  };

  # This value determines the NixOS release with which your system is
  # to be compatible, in order to avoid breaking some software such as
  # database servers. You should change this only after NixOS release
  # notes say you should.
  # https://nixos.org/nixos/manual/release-notes.html
  system.stateVersion = "19.03"; # Did you read the comment?
}